Access Abfrage in nächste freie Zeile von Excel Sheet kopieren

Hallo zusammen,

ich wollte eine Access(2010) Abfrage in eine verlinkte Excel Tabelle anfügen(Anfügeabfrage), leider wurde diese Funktion von Microsoft gesperrt, jetzt bräuchte ich wieder einen VBA Code um das ganze zu realisieren.

Code bis jetzt:

Sub ExportQuery()
  DoCmd.TransferSpreadsheet acExport, 8, "AUSGESCHIEDENE_MITARBEITER", _  
            "C:\Projekt\test.xlsm", True, "Ausgeschiedene Mitarbeiter"  
End Sub

wie müsste man den Code erweitern damit der Inhalt der Abfrage "AUSGESCHIEDENE_MITARBEITER" in den Sheet "AUSGESCHIEDENE_MITARBEITER" angefügt wird(in die nächste freie Zeile)?

Bitte um Hilfe!

Vielen Dank!

Grüße

Dr.C

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 301165

Url: https://administrator.de/forum/access-abfrage-in-naechste-freie-zeile-von-excel-sheet-kopieren-301165.html

Ausgedruckt am: 20.05.2025 um 16:05 Uhr

5 Kommentare

Neuester Kommentar

Hallo Dr. C.,
biddeschön

Sub ExportQueryToExcel()
    Dim rec As Recordset, objExcel As Object, wb as Object
    'Recordset aus Abfrage holen  
    Set rec = CurrentDb.OpenRecordset("AUSGESCHIEDENE_MITARBEITER")  
    'Excel öffnen  
    Set objExcel = CreateObject("Excel.Application")  
    'Ziel-Workbook öffnen  
    Set wb = objExcel.Workbooks.Open("C:\Projekt\test.xlsm")  
    'Daten in das erste Worksheet importieren in die nächste freie Zeile (überprüft wird nächste freie Zeile in Spalte A)  
    With wb.Sheets(1)
        .Cells(.Rows.Count, "A").End(-4162).Offset(1, 0).CopyFromRecordset rec  
    End With
    'Workbook speichern  
    wb.Save
    'Excel schließen  
    objExcel.Quit
End Sub

Grüße Uwe

Falls der Beitrag gefällt, seid so nett und unterstützt mich durch eine kleine Spende / If you like my contribution please support me and donate