krasseritfreak
Goto Top

excel unklarheit

ich möchte dass bei excel wenn ich eine zahl eingebe eine abfrage gestartet wird

das soll herauskommen

<199 0%
200-599 3%
600-1199 6%
1200-2399 9%
2400-3999 12%
4000-6999 15%
7000-9999 18%
10000>> 21%

wie muss ich das in excel definieren dass ich die richtigen prozentwerte bekomme?

habe es mit folgender abfrage probiert aber geht nicht:
=WENN(F3<200;0;WENN(F3>=200&F3<600;3;WENN(F3>=600&F3<1200;6;WENN(F3>=1200&F3<2400;9;WENN(F3>=2400&F3<4000;12;WENN(F3>=4000&F3<7000;15;WENN(F3>=7000&F3<10000;18;21)))))))
bitte hilfestellungen geben

Content-Key: 66106

Url: https://administrator.de/contentid/66106

Ausgedruckt am: 28.03.2024 um 10:03 Uhr

Mitglied: Alforno
Alforno 13.08.2007 um 19:43:11 Uhr
Goto Top
Soweit ich weiß lässt sich die WENN Anweisung nur 7 oder 8 mal verkschachteln.
Ich weiß nicht ob du dich ein wenig mit vba auskennst, da wäre das schnell gemacht.

Sonst probiere das hier:

http://www.office-loesung.de/ftopic74022_0_0_asc.php

mfg
Alforno
Mitglied: bastla
bastla 13.08.2007 um 19:58:08 Uhr
Goto Top
Hallo KrasserItFreak und Alforno!

Der Link war schon nicht schlecht, da er indirekt zu diesem Thread mit der sinnvollen Lösung SVERWEIS (im vorletzten Kommentar der ersten Seite) führt:
http://www.office-loesung.de/ftopic33270_0_0_asc.php

Grüße
bastla
Mitglied: bastla
bastla 13.08.2007 um 20:18:00 Uhr
Goto Top
... oder, um es gleich konkret zu machen: Baue eine kleine Tabelle aus den beiden Spalten "ab Menge" und "Satz" (zB ab M2 oder auch in einem anderen Tabellenblatt) auf und befülle sie mit den entsprechenden Wertepaaren:

MN
2ab MengeSatz
300%
42003%
56006%
612009%
7240012%
8400015%
9700018%
101000021%

Wichtig ist bei dieser Tabelle, dass sie immer mit der Untergrenze eines Bereiches (und daher gleich mit 0) beginnt und aufsteigend sortiert ist.

Verwende dann in G3 die Formel
=SVERWEIS(F3;$M$3:$N$10;2)
wobei der zweite Parameter nur die Daten (ab M3) ohne Überschriften (in M2 und N2) umfassen darf.

Grüße
bastla
Mitglied: Biber
Biber 13.08.2007 um 22:30:01 Uhr
Goto Top
Na, KrosserITFreak,

ein oder zwei Varianten hätte ich auch noch...

Am knackigsten finde ich die hier:
=WAHL(VERGLEICH($F3;{0;200;600;1200;2400;4000;7000;10000};1);0;3;6;9;12;15;18;21)

[Es werden Integer-Werte geliefert; ich unterstelle eine Formatierung auf Prozent]

Btw, eigentlich habe ich mich nur angemeldet, weil ich diesen Beitrag mal von "Betriebssysteme" nach "Excel-Krams" verschieben wollte.

Gruß
Biber
Mitglied: bastla
bastla 13.08.2007 um 22:48:39 Uhr
Goto Top
@Biber

Da "knackig" ja sicher nicht als Synonym für "wartbar" gemeint ist, gefällt mir der Ansatz als "Oneliner" wirklich sehr gut ... face-wink

Grüße
bastla
Mitglied: Biber
Biber 13.08.2007 um 22:56:47 Uhr
Goto Top
@bastla

Okay, erwischt...
ich würde natürlich Deine Hilfstabelle nehmen und dann Namen vergeben für MaxWerte (=M2:M10) bzw. Prozent (=N2:N10) und dann schreiben:
=WAHL(VERGLEICH(F3;MaxWerte;1);Prozente)
Sinngemäß zumindest... müsste Excel ja mitmachen... face-wink
Ist aber ungetestet. *zugeb

Grüße
Biber
Mitglied: bastla
bastla 13.08.2007 um 23:28:39 Uhr
Goto Top
@Biber

Mit INDEX() ginge es tatsächlich:
=INDEX(Prozente;VERGLEICH(F3;MaxWerte;1))

Grüße
bastla