thomas0204
Goto Top

Zwei Texte Zeilenweise zusammenfügen per batch

Hey,
ich habe hier schon viel in diesem Forum gelesen und konnte schon viele meiner Fragen damit beantworten, aber zu meinem akktuellen Problem habe ich leider nichts passendes gefunden.
Also ich habe zwei txt Dateien, die ich Zeilenweise zusammen fügen möchte.

1. Datei
505440
4520145
584014
4525

2. Datei
HNODH
HFNJSIK
HFHIKLSE
GKIKDE

und am Ende soll so eine Datei raus kommen
505440HNODH
4520145HFNJSIK
584014HFHIKLSE
4525GKIKDE

ich hoffe ihr könnt mir helfen face-smile

Content-Key: 174339

Url: https://administrator.de/contentid/174339

Ausgedruckt am: 28.03.2024 um 09:03 Uhr

Mitglied: Friemler
Friemler 09.10.2011 um 12:06:42 Uhr
Goto Top
Hallo Thomas0204,

teste mal folgendes:
@echo off & setlocal enabledelayedexpansion


set "InFile1=file1.txt"  
set "InFile2=file2.txt"  
set "OutFile=CON"  


( for /f "tokens=1* delims=:" %%a in ('findstr /n "^" "%InFile1%"') do (  
    set /p "Line="  
    >> "%OutFile%" echo\%%b!Line!  
  )
) < "%InFile2%"  

Falls die Eingabedateien Ausrufezeichen enthalten, werden diese NICHT in die Ausgabedatei geschrieben.

Gruß
Friemler
Mitglied: Thomas0204
Thomas0204 09.10.2011 um 12:55:58 Uhr
Goto Top
Hey danke für die schnelle antwort es hat super funktioniert face-smile
Mitglied: pieh-ejdsch
pieh-ejdsch 09.10.2011 um 16:24:09 Uhr
Goto Top
moin Friemler,

Oh, was neues - na das nenn ich mal good Stuff!
< "File2" (for /f "usebackqdelims=" %i in ("File1") do @set "A=%i"&set /p "B="&&cmd /von /c echo !A! !B!) >Out.txt  

da kann ich mir ja endlich die Zeilen 5 - 35 meiner 100 MB logDatei etwas unkomplizierter zügiger ausgeben lassen, ohne die Datei Komplett Durchzurasseln.
< 100MBLogFile (for /l %i in (1,1,35) do @set/p"Line="&if %i geq 5 cmd /von /c echo\!Line!)  

Gruß Phil
Mitglied: bastla
bastla 09.10.2011 um 17:15:54 Uhr
Goto Top
@Friemler
Falls die Eingabedateien Ausrufezeichen enthalten, werden diese NICHT in die Ausgabedatei geschrieben.
... und falls in "file1.txt" eine Zeile mit einem Doppelpunkt beginnen sollte, ist der im Ergebnis auch nimmer da ...

... ansonsten aber eine sehr schöne Lösung. face-smile

Grüße
bastla
Mitglied: Friemler
Friemler 09.10.2011 um 17:25:53 Uhr
Goto Top
Hallo bastla, hallo Phil,

danke für die Blumen, aber inspiriert hat mich Rubberman in diesem Fred.

Schönen Sonntag
Friemler