Top-Themen

Aktuelle Themen (A bis Z)

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit

gelöst Tokens-Dateinamenzerlegungsproblem (Variablen werden überschrieben?)

Mitglied: Sodele

Sodele (Level 1) - Jetzt verbinden

31.07.2011, aktualisiert 10:31 Uhr, 3206 Aufrufe, 11 Kommentare

Hallo zusammen. Ich habe hier durch vielerlei Anregungen eine Batch halbwegs zum Laufen gebracht, die mir als Ergebnis aber immer nur die Werte der letzten Datei aus einem Ordner wiedergibt, wobei eigentlich alle berücksichtigt werden sollen. Da ich absoluter Laie bin (was man am Code vermutlich auch unschwer erkennen kann) hoffe ich auf eure Hilfe.

Aufgabe: Die Batch soll die Dateinamen aller Mediendateien in einem Ordner, in dem sie sich selbst befindet (ist aber kein Muss, meinetwegen darf sie ruhig eine Ebene hochrutschen) "zerstückeln" und zusammen mit der jeweiligen Dateigröße in eine XML zur Weiterverarbeitung schreiben.
Mein bisheriger Versuch sieht so aus:

01.
@echo off 
02.
@setlocal enabledelayedexpansion
03.

04.
REM +++ Dateinamen zerlegen 
05.
FOR /f "delims=_ tokens=1-6" %%i in ('Dir /b C:\MyMedia\Test\*_*_*_*_*_*.*') do ( 
06.
	set varGroup=%%i
07.
	set varAlbum=%%j
08.
	set varTitle=%%k
09.
	set varNr=%%l
10.
	set varBitrate=%%m
11.
	set varType=%%n)
12.
	
13.
REM +++ Dateigrösse ermitteln
14.
for /f "delims=" %%i in ('Dir /b C:\MyMedia\Test\*_*_*_*_*_*.*') do ( 
15.
        set varSize=%%~zi)
16.

17.
REM +++ XML Header schreiben
18.
ECHO ^<?xml version="1.0" encoding="UTF-8"?^> >test.xml
19.
ECHO ^<request^> >>test.xml
20.

21.
REM +++ XML schreiben
22.
FOR /f "delims=_ tokens=1-6" %%i in ('Dir /b C:\MyMedia\Test\*_*_*_*_*_*.*') do (
23.
ECHO 	^<item type="file"^> >>test.xml
24.
ECHO 		^<filename^>%Dateiname%^</filename^> >>test.xml
25.
ECHO 		^<group^>%varGroup%^</group^> >>test.xml
26.
ECHO 		^<album^>%varAlbum%^</album^> >>test.xml
27.
ECHO 		^<title^>%varTitle^</title^> >>test.xml
28.
ECHO 		^<nr^>%varNr%^</nr^> >>test.xml
29.
ECHO 		^<type^>%varType%^</type^> >>test.xml
30.
ECHO 		^<bytes^>%varSize%^</bytes^> >>test.xml
31.
ECHO 	^</item^> >>test.xml
32.
)
33.

34.
REM +++XML Footer schreiben
35.
ECHO ^</request^> >>test.xml
36.

37.

38.
goto :eof 
39.

40.
:End 
41.

42.
Endlocal
Das Ganze liefert mir eigentlich schon den gewünschten Aufbau, nur leider schreibt er nur die Ergebnisse der letzten Datei hinein. Ich nehme also an, dass er die Variablen %%i-%%n überschreibt. Nur weiß ich leider nicht, wo ich da ansetzen soll. Außerdem wäre es nett, wenn ihr mir einen Tipp zum Schreiben des jeweiligen Dateinamens in die xml geben könntet, der sträubt sich auch noch. Vielen Dank schon mal.
Mitglied: Friemler
31.07.2011 um 10:57 Uhr
Hallo Sodele,

das sollte so gehen (ungetestet):
01.
@echo off & setlocal
02.

03.

04.
set "Output=C:\test.xml"
05.

06.
REM +++ XML Header schreiben
07.
> "%Output%" ECHO ^<?xml version="1.0" encoding="UTF-8"?^>
08.
>>"%Output%" ECHO ^<request^>
09.

10.
pushd "C:\MyMedia\Test"
11.

