Home-Shares aufräumen

Break on

$Homepfad="\\Server1\Home\"  

; Homeverzeichnisse aus ADS auslesen
$rc=GetUserHome(@DOMAIN)

; Liste der vorhandenen Home-Verzeichnisse erstellen
$l3=FreeFileHandle()
$rc=Open($l3,"%TEMP%\Vorhandene_Verzeichnisse.txt",5)  
$FileName = Dir($Homepfad)
While $FileName <> "" AND @ERROR = 0  
  If $Filename <> "." AND $FileName <> ".."  
    $rc=WriteLine($l3,$Homepfad+$FileName+@CRLF)
  EndIf
  $FileName = Dir()
Loop
$rc=Close($l3)

; Einträge vergleichen
Del "C:\nicht_eingetragene_Verzeichnisse.txt"  
$l4=FreeFileHandle()
$rc=Open($l4,"%TEMP%\Vorhandene_Verzeichnisse.txt",2)  
$l5=FreeFileHandle()
$rc=Open($l5,"C:\nicht_eingetragene_Verzeichnisse.txt",5)  
$line=ReadLine($l4)
While @ERROR=0
  $merker=0
  For $i = 0 to Ubound($Home)
    If $Home[$i]=$line
      $merker=1
    EndIf
  Next
  If $merker=0 ; keine Übereinstimmung gefunden
    $rc=WriteLine($l5,$line+@CRLF) ; in Liste schreiben
  EndIf
  $line=ReadLine($l4)
Loop
$rc=Close($l4)
$rc=Close($l5)

Del "%TEMP%\Vorhandene_Verzeichnisse.txt"  
Exit

Function GetUserHome ($DomainName)
	Dim $UHome[10000]	
	$Domain = GetObject("WinNT://" + $DomainName + ",domain")  
	$Container = $Domain
		For Each $User In $Container
	  	  If $User.Class = "User"  
	      	$UHome[$x] = $User.HomeDirectory
	      	$x = $x + 1
	  	EndIf
	Next
	ReDim Preserve $UHome[$x - 1]
	$Home = $UHome
	$Domain = 0
	$Container = 0
EndFunction