Zellen aus anderer Excel-Mappe mit vba auslesen

Option Explicit

Private Const FilePath = "V:\LDS Tabelle"       'Ordnerpfad  
Private Const CellsCopy = "A2,F3,K1,K2,K3,K4"   'Copy-Zelladressen  

Private Sub DatenImport()
    Dim aData As Variant, sFileName As Variant
    
    ChDrive Left(FilePath, 2):  ChDir FilePath
    
    sFileName = Application.GetOpenFilename("Excel Dateien (*.xls;*.xlsx), *.xls;*.xlsx")  
    
    If sFileName <> False Then
        ActiveSheet.UsedRange.ClearContents
        aData = GetValues(sFileName)
        Range("A1").Resize(UBound(aData, 1), UBound(aData, 2)).Value = aData  
    End If
End Sub

Private Function GetValues(ByRef sFileName) As Variant
    Dim oWkb As Workbook, oWks As Worksheet, oData As Object
    Dim aTemp As Variant, aData As Variant, i As Integer
    
    aData = Split(CellsCopy, ",")  
    ReDim aTemp(UBound(aData))
    
    Set oWkb = GetObject(sFileName)
    Set oData = CreateObject("Scripting.Dictionary")  
    
    For Each oWks In oWkb.Sheets
        For i = 0 To UBound(aData)
            aTemp(i) = oWks.Range(aData(i)).Value
        Next
        oData.Add oData.Count, aTemp
    Next
    
    oWkb.Close False
    
    With WorksheetFunction
        GetValues = .Transpose(.Transpose(oData.Items))
    End With
End Function