Werte aus zwei txt-Dateien abwechselnd in Variablen einlesen
Hallo Zusammen,
nachdem ich mich halb zu Tode gesucht habe frag ich mal euch
Ich habe 2 Textdateien, beide haben garantiert gleich viele Zeilen. Ich möchte nun abwechselnd eine Zeile auslesen und ausgeben, so dass am Schluss da steht:
Datei1Zeile1, Datei2Zeile1
Datei1Zeile2, Datei2Zeile2
Datei1Zeile3, Datei2Zeile3
...
...
.
.
.
Kann mir jemand helfen?
Gruß, J.D.
nachdem ich mich halb zu Tode gesucht habe frag ich mal euch
Ich habe 2 Textdateien, beide haben garantiert gleich viele Zeilen. Ich möchte nun abwechselnd eine Zeile auslesen und ausgeben, so dass am Schluss da steht:
Datei1Zeile1, Datei2Zeile1
Datei1Zeile2, Datei2Zeile2
Datei1Zeile3, Datei2Zeile3
...
...
.
.
.
Kann mir jemand helfen?
Gruß, J.D.
Please also mark the comments that contributed to the solution of the article
Content-Key: 221513
Url: https://administrator.de/contentid/221513
Printed on: April 19, 2024 at 23:04 o'clock
4 Comments
Latest comment
Hallo JohnDorian!
In welcher Sprache soll das denn durchgeführt werden? Als Batch zB etwa so:
Grüße
bastla
In welcher Sprache soll das denn durchgeführt werden? Als Batch zB etwa so:
@echo off & setlocal
set "Ein1=D:\Datei1.txt"
set "Ein2=D:\Datei2.txt"
set "Aus=D:\Ausgabe.txt"
del "%Aus%" 2>nul
(for /f "usebackq delims=" %%i in ("%Ein1%") do (
set "Z1=%%i"
set /p "Z2="
setlocal enabledelayedexpansion
>>"%Aus%" echo !Z1!, !Z2!
endlocal
))<"%Ein2%"
bastla
Oder so, falls doch mal LeerZeilen oder längere Texte
lg.
@ECHO OFF &SETLOCAL
set "Ein1=D:\Datei1.txt"
set "Ein2=D:\Datei2.txt"
set "Aus=D:\Ausgabe.txt"
<"%Ein2%" (
for /f "delims=" %%i in ('findstr /n "^" "%Ein1%"') do (
set "Z1=%%i"
SET "Z2="
set /p "Z2="
setlocal ENABLEDELAYEDEXPANSION
SET "Z1=!Z1:*:=!"
echo !Z1!, !Z2!
ENDLOCAL
))>"%Aus%"