12.
REM +++ Dateinamen ermitteln
13.
(FOR /f "delims=" %%a in ('dir /b "*_*_*_*_*_*.*"') do (
14.
   REM +++ Dateinamen zerlegen
15.
   FOR /f "delims=_. tokens=1-6" %%i in ("%%a") do (
16.
     ECHO ^<item type="file"^>
17.
     ECHO   ^<filename^>%%~na^</filename^>
18.
     ECHO   ^<group^>%%i^</group^>
19.
     ECHO   ^<album^>%%j^</album^>
20.
     ECHO   ^<title^>%%k^</title^>
21.
     ECHO   ^<nr^>%%l^</nr^>
22.
     ECHO   ^<bitrate^>%%m^</bitrate^>
23.
     ECHO   ^<type^>%%n^</type^>
24.
     ECHO   ^<bytes^>%%~za^</bytes^>
25.
     ECHO ^</item^>
26.
   )
27.
))>>"%Output%"
28.

29.
popd
30.

31.
REM +++XML Footer schreiben
32.
>>"%Output%" ECHO ^</request^>
Daten, die man ermittelt hat, sollte man auch direkt verarbeiten, nicht erst 10 Zeilen weiter unten, nachdem die Schleife schon beendet ist. .

Die Ausgabeumleitung bei ECHO-Befehlen sollte man immer vor das ECHO schreiben, das vermeidet Fehlfunktionen des Codes, die tückischerweise nur unter bestimmten Umständen auftreten. Das hat aber nichts mit Deinem Fehler zu tun.

In Zeile 17 wird nur der Dateiname ohne Erweiterung in die XML-Datei geschrieben. Wenn es beides sein soll, schreibe statt %%~na einfach %%a.

Gruß
Friemler


[EDIT]
Code zur Erhöhung der Ausführungsgeschwindigkeit auf die Blockwrite-Methode von Mathe geändert.
[/EDIT]

[EDIT2]
Bugfix: Der Dateiname wurde falsch zerlegt.
[/EDIT2]
Bitte warten ..
Mitglied: mathe172
31.07.2011 um 11:00 Uhr
Hallo,

du musst nach dem setzten der Variablen (Z6-Z11) jedesmal Daten in die XML schreiben.
Etwa so:
01.
@echo off 
02.
REM +++ XML Header schreiben
03.
(ECHO ^<?xml version="1.0" encoding="UTF-8"?^>
04.
ECHO ^<request^>
05.
)>"test.xml"
06.

07.
REM +++ Alle Dateien abarbeiten (Schau mal "/s" bei "dir /?" and)
08.
for /f "delims=" %%a in ('Dir /b C:\MyMedia\Test\*_*_*_*_*_*.*') do (
09.
REM +++ XML schreiben
10.
FOR /f "delims=_ tokens=1-6" %%i in ("%~a") do (
11.
ECHO 	^<item type="file"^>
12.
REM Hier musst du schauen, was du von %~a brauchst
13.
ECHO 		^<filename^>%~na^</filename^>
14.
ECHO 		^<group^>%%i^</group^>
15.
ECHO 		^<album^>%%j^</album^>
16.
ECHO 		^<title^>%%k^</title^>
17.
ECHO 		^<nr^>%%l^</nr^>
18.
ECHO            ^<bitrate^>%%m^</bitrate^>
19.
ECHO 		^<type^>%n%^</type^>
20.
ECHO 		^<bytes^>%~za^</bytes^>
21.
ECHO 	^</item^>
22.
))>>"test.xml"
23.

24.
REM +++XML Footer schreiben
25.
(ECHO ^</request^>
26.
)>>"test.xml"
(Ungetestet)

MfG,
Mathe172
[Edit: Das war so klar dass wieder jemand schneller ist...]
Bitte warten ..
Mitglied: Skyemugen
31.07.2011 um 11:05 Uhr
Aloha,

zu viel Aufwand

Versuch' es doch so:
01.
@echo off & setlocal
02.

03.
REM +++ XML Header schreiben
04.
>test.xml (
05.
ECHO ^<?xml version="1.0" encoding="UTF-8"?^>
06.
ECHO ^<request^>
07.
)
08.

09.
FOR /f "delims=" %%a in ('Dir /b C:\MyMedia\Test\*_*_*_*_*_*.*') do ( 
10.
FOR /f "delims=_ tokens=1-6" %%i in ('echo %%~a') do (
11.
>>test.xml (
12.
ECHO 	^<item type="file"^>
13.
ECHO 		^<filename^>%%a^</filename^>
14.
ECHO 		^<group^>%%i^</group^>
15.
ECHO 		^<album^>%%j^</album^>
16.
ECHO 		^<title^>%%k^</title^>
17.
ECHO 		^<nr^>%%l^</nr^>
18.
ECHO 		^<bitrate^>%%m^</nr^>
19.
ECHO 		^<type^>%%n^</type^>
20.
ECHO 		^<bytes^>%%~za^</bytes^>
21.
ECHO 	^</item^>
22.
)
23.
)
24.
)
25.
REM +++XML Footer schreiben 
26.
>>test.xml ECHO ^</request^>
27.
pause
28.
goto :eof
Anmerkung: Für die Dateigrößenausgabe muss die Batchdatei imselben Verzeichnis liegen, sonst müsste man den Code etwas anpassen

Ebenso ist bei dir Dateiname nicht definiert, also gehe ich vom eigentlichen, wirklichen, kompletten Dateinamen aus.
Desweiteren gab es bei dir keine Zeile, in der varBitrate genutzt wurde, auch diese habe ich dazugetragen und es fehlt bei dir sowieso ein Prozentzeichen in Zeile 27 ^_^.

Anyway: enabledelayedexpansion ohne Ausrufezeichen ist eh zwecklos aber auch die hätten hier nicht viel genutzt und wie du siehst: Man benötigt es auch gar nicht, da du die for-Variablen direkt nutzen kannst.

greetz André

EDIT AHA! Da wartet man extra, bis der Herr Friemler etwas postet, um sich die Arbeit zu sparen, da loggt er sich aus und ist nicht mehr da, also denkt man: Gut, dann mach' ich das und wenn man postet hat der Herr Friemler sich auch schon ganz weit wieder vorgedrängelt, ja, ja, ja *fg*

P.S.: @mathe, au weia, überfliege noch einmal deine ganzen for-Variablen, das wird nix ^_^ %~a ? %n% ? %~za ?
Bitte warten ..
Mitglied: mathe172
31.07.2011 um 11:08 Uhr
@Friemler:
Die Ausgabeumleitung bei ECHO-Befehlen sollte man immer vor das ECHO schreiben, das vermeidet Fehlfunktionen des Codes, die tückischerweise nur unter bestimmten Umständen auftreten.
Noch einfacher ist es bei grossen Blöcken, alles auf einmal umzuleiten

MfG,
Mathe172
Bitte warten ..
Mitglied: Sodele
31.07.2011 um 11:10 Uhr
Wow. Das ging ja wirklich fix. Vielen, vielen Dank euch beiden. Werde das mal gleich beides testen, v.a. Friemlers Version sieht schön viel schlanker als mein Ansatz aus.
Bitte warten ..
Mitglied: Friemler
31.07.2011 um 11:13 Uhr
Hallo Mathe,

in dem Fall hier kann man das auch ohne weiteres machen. Wenn der zu schreibende Text aber Klammern enthält (z.B. Inline-VBScript), kommen zu den üblichen Quertreibern &, < und >, die "escaped" werden müssen, noch die öffnende und schließende Klammer hinzu. Dann wird es meist zu unübersichtlich. Ich bevorzuge es deshalb, die Umleitung vor jede Zeile zu schreiben.

Gruß
Friemler
Bitte warten ..
Mitglied: Sodele
31.07.2011 um 11:14 Uhr
Vielen Dank auch dir Skyemugen. Gebt mir mal ein paar Minuten, um das alles nachzuvollziehen. Ist ja Wahnsinn, wie flott ihr seid. Danke!

So, habe mich jetzt mal durch eure Hilfe gearbeitet und es hat alles geklappt. Vielen Dank noch mal.

Nur noch eine kurze Frage zu Skymugen:

Wenn nach dem Code nichts mehr kommt, wieso muss ich dann eigentlich nach goto :eof? Ein einfaches EXIT wäre doch sinnvoller, oder übersehe ich da etwas? Und sehe ich das richtig, dass ich auf Endlocal verzichten kann?
Bitte warten ..
Mitglied: Skyemugen
31.07.2011 um 11:14 Uhr
Aloha Friemler,

das dauert aber länger, da dabei öfter die Datei geöffnet, beschrieben, geschlossen etc. wird :P (gut, hier nicht wirklich aber generell schon ^_^), zumindest hatte das mal der gute Phil erwähnt

greetz André
Bitte warten ..
Mitglied: Friemler
31.07.2011 um 11:19 Uhr
Moin André,

ja, das ist richtig, das kann sogar einen richtigen Geschwindigkeitsboost ergeben. Man muss das eben immer für den Einzelfall abwägen. Codeblöcke, die sehr oft abgearbeitet werden, sollte man wirklich besser mit der Blockwrite-Methode schreiben. Bei Codeblöcken, die nur 1, 2 Mal abgearbeitet werden, sollte man aufgrund der besseren Lesbarkeit darauf verzichten (zumindest wenn der zu schreibende Text Klammern enthält, ich habe das hier halt aus reiner Gewohnheit so gemacht ).

Gruß
Friemler
Bitte warten ..
Mitglied: bastla
31.07.2011 um 12:48 Uhr
Hallo Sodele und willkommen im Forum!
Wenn nach dem Code nichts mehr kommt, wieso muss ich dann eigentlich nach goto :eof?
Musst Du nicht.
Ein einfaches EXIT wäre doch sinnvoller, oder übersehe ich da etwas?
In den allermeisten Fällen ist "exit" ohne "/b" sinnlos - je nach Aufruf wird die CMD-Shell ohnehin automatisch geschlossen (bzw soll sie das gar nicht werden - Stichwort "Testen").
Und sehe ich das richtig, dass ich auf Endlocal verzichten kann?
Soferne es (wie oben) am Ende des Batches steht: ja.

Grüße
bastla
Bitte warten ..
Mitglied: Sodele
31.07.2011 um 13:42 Uhr
Okay, vielen Dank euch allen! Dann wünsche ich noch einen schönen Sonntag.
Bitte warten ..
Neue Wissensbeiträge
Windows Server

Zähe Update-Installation auf Windows Server 2016

Information von kgborn vor 1 TagWindows Server4 Kommentare

Mir sind in der Vergangenheit immer wieder Beschwerden von Admins unter die Augen gekommen, die sich über die doch ...

Humor (lol)
Turnschuhe per Firmware lahmlegen
Information von Henere vor 1 TagHumor (lol)8 Kommentare

Und was kommt demnächst ? Bekomme ich kein Klopapier mehr, weil der Spender einem DDOS unterliegt ? :-) Ich ...

Sicherheit

Sicherheitsrisiko in WinRAR und Co. durch Schwachstelle in UNACEV2.DLL

Information von kgborn vor 2 TagenSicherheit

In der seit 2005 nicht mehr aktualisierten Bibliothek UNACEV2.DLL gibt es eine Path-Traversal-Schwachstelle. Diese ermöglicht es, bei ACE-Archiven Dateien ...

Internet

CDU Propaganda: Urheberschutz im Internet - Ende des digitalen Wild-West

Information von Frank vor 3 TagenInternet6 Kommentare

Hallo Administratoren, aus einem Kommentar heraus habe ich folgenden Beiträge von Herr Sven Schulze und Axel Voss (beide CDU ...

Heiß diskutierte Inhalte
Windows Tools
Dateiname Automatisch auf PDF Klartext oder als Barcode abdrucken
Frage von spongebob24Windows Tools29 Kommentare

Hallo Zusammen, habe eine tolle Anforderung bekommen. Ich sollte auf mehrere PDF Dateien Automatisch einen Stempel anbringen lassen. Toll ...

Internet
SDSL oder ADSL - Preis-Leistungs-Verhältnis
Frage von ZeppelinInternet22 Kommentare

Wehrte Community, der Unterschied dieser beiden Techniken ist recht einfach erklärt. Das S, steht für Synchron (Gleich) und das ...

Microsoft Office
MicroSoft und seine Lizenzen
Frage von ZeppelinMicrosoft Office19 Kommentare

Wehrte Community, ich wende mich an die Community weil MicroSoft dazu keine Stellung nehmen möchte. Ich öffne mein Web-Browser ...

SAN, NAS, DAS
Thecus NAS 7700 Login nicht möglich
Frage von uridium69SAN, NAS, DAS13 Kommentare

Morgen allerseits Ich habe einem Kunden ein gebrauchtes Thecus 7700 NAS verkauft. Nun kann der Kunde sich nicht einloggen, ...