mariusap
Goto Top

Mit Batch Job eine bestimmte Zeile von einer XML- in eine andere XML-Datei übertragen

Hallo,

ich möchte aus der Datei "c:\config\config.xml" den Inhalt der Zeile 4 (<ID>wert</ID>) in die Datei "c:\update\config.xml" (<ID>standardwert</ID>) auch Zeile 4 übertragen. Hab schon einiges versucht, aber irgendwie will es nicht.

Leider muss es ein Batch-Job sein.

Schon mal Danke für Eure Hilfe

LG
Marius

Content-Key: 219664

Url: https://administrator.de/contentid/219664

Ausgedruckt am: 28.03.2024 um 12:03 Uhr

Mitglied: bastla
bastla 17.10.2013 um 17:54:30 Uhr
Goto Top
Hallo MariusAP und willkommen im Forum!

Wenn es nur darum geht, die gesamte Zeile 4 auszutauschen, könntest Du es so versuchen:
@echo off & setlocal
set "Quelle=c:\config\config.xml"  
set "Ziel=c:\update\config.xml"  
set /a ZNr=4

set "XMLTemp=%temp%\xml.tmp"  
for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%Quelle%"^|findstr /b "%ZNr%:"') do set "ZeileNeu=%%j"  
move "%Ziel%" "%XMLTemp%"  
(for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%XMLTemp%"') do (  
    set "Zeile=%%j"  
    setlocal enabledelayedexpansion
    if %%i==%ZNr% (
        echo(!ZeileNeu!
    ) else (
        echo(!Zeile!
    )
    endlocal
))>>"%Ziel%"  
del "%XMLTemp%"  
Grüße
bastla
Mitglied: MariusAP
MariusAP 17.10.2013 um 22:09:55 Uhr
Goto Top
Hallo Bastla,

veni vidi vici.

Vielen Dank und LG
Marius