Dateien Speicherort-Spezifisch umbenennen und Teilstrings darin ersetzen

Zu meinem Problem (Betriebssystem ist Windows XP):

Erstmal abstrakt:
Ich habe einen Ordner in dem einige Dateien (hauptsächlich PDF's und die besagte BAT) liegen. Die PDF's sind nach Kürzeln benannt.
Die bat soll nun die PDF's (keine anderen Dateien) wie folgt umbenennen:
Zunächst soll soll der Name (nicht Pfad!) des Ordners in dem sie liegen an den Anfang ihres Dateinamens gesetzt werden und mit einem Unterstrich mit dem "Hauptnamen" verbunden werden. Dieser ist abhängig vom voherigen Namen (einem Kürzel) der PDF. Dieses Kürzel soll dann nach einer hardcoded-Liste ersetzt werden (falls keine Ersetzung für das Kürzel definiert wurde, soll dieses als "Hauptname" benutzt werden).
Zum Schluss soll die BAT sich selbst löschen (das hab ich bei meinen Versuchen immerhin hinbekommen :O )


An einem Beispiel erklärt:
Ich habe einen Ordner mit Namen "0-50_PS".

Darin sind folgende Dateien:
LKW.txt
LKW.pdf
PKW.pdf
BC.pdf
Moped.pdf
rename.bat

In rename.bat ist (hardgecoded, aber an einer zentralen Stelle änderbar) definiert:
LKW soll umbenannt werden in "Lastkraftwagen"
PWK soll umbenannt werden in "Personenkraftwagen"
BC soll umbenannt werden in "Boby Car"
DR soll umbenannt werden in "Dreirad"

Nach Ausführung von rename.bat soll der Inhalt so aussehen:
LKW.txt
0-50_PS_Lastkraftwagen.pdf
0-50_PS_Personenkraftwagen.pdf
0-50_PS_Boby Car.pdf [Ja, das Leerzeichen muss leider sein]
0-50_PS_Moped.pdf


Die TXT-Datei soll also noch genauso heißen, obwohl sie ein Kürzel enthält. Die PDF's sollen _alle_ den Ordnernamen am Anfang stehen haben und anschließend das (evtl. ersetzte) Kürzel.


Ich hoffe ich habe mich verständlich ausgedrückt.
Ich habe wirklich ewig rumprobiert, aber mit meinen (minimalen) Batch-Kenntnissen leider gescheitert. Wäre super wenn mir da jemand was schustern könnte. Falls das zuviel verlangt ist, kann ich morgen mal meinen (mehr als fragwürdigen) Code posten und meine Probleme aufzählen und nächste Woche hab ich das Ding dann auch fertig mit eurer Hilfe


Vielen Danke nochmal!

mit freundlichen Grüßen
Bene / Heinzel

LKW=Lastkraftwagen
PKW=Personenkraftwagen
BC=Bobby Car
DR=Dreirad
Moped=Moped

@echo off
for %%* in (.) do set "Verzeichnis=%%~n*"  
for /f "delims=" %%s in ('dir /b /a-d *.pdf') do (  
	for /f "usebackq delims== tokens=1,2" %%m in ("Liste.txt") do (  
		if "%%~ns"=="%%m" echo ren "%%s" "%Verzeichnis%_%%n%%~xs"  
		)
	)
pause
goto :eof

@echo off

setlocal enabledelayedexpansion


set "Expressions=LKW PKW BC DR"  
set "ReplaceExp=Lastkraftwagen Personenkraftwagen "Bobby Car" Dreirad"  


for %%d in (.) do set "HomeDir=%%~nd"  

for /f "delims=" %%f in ('dir /b /a:-d *.pdf') do (  
  set /a Cntr=0
  set "Exp=%%~nf"  

  for %%e in (%Expressions%) do (
    set /a Cntr+=1

    if "%%~nf" equ "%%~e" (  
      set /a Cntr2=0

      for %%r in (%ReplaceExp%) do (
        set /a Cntr2+=1

        if !Cntr2! equ !Cntr! (
          set "Exp=%%~r"  
        )
      )
    )
  )

  ren "%%f" "%HomeDir%_!Exp!%%~xf"  
)