Anfrage Ordner Auflistungs Skript

Hallo zusammen,

ich habe ein Skript was einen Ordner durchsucht und alle Ordner samt Unterordner mit der jeweiligen Anzahl der Dateien auflistet.

Output ist also eine TXT die so ausschaut:

0001107096 35 Dateien
0001107412 25 Dateien
0001115080 35 Dateien


Jetzt hätte ich gerne, dass er neben jedem Ordnernamen noch das Erstelldatum listet.
z.b.

Ordnername 35 Dateien 14.12.2019

Kann jemand das Skript unten entsprechend anpassen?


@echo off &setlocal

set "root=PfadZumOrdnerDasAufgelistetWerdenSoll"

for /f "delims=" %%a in ('dir /ad /b "%root%" 2^>nul') do (
set "folder=%root%\%%~a"
set /a n=0
setlocal enabledelayedexpansion
for /f "delims=" %%b in ('dir /a-d /b "!folder!" 2^>nul') do (
set /a n+=1
)
set "folder=%%~a "
>>test.txt echo !folder:~,40! !n! Dateien
endlocal
)

@echo off
setlocal enabledelayedexpansion

set "root=PfadZumOrdnerDasAufgelistetWerdenSoll"  

>test.txt type nul
cd /d "%root%"  
for /f "delims=" %%a in ('dir /ad /b 2^>nul') do (  
	set "folder=%%~a"  
	set datum=%%~ta
	echo !datum:~0,10!
	set n=0
	for /f "delims=" %%b in ('dir /a-d /b "!folder!" 2^>nul') do (  
		set /a n+=1
		)
	set "folder=%%~a "  
	>>"%~dp0\test.txt" echo !folder:~,40! !n! Dateien !datum:~0,10!  
	)

@echo off
set "root=PfadZumOrdnerDasAufgelistetWerdenSoll"  

powershell ls -dir '%root%' ^| %% { $_.name+' '+(ls -file $_.FullName).length+' Dateien '+$_.CreationTime.ToString('dd.MM.yyyy') } ^| Out-File -Encoding Default test.txt  

@echo off
set "root=PfadZumOrdnerDasAufgelistetWerdenSoll"  

powershell ls -dir '%root%' ^| %% { $_.name+' '+(ls -r -file $_.FullName).length+' Dateien '+$_.CreationTime.ToString('dd.MM.yyyy') } ^| Out-File -Encoding Default test.txt  

@echo off
set "root=PfadZumOrdnerDasAufgelistetWerdenSoll"  

powershell ls -dir '%root%' ^| %% { $_^|Add-Member NoteProperty 'Anzahl Dateien' (ls -r -file $_.FullName).count;$_ } ^| select Name,'Anzahl Dateien',Creationtime ^| Export-Csv -e default -d ';' -nti test.csv