daniel2000
Goto Top

Per Batch oder VBS Zeichen aus Dateinamen ersetzen

Hallo,
hab schon viel hier im Forum gelesen, finde aber nicht die passende Lösung für mich.

Ich habe einen Ordner mit mehreren Dateien.

Der Name der Dateien in dem Ordner soll per Batch oder VB-Script umbenannt werden.

z.B. soll aus

Frü hling -> Frühling werden

Also muss das Zeichen ü in ein ü umgewandelt werden.

Bekomme es einfach nicht, wer hat Tipps wie es geht?


Gruß Daniel

Content-Key: 139025

Url: https://administrator.de/contentid/139025

Ausgedruckt am: 29.03.2024 um 14:03 Uhr

Mitglied: bastla
bastla 24.03.2010 um 13:17:24 Uhr
Goto Top
Hallo Daniel2000!

Als VBScript etwa so:
Ordner = "D:\Dein Ordner"  
LogDatei = "D:\Umbenennungen.txt"  
ErsetzungsListe = Array("ü =ü", "ÞÅ =ö")  
Delim = "="  

If WScript.Arguments.Count > 0 Then Ordner = WScript.Arguments(0)
Set fso = CreateObject("Scripting.FileSystemObject")  
Set L = fso.CreateTextFile(LogDatei)

For Each File In fso.GetFolder(Ordner).Files
    Alt = File.Name
	Neu = File.Name
    For Each Ersetzung In Ersetzungsliste
        Neu = Replace(Neu, Split(Ersetzung, Delim)(0), Split(Ersetzung, Delim)(1))
    Next
    If Alt <> Neu Then
        L.WriteLine Alt & " --> " & Neu  
        'Um die Umbenennung tatsächlich durchzuführen, das  
        'Kommentarzeichen vor der nächsten Zeile entfernen:  
        'File.Name = Neu  
    End If
Next
WScript.Echo vbCrLF & "Fertig."  
Die Ersetzungsliste in der Zeile 3 kann (jeweils durch ein Komma getrennt), um Ersetzungspaare in der Schreibweise "Alt=Neu" ergänzt werden (das zweite oben verwendete Paar ist nur als Demo gedacht).

Vorläufig wird nur eine Logdatei mit den Umbenennungen erstellt - erst wenn Du das Kommentarzeichen am Beginn der Zeile 20 entfernst, wird der Dateiname tatsächlich geändert.

Grüße
bastla
Mitglied: daniel2000
daniel2000 24.03.2010 um 13:37:35 Uhr
Goto Top
Hallo Bastla,

besten Dank für dein Script, genauso etwas habe ich gesucht!!!

Funktioniert super!