Dateien mit dem aktuellen Datum Zählen

Servus zusammen,

ich hoffe sehr, dass mir mal wieder jemand helfen kann. Ich arbeite mit einem VBA-Makro bzw einer Funktion, die mir alle Dateien eines definierten Ordners zählt. Ich würde die Funktion nun gern noch so anpassen, dass nur noch die Dateien mit dem aktuellen Datum (als immer das Datum, an dem die Funktion ausgeführt wird) gezählt werden. Leider scheitere ich nun schon seit Tagen daran und zweifele an mir selbst - jedoch habe ich Zeitdruck.

Kann mir eventuell jemand helfen?

Meine Funktion schaut bisher so aus (ich verwende Excel 2010):

Function DateienZählen(verz As String) As Integer
Dim datName As String
Dim counter As Integer
 
 
If Right(Trim(verz), 1) <> "\" Then verz = Trim(verz) & "\"  
such = verz & "*MS*.txt"  
On Error GoTo fehler
ChDir verz              'testen, ob das Verzeichnis existiert  
datName = Dir(such, 7)  'ersten Eintrag  
Do While datName <> ""  
    counter = counter + 1
    datName = Dir       'nächster Eintrag  
Loop
DateienZählen = counter
Exit Function
 
fehler:
DateienZählen = -666      'Verzeichnis existiert nicht  
End Function

Grüße, Olli

p.s. Hoffe, dass ich das richtige Thema gewählt habe - und das Archiv habe ich bereits nach Kräften durchsucht...

[Edit Biber] Codeformatierung. [/Edit]

Please also mark the comments that contributed to the solution of the article

Content-Key: 298504

Url: https://administrator.de/contentid/298504

Printed on: April 16, 2024 at 23:04 o'clock

3 Comments

Latest comment

Hallo Olli!

Sollte so gehen:

Option Explicit
Option Compare Text

Function DateienZählen(ByVal strDir As String) As Integer
    Dim objFile As Object
    
    With CreateObject("Scripting.FileSystemObject")  
        If .FolderExists(strDir) Then
            For Each objFile In .GetFolder(strDir).Files
                If objFile.Name Like "*MS*.txt" And DateValue(objFile.DateCreated) = Date Then  
                    DateienZählen = DateienZählen + 1
                End If
            Next
        Else
            DateienZählen = -666 'Verzeichnis existiert nicht  
        End If
    End With
End Function

Gruß Dieter

Servus Dieter,

vielen Dank für deine Mühe - leider hängt Excel in einer Endlosschleife (reagiert nicht mehr) und ich finde keinen Fehler.

Gruß, Olli

Korrektur: Es geht!

Danke nochmals!

German solved Question Microsoft Office Microsoft

Hotly discussed

End of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment