photographix
Mar 29, 2010, updated at Mar 01, 2023 (UTC)
view6927
view8
0
Goto Top

Nach fertiger Batch Mail versenden

GermansolvedQuestionBatch, ShellDevelopment
Olá @ all

beim Frühjahrsputz in unseren Servern habe ich einige sehr alte Scripte entdeckt die bei uns wichtige Sachen nochmals spiegeln.
Beispielscript unten.

Leider gefällt mit das mit der Batch aber nicht mehr so.
Die Batch schreibt immer dann eine Email wenn Sie durchgelaufen ist.
Wenn ein Fehler auftritt bekomm ich keine Mail!
Das ist nicht schön - ich hätte es gern anders rum - bin aber kein "batcher".

Meine Idee wäre ja mit II zu arbeiten. (Befehl copy II Send Mail)
Ich weiss aber nicht genau wo ich konkret II einbauen muss.


Vielleicht hat jemand einen Tipp


Danke im Voraus.


Bsp:


:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Copy von Server DATEN nach Server BACKUP auf Windows Server 2008 - Backup per Mirroring
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::Pfadvaribale für Blat Mailer setzen
SET PATH=%PATH%;C:\Batches\Blat\
set time-begin=%time:~0,8%
set date-begin=%date%

:: Dateien spiegeln mit zuwachs (kein löschen und nur hinzufügen)

robocopy.exe "w:" "d:\administration" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"d:\robolog_mir_administration.log" /NP /V  
robocopy.exe "\\server3\netlogon$" "D:\Netlogon Kopie" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"D:\robolog_mir_netlogon.log" /NP /V  
robocopy.exe "\\server3\deploy$" "D:\Deploy" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"D:\robolog_mir_deploy.log" /NP /V  
robocopy.exe "g:" "d:\framework" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"d:\robolog_mir_framework.log" /NP /V  
	

::Mail verschicken das Batch fertig
		
set time-end=%time:~0,8%
set date-end=%date%
echo Backup Mirror Admin-Server2 Ende - vom %date-begin% - %time-begin::=:% Uhr bis %date-end% - %time-end::=:% Uhr | Blat.exe -priority 1 -to adminuser@domain.de -server smtp.domain.de -u adminuser@domain.de -pw K5EeiMB7 -debug -timestamp -log blatSMTPlog.txt -subject "Backup Mirror Admin-Server2 Ende - vom %date-begin% - %time-begin::=:% Uhr bis %date-end% - %time-end::=:% Uhr "
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 139418

Url: https://administrator.de/contentid/139418

Printed on: April 18, 2024 at 04:04 o'clock

8 Comments
Latest comment
Goto Top
Member: Snowman25
Snowman25 Mar 29, 2010 at 13:58:14 (UTC)
Goto Top
Hallo @photographix,

probiers mal so:
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Copy von Server DATEN nach Server BACKUP auf Windows Server 2008 - Backup per Mirroring
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::Pfadvaribale für Blat Mailer setzen
SET PATH=%PATH%;C:\Batches\Blat\
set time-begin=%time:~0,8%
set date-begin=%date%
set /A fail=0

:: Dateien spiegeln mit zuwachs (kein löschen und nur hinzufügen)

robocopy.exe "w:" "d:\administration" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"d:\robolog_mir_administration.log" /NP /V  
call check
robocopy.exe "\\server3\netlogon$" "D:\Netlogon Kopie" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"D:\robolog_mir_netlogon.log" /NP /V  
call check
robocopy.exe "\\server3\deploy$" "D:\Deploy" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"D:\robolog_mir_deploy.log" /NP /V  
call check
robocopy.exe "g:" "d:\framework" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"d:\robolog_mir_framework.log" /NP /V  
call check
	

::Mail verschicken wenn fail=1
if %fail%==1 (
set time-end=%time:~0,8%
set date-end=%date%
echo Backup Mirror Admin-Server2 FEHLER - vom %date-begin% - %time-begin::=:% Uhr bis %date-end% - %time-end::=:% Uhr | Blat.exe -priority 1 -to adminuser@domain.de -server smtp.domain.de -u adminuser@domain.de -pw K5EeiMB7 -debug -timestamp -log blatSMTPlog.txt -subject "Backup Mirror Admin-Server2 FEHLER - vom %date-begin% - %time-begin::=:% Uhr bis %date-end% - %time-end::=:% Uhr " 
goto theend
)

:check
if %ERRORLEVEL% GTR 0 set /A fail=1

:theend
ungetestet

Gruß
Snow
Member: bastla
bastla Mar 29, 2010 at 14:41:50 (UTC)
Goto Top
@Snowman25

