Passworteingabe verbergen - Batch

color

@echo off & setlocal
if "%~1" == "/?" findstr /b /c:"::: " "%~f0" & goto :eof  
for %%i in ("%~dp0choice.exe") do if "%%~zi" == "5320" set "Ok=1"  
if not defined OK (echo Bitte die Herunterladbare Choice.exe ins Verzeichnis "%~dp0" legen!&explorer http://winsupport.org/packages/choice.exe&ping localhost -n 15 >nul&exit /b 2 )  
chcp 850 >nul
echo Eingabe von Zeichen Ausgabe als Sternchen.

<nul set /p "=Mach Deine Eingabe : "  

set "Output="  
set /a Check =0
set "One="  
goto :In

:Check
setlocal enabledelayedexpansion
set "OneX="  
for /f "eol= tokens=2,3" %%i in ('findstr /b /c:"::x " "%~f0"') do if not defined OneX if "%%i" == "!One!" set "OneX=%%j"&set "One="  
set "oney=!oney!!OneX!!One!"  
set "One="  
set "OneX="  
for /f "eol=" %%i in ("!oney!") do endlocal & set "oney=%%i" & set "One="  
if not defined oney endlocal
if %Check% equ 5 goto :Out
:In
(
for /f "eol=" %%i in ('" "%~dp0\choice.exe" /cabcdefghijklmnopqrstuvwxyz1234567890ABCDEFGHIJKLMNOPQRSTUVWXYZ!$%%.,{}()?/\*#-:;_'^^@~ /n /s /t,1 "') do for /f "eol= delims=" %%j in ("%%i") do set "One=%%j"  
) >nul
if defined One (set /a Check =0 & <nul set /p "=*" ) else set /a check +=1  
goto :Check
:Out
if not defined oney (echo\& echo Keine Eingabe erfolgt!) else echo\&echo Eingabe beendet!
ping localhost -n 4 >nul
if not defined oney endlocal & exit /b 1
endlocal & set "Output=%oney%" & goto :eof  

:::  Variable Output wird ausgegeben.
:::  Bei Nichteingabe nach 5 sekunden Abbruch oder
:::   automastisches Ende der Eingabe
::: 
:::  Zeichen welche erkannt werden
:::  
:::   ø   !   "   õ   $   %   &       (   )   =   ?   
:::       1   2   3   4   5   6   7   8   9   0   á 
:::         Q   W   E   R   T   Z   U   I   O   P   š   * 
:::         q   w   e   r   t   z   u   i   o   p      + 
:::          A   S   D   F   G   H   J   K   L   ™       '   
:::          a   s   d   f   g   h   j   k   l   ”   „   # 
:::            Y   X   C   V   B   N   M           _ 
:::            y   x   c   v   b   n   m   ,   .   - 
::: 
:::  dieser Batch fuktioniert nur mit dieser herunterladbaren Version:
:::  http://winsupport.org/packages/choice.exe

::x ~ ø
::x @ "  
::x # õ
::x ^ &
::x * (
::x ( )
::x ) =
::x _ ?
::x - á
::x ] +
::x } *
::x : ™
::x ; ”
::x ' „  
::x \ #
::x { š
::x [ 
::x / -
::x ? _
::x z y
::x Z Y
::x y z
::x Y Z