CSV per Batch bearbeiten und als neue csv speichern

Mitglied: chaoscs

chaoscs (Level 1)

08.11.2013 um 14:59 Uhr, 2791 Aufrufe, 17 Kommentare, 1 Danke

Hallo zusammen!

Ich brauche einmal Eure Hilfe.

Eine csv Datei welche per FTP Programm automatisch abgerufen wird soll wie folgt per Batch bearbeitet werden und als xy.csv gespeichert werden.

Die neue Datei soll nur Spalte 1 und die errechnete Spalte 2 enthalten. Trennzeichen ist ein "@" Zeichen

Spalte 2 errechnet sich wie folgt aus der ersten Datei:

Wenn Spalte 8<3 dann setze 0, wenn Spalte 9<4 setze 0,wenn Spalte 10<4 setze 0

Summe aus den Spalten 8+9+10 = Spalte 2

Habt Ihr da vielleicht was für mich ?
Mitglied: mc-doubleyou
08.11.2013 um 16:08 Uhr
Hey,

das sieht mir eher nach einem Makro aus als nach einer Batch.
Du kannst zwar mit einer Batch in eine csv Datei schreiben

01.
echo dein Text für A1 > meine.csv
02.
echo dein Text für A2 >> meine.csv
03.
usw.
aber ich fürchte nicht so komplex rechnen.

Aber andere wissen da sicher besser bescheid.

LG mcdy
Mitglied: bastla
08.11.2013, aktualisiert um 17:47 Uhr
Hallo chaoscs und willkommen im Forum!

Das könnte zB so gehen:
01.
@echo off & setlocal
02.
set "Ein=D:\Datei.csv"
03.
set "Aus=D:\xy.csv"
04.
set "Delim=;"
05.

06.
del "%Aus%" 2>nul
07.
for /f "usebackq tokens=1-10 delims=%Delim%" %%a in ("%Ein%") do (
08.
    if %%h lss 3 (
09.
        >>"%Aus%" echo %%a%Delim%0
10.
    ) else (
11.
        if %%i lss 4 (
12.
            >>"%Aus%" echo %%a%Delim%0
13.
        ) else (
14.
            if %%j lss 4 (
15.
                >>"%Aus%" echo %%a%Delim%0
16.
            ) else (
17.
                set /a Summe=%%h + %%i + %%j
18.
                setlocal enabledelayedexpansion
19.
                >>"%Aus%" echo %%a%Delim%!Summe!
20.
                endlocal
21.
            )
22.
        )
23.
    )
24.
)
Vorausgesetzt habe ich, dass als Trennzeichen ein Semikolon (siehe Zeile 4) verwendet wird und in den einzelnen Zeilen keine Trennzeichen unmittelbar aufeinander folgen (weil ein onder mehrere Felder leer sind).

Grüße
bastla
Mitglied: chaoscs
08.11.2013 um 17:39 Uhr
Hey, erstmal danke für die schnellen Antworten.

Also Trennzeichen ist wie beschrieben das "@" Zeichen.

Spalten gibt es von A-L. Die Spalten D und E sind leer. Die Spalten B,C,D,E,F,G,K,L brauche ich nicht.
Mitglied: bastla
08.11.2013 um 17:46 Uhr
Hallo chaoscs!
Trennzeichen ist wie beschrieben das "@" Zeichen.
Sorry - hatte ich glatt überlesen ...

Wenn D und E leer sind, müssten eigentlich zwei "@" aufeinander folgen - in diesem Fall:
01.
@echo off & setlocal
02.
set "Ein=D:\Datei.csv"
03.
set "Aus=D:\xy.csv"
04.
set "Delim=@"
05.

06.
del "%Aus%" 2>nul
07.
for /f "usebackq tokens=1-10 delims=%Delim%" %%a in ("%Ein%") do (
08.
    if %%g lss 3 (
09.
        >>"%Aus%" echo %%a%Delim%0
10.
    ) else (
11.
        if %%h lss 4 (
12.
            >>"%Aus%" echo %%a%Delim%0
13.
        ) else (
14.
            if %%i lss 4 (
15.
                >>"%Aus%" echo %%a%Delim%0
16.
            ) else (
17.
                set /a Summe=%%g + %%h + %%i
18.
                setlocal enabledelayedexpansion
19.
                >>"%Aus%" echo %%a%Delim%!Summe!
20.
                endlocal
21.
            )
22.
        )
23.
    )
24.
)
Grüße
bastla
Mitglied: chaoscs
08.11.2013 um 18:42 Uhr
Super....also läuft schonmal schön durch. Dauert ca. 5 Min bei 18000 Zeilen. Spalte A tadellos. Spalte B leider immer 0
Mitglied: chaoscs
08.11.2013 um 18:46 Uhr
achso...jetzt wäre noch top, wenn die Ausgabedeite ein Semikolon als Trennzeichen hätte, da dass anschließend einlesende Programm keine Definition des @ Zeichens als Trennzeichen zulässt.....Tausend Dank!
Mitglied: bastla
08.11.2013, aktualisiert um 18:49 Uhr
Hallo chaoscs!

Könntest Du mal (unter Verwendung von <code>- und </code>-Tags) ein paar Zeilen aus der Datei posten?

Für die Ausgabe mit Semikolon wäre die Zeile 19 anzupassen:
                >>"%Aus%" echo %%a;!Summe!
Grüße
bastla
Mitglied: chaoscs
08.11.2013 um 18:57 Uhr
123456@TestTest@TestTest@@@1,00@6,00@4@4@0@0@0@
654321@TestTest@TestTest@@2,00@315,00@4@4@0@0@0@
546879@TestTest@TestTest@@20,00@149,90@4@4@0@0@0@
213879@TestTest@TestTest@@@35,00@29,50@4@4@0@0@0@
Mitglied: chaoscs
08.11.2013 um 18:58 Uhr
quatsch..so natürlich