Sollte nicht (ganz ohne Unterprogramm) ein
set "fail="
robocopy ... || set "fail=True"
...
if defined fail ( ...
oder alternativ nach jedem "robocopy" ein
if errorlevel 1 set "fail=True"
genügen?

Außerdem wäre es ratsam, die Variablen %time-end% und %date-end% vor dem "if" (= außerhalb der Klammer) zu erstellen (da ansonsten "delayedExpansion" erforderlich wäre) ...

Grüße
bastla
Member: Snowman25
Snowman25 Mar 29, 2010 at 15:00:35 (UTC)
Goto Top
Zitat von @bastla:
nach jedem "robocopy" ein if errorlevel 1 set "fail=True" > genügen?
ungefähr so hatte ich es anfangs auch, aber i-wie hat mir das nicht gefallen...
Ich setzte fail auf 1 bzw. 0 um einfach konsistent zu bleiben. So kommt mir der Programmierstil doch wesentlich sauberer und selbsterklärender vor.
Außerdem wäre es ratsam, die Variablen %time-end% und %date-end% vor dem "if" (= außerhalb der
Klammer) zu erstellen (da ansonsten "delayedExpansion" erforderlich wäre) ...
Da spricht eigentlich nichts dagegen. Wie vorhin schon geschrieben ist das Script ja ungetestet.


Hier also nochmal die korrigierte Version:
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Copy von Server DATEN nach Server BACKUP auf Windows Server 2008 - Backup per Mirroring
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem Pfadvaribale für Blat Mailer setzen
SET PATH=%PATH%;C:\Batches\Blat\
set time-begin=%time:~0,8%
set date-begin=%date%
set /A fail=0

:: Dateien spiegeln mit zuwachs (kein löschen und nur hinzufügen)

robocopy.exe "w:" "d:\administration" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"d:\robolog_mir_administration.log" /NP /V  
if %ERRORLEVEL% GTR 0 set /A fail=1
robocopy.exe "\\server3\netlogon$" "D:\Netlogon Kopie" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"D:\robolog_mir_netlogon.log" /NP /V  
if %ERRORLEVEL% GTR 0 set /A fail=1
robocopy.exe "\\server3\deploy$" "D:\Deploy" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"D:\robolog_mir_deploy.log" /NP /V  
if %ERRORLEVEL% GTR 0 set /A fail=1
robocopy.exe "g:" "d:\framework" /MIR /R:10 /ZB /DCOPY:T /TEE /LOG:"d:\robolog_mir_framework.log" /NP /V  
if %ERRORLEVEL% GTR 0 set /A fail=1

set time-end=%time:~0,8%
set date-end=%date%

rem Mail verschicken wenn fail=1
if %fail%==1 (
echo Backup Mirror Admin-Server2 FEHLER - vom %date-begin% - %time-begin::=:% Uhr bis %date-end% - %time-end::=:% Uhr | Blat.exe -priority 1 -to adminuser@domain.de -server smtp.domain.de -u adminuser@domain.de -pw K5EeiMB7 -debug -timestamp -log blatSMTPlog.txt -subject "Backup Mirror Admin-Server2 FEHLER - vom %date-begin% - %time-begin::=:% Uhr bis %date-end% - %time-end::=:% Uhr " -body "Es sind Fehler aufgetreten. Bitte folgende logfiles ueberpruefen: D:\robolog_mir_administration.log D:\robolog_mir_netlogon.log D:\robolog_mir_deploy.log D:\robolog_mir_framework.log" 
)
Member: bastla
bastla Mar 29, 2010 at 15:11:23 (UTC)
Goto Top
@Snowman25
Ich setzte fail auf 1 bzw. 0 um einfach konsistent zu bleiben. So kommt mir der Programmierstil doch wesentlich sauberer und selbsterklärender vor.
"defined" (egal ob "True" oder 1 enthalten ist) oder "not defined" würde ich auch als konsistent betrachten ...

Der Hauptgrund, warum ich zuletzt vorrangig diese Variante verwende: Auf "defined" kann auch innerhalb einer Struktur (zB "for"-Schleife) geprüft werden, ohne "delayedExpansion" verwenden zu müssen.

Grüße
bastla
Member: photographix
photographix Apr 06, 2010 at 04:17:25 (UTC)
Goto Top
Olá@all

War im verlängerten Oster-Weekend.
Feedback zur Batch kommt noch diese Woche.
Danke vorab fürs helfen.

Nice Week.

LG
Member: photographix
photographix Apr 07, 2010 at 11:41:55 (UTC)
Goto Top
So nun mein Fazit:

Das Script funktioniert soweit ganz gut ABER die Version 026 von Robocopy (XP) hat ein Problem bei der Fehlerrückgabe.
Bsp: Laufwerk überhaupt nicht da -> Error 0 ??

Die Version 010 (2k) von Robocopy bring dort einen Fehler den ich abfangen kann.
Kann dafür aber nicht mit der Option /DCOPY:T arbeiten.

Die Version 027 (Vista/Win7) geht gar nicht unter XP...

Naja mal sehen was ich nun mache.

Trotzdem danke fürs rege Feedback.
Member: Snowman25
Snowman25 Apr 07, 2010 at 11:54:32 (UTC)
Goto Top
sind die Ordner-timestamps denn Überlebenswichtig? Höchstwahrscheinlich werden die sowieso von niemandem beachtet..
Member: photographix
photographix Apr 07, 2010 at 12:08:15 (UTC)
Goto Top
Sagen wir so jain ^^

Man kann daran aber noch sehen wann einmal ein Ordner erstellt wurde und so finden wir ab und zu mal richtige Leichen.

Eventuell könnte man das mit Delage -> Datei löschen -> und dann später leere Ordner löschen lassen
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
AlexWishaHow to set up and configure a Linux GRE tunnelAlexWisha - 3 CommentsDaniEnd of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment