Office 2010 deinstallieren und gegen 365 ersetzen

@echo off


echo %time% Batch wurde gestartet >> C:\officeupgrade.log

::Check if machine is LT or P
echo %COMPUTERNAME% | find "V" >NUL  
if not errorlevel 1 (
	echo Target Machine is Server. Exiting...
	ping -n 4 127.0.0.1 >NUL
	exit
)

::check for running outlook process
for /f %%i in ('"tasklist | findstr OUTLOOK"') do set outlook=%%i  

IF "%outlook%"=="OUTLOOK.EXE" (  
	taskkill /IM OUTLOOK.EXE
	ping 127.0.0.1 -n 3 >NUL
	) else (
	echo outlook not running
)
msg * "Das Herunterfahren kann sich verzögern, da dass neue Office installiert wird."  
ping 127.0.0.1 -n 7 >NUL
::myPBX schließen:
for /f %%j in ('"tasklist | findstr myPBX"') do set mypbx=%%j  

IF "%mypbx%"=="myPBX.exe" (  
	taskkill /IM myPBX.exe
	ping 127.0.0.1 -n 3 >NUL
	) else (
	echo myPBX not running
)

::uninstall Office 2010 Standard

if exist "C:\Program Files (x86)\Microsoft Office\Office14\OUTLOOK.EXE" (  
	echo alte Office Version vorhanden
	"\\**Netzwerkpfad**\setup.exe" /uninstall Standard /config "\\**Netzwerkpfad**\Standard.WW\uninstall.xml"  
	echo %time% Alte Outlook Version vorhanden >> C:\officeupgrade.log
) else (
	echo Alte Outlook Version nicht vorhanden
	echo %time% Alte OfficeVersion nicht vorhanden >> C:\officeupgrade.log
)

::Install Office 365

if exist "C:\Program Files (x86)\Microsoft Office\root\Office16\OUTLOOK.EXE" (  
	echo Neue OfficeVersion gefunden
) else (
	echo Neue Office Version nicht vorhanden
	echo %time% Neue Office Version noch nicht vorhanden >> C:\officeupgrade.log
	"\\**Netzwerkpfad**\Office365\setup.exe" /configure "\\**Netzwerkpfad**\Office365\Configuration.xml"  
	echo %time% Office wurde installiert >> C:\officeupgrade.log
	echo %computername% >> "\\**Netzwerkpfad**\Office365\Installiert auf.txt"  
	msg * "Office wurde installiert und kann nach dem Hochfahren wieder verwendet werden."  
	ping 127.0.0.1 -n 10 >NUL
)

<Configuration Product="Standard">  
   <Display Level="none" CompletionNotice="no" SuppressModal="yes" AcceptEula="yes" />  
   <Setting Id="SETUP_REBOOT" Value="NEVER" />  
</Configuration>