123456@TestTest@TestTest@@@1,00@6,00@4@4@0@0@0@
654321@TestTest@TestTest@@@2,00@315,00@4@4@0@0@0@
546879@TestTest@TestTest@@@20,00@149,90@4@4@0@0@0@
213879@TestTest@TestTest@@@35,00@29,50@4@4@0@0@0@
Mitglied: bastla
08.11.2013 um 19:07 Uhr
Hallo choscs!

Bei Deinen Beispielzeilen enthalten die Spalten 8 bis 10 ja jeweils die Werte 4,4 und 0, sodass also wegen "Spalte 10 < 4" in allen Fällen das Ergebnis 0 lauten muss ...

Grüße
bastla
Mitglied: chaoscs
08.11.2013 um 19:32 Uhr
ahh ok...ich dachte mir, dass die summe aus 4+4+0=8 ist?!?

Es soll auf jeden Fall so sein, dass wenn in einer der Spalten eine 4 ist, auch die vier ausgegeben wird. Ist in zwei Spalten die vier dann halt die 8 und wenn in drei Spalten die 4, dann halt die 12, halt die Summe. Geht das?
Mitglied: bastla
08.11.2013 um 21:56 Uhr
Hallo chaoscs!

Wie soll denn nun die Regel wirklich lauten: Auf jeden Fall die Summe ausgeben, oder nur, wenn eine Spalte zumindest 4 enthält, oder ... ?

Falls tatsächlich die Ausgabe der Summe ohne Bedingung gewünscht wäre, würde sich der Batchauf
01.
@echo off & setlocal
02.
set "Ein=D:\Datei.csv"
03.
set "Aus=D:\xy.csv"
04.
set "DelimEin=@"
05.
set "DelimAus=;"
06.

07.
del "%Aus%" 2>nul
08.
for /f "usebackq tokens=1-10 delims=%DelimEin%" %%a in ("%Ein%") do (
09.
    set /a Summe=%%f + %%g + %%h
10.
    setlocal enabledelayedexpansion
11.
    >>"%Aus%" echo %%a%DelimAus%!Summe!
12.
    endlocal
13.
)
reduzieren ...

Grüße
bastla
Mitglied: chaoscs
08.11.2013 um 22:11 Uhr
Im Prinzip ganz einfach:

Ist der Inhalt der Spalten 8-10 kleiner 4 soll er eine 0 in der Spalte setzen. Ist der Wert >=4 soll die Zahl stehen bleiben. Anschließend soll er die Summe aus den Spalten 8-10 ziehen

Bsp.

0 0 0 = 0 0 0 = 0
1 4 2 = 0 4 0 = 4
4 1 4 = 4 0 4 = 8
Mitglied: bastla
08.11.2013 um 22:19 Uhr
Hallo chaoscs!

Dann ist die Umsetzung auch einfach :
01.
@echo off & setlocal
02.
set "Ein=D:\Datei.csv"
03.
set "Aus=D:\xy.csv"
04.
set "DelimEin=@"
05.
set "DelimAus=;"
06.
set /a Grenze=4
07.

08.
del "%Aus%" 2>nul
09.
for /f "usebackq tokens=1-10 delims=%DelimEin%" %%a in ("%Ein%") do (
10.
    set /a Summe=0
11.
    if %%f geq %Grenze% set /a Summe+=%%f
12.
    if %%g geq %Grenze% set /a Summe+=%%g
13.
    if %%h geq %Grenze% set /a Summe+=%%h
14.
    setlocal enabledelayedexpansion
15.
    >>"%Aus%" echo %%a%DelimAus%!Summe!
16.
    endlocal
17.
)
Grüße
bastla
Mitglied: chaoscs
09.11.2013 um 09:00 Uhr
Funktioniert super! Nochmal danke!
Mitglied: chaoscs
09.11.2013 um 09:43 Uhr
Leider fallen einem Fehler erst auf, wenn man damit arbeitet.....Kann man noch eine erste Zeile mit Überschriften und eine dritte Spalte mit einer fixen Zahl einfügen?!?

Ergebnis quasi:

Spalte1 Spalte 2 Spalte 3
xx xy xz
Spalte 1 Summe 1
Spalte 1 Summe 1
....
Mitglied: bastla
09.11.2013 um 11:30 Uhr
Hallo chaoscs!
Kann man noch eine erste Zeile mit Überschriften und eine dritte Spalte mit einer fixen Zahl einfügen?!?
Man(n) kann :
01.
@echo off & setlocal
02.
set "Ein=D:\Datei.csv"
03.
set "Aus=D:\xy.csv"
04.
set "DelimEin=@"
05.
set "DelimAus=;"
06.
set /a Grenze=4
07.
set /a Fix=42
08.

09.
>"%Aus%" echo xx%DelimAus%xy%DelimAus%xz
10.
for /f "usebackq tokens=1-10 delims=%DelimEin%" %%a in ("%Ein%") do (
11.
    set /a Summe=0
12.
    if %%f geq %Grenze% set /a Summe+=%%f
13.
    if %%g geq %Grenze% set /a Summe+=%%g
14.
    if %%h geq %Grenze% set /a Summe+=%%h
15.
    setlocal enabledelayedexpansion
16.
    >>"%Aus%" echo %%a%DelimAus%!Summe!%DelimAus%%Fix%
17.
    endlocal
18.
)
Grüße
bastla
Titel: CSV per Batch bearbeiten und als neue csv speichern
Content-ID: 221514
Art des Inhalts: Frage
Ausgedruckt am: 26.08.2019 um 08:59:28 Uhr
URL: https://administrator.de/contentid/221514