Auswahlmenü in einer Bat

Also ich wollte ein kleine Nietliche Batch Datei schreiben, die mit aufforderung ganz bestimmte Server mit dem befehl tracert anping.

Also ich wollte ein kleine Nietliche Batch Datei schreiben, die mit aufforderung ganz bestimmte Server mit dem befehl tracert anping.

@echo off   
color 9f

echo  --------------------------------------------------------------------
echo           Bitte gib den Name fuer die Datein an
set /p tracert=
echo  --------------------------------------------------------------------
echo  Bitte waehle deine Instanz an
echo   1 Deutschland-1
echo   2 Deutschland-2
echo   3 Deutschland-3
echo   4 Deutschland-4
echo   5 Global-1
echo   6 Global-2
echo   7 Global-3
echo   8 Global-4
echo   9 Global-5
echo.
set /p AuswahlEingabe=Instanz Auswaehlen:
echo  --------------------------------------------------------------------
:menu
echo                 Wie viele Abschnitte sollen auf der 
echo              Leitung bis zum Server Ueberprueft werden?
echo              Standart sollte 15 eingetragen werden
echo.
set /p router=
echo  --------------------------------------------------------------------
echo  Datei wird gerade Erstellt, sie finden die Dabei in dem Ordner, wo 
echo  die Batch Datei drin ist. Bitte warten sie, bis sich das Fenster 
echo  von selber schliesst. Danke
echo.
echo.
echo  Programm beendet sich selber
echo  --------------------------------------------------------------------


if (%AuswahlEingabe%) equ 1 goto de1
if (%AuswahlEingabe%) equ 2 goto de2
if (%AuswahlEingabe%) equ 3 goto de3
if (%AuswahlEingabe%) equ 4 goto de4
if (%AuswahlEingabe%) equ 5 goto int1
if (%AuswahlEingabe%) equ 6 goto int5
if (%AuswahlEingabe%) equ 7 goto int7
if (%AuswahlEingabe%) equ 8 goto int10
if (%AuswahlEingabe%) equ 9 goto int11

:de1
Set IP1=de1.darkorbit.bigpoint.com
goto menu

:de2
Set IP1=de2.darkorbit.bigpoint.com
goto menu

:de3
Set IP1=de3.darkorbit.bigpoint.com
goto menu

:de4
Set IP1=de4.darkorbit.bigpoint.com
goto menu

:int1
Set IP1=int1.darkorbit.bigpoint.com
goto menu

:int5
Set IP1=int5.darkorbit.bigpoint.com
goto menu

:int7
Set IP1=int7.darkorbit.bigpoint.com
goto menu

:int10
Set IP1=int10.darkorbit.bigpoint.com
goto menu

:int11
Set IP1=int11.darkorbit.bigpoint.com
goto menu

SET TraceLog="%tracert%.txt"  
Set IP=www.darkorbit.de.

echo Start Trace at %Date% %Time% >> %TraceLog%
ver >>%TraceLog%
tracert -h %router% -d %IP% >> %TraceLog%
tracert -h %router% -d %IP1% >> %TraceLog%
echo END Dark Orbit Tracert Protokoll 3.0 >> %TraceLog%

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Kommentar vom Moderator Dani am 29.01.2011 um 22:55:25 Uhr

Formatierungen eingefügt...

Content-ID: 159720

Url: https://administrator.de/forum/auswahlmenue-in-einer-bat-159720.html

Ausgedruckt am: 13.05.2025 um 18:05 Uhr

7 Kommentare

Neuester Kommentar

Hi,

hübsch, aber wo dein Problem eigentlich ist hast du uns verschwiegen ...

VG

Er Hängt sich auf, nach dem goto, dabei soll er an dem Punkt dann die 2 Adressen mit tracert bearbeiten und das Ergbniss in der vorher festgelegten Datei abladen.
Also in der Vorgänger Version habe ich da kein Menü, sondern da musst man vom Spie die Instanz angeben z.B de1, de2, de3, de4 und so weiter. Nur es gibt Unser die Schreiben dann d1 und wundern nsich, dass cmd beim befehl tracert d1.darkorbit.bigpoint.com nicht auflösen kann da ja statt d1 da de1 stehen hätten müssen, deswegn will ich da ein Menü einfügen nur am Menü hängt es sich auf.

Er erstellt die Daqtei nicht, die am ersten Pubnkte gefragt worden ist und der fürt die 2 Tracert befehle nicht aus

Hallo Derroterecher und willkommen im Forum!

Also ich wollte ein kleine Nietliche Batch Datei schreiben

Vielleicht ginge es mit Schrauben besser ...

... oder halt so:

@echo off & setlocal
color 9f

echo.
echo -------------------------------------------------------------------------------
set /p tracert=Bitte geben Sie den Name fuer die Datei an: 
echo -------------------------------------------------------------------------------
echo.

echo Bitte waehlen Sie die Instanz durch Eingabe der Nummer
echo 1 Deutschland-1
echo 2 Deutschland-2
echo 3 Deutschland-3
echo 4 Deutschland-4
echo 5 Global-1
echo 6 Global-2
echo 7 Global-3
echo 8 Global-4
echo 9 Global-5
echo.

Set Wahl1=de1.darkorbit.bigpoint.com
Set Wahl2=de2.darkorbit.bigpoint.com
Set Wahl3=de3.darkorbit.bigpoint.com
Set Wahl4=de4.darkorbit.bigpoint.com
Set Wahl5=int1.darkorbit.bigpoint.com
Set Wahl6=int5.darkorbit.bigpoint.com
Set Wahl7=int7.darkorbit.bigpoint.com
Set Wahl8=int10.darkorbit.bigpoint.com
Set Wahl9=int11.darkorbit.bigpoint.com

set /p AuswahlEingabe=Instanz auswaehlen: 
echo -------------------------------------------------------------------------------

Set "TraceLog=%tracert%.txt"  
Set IP=www.darkorbit.de.
call Set IP1=%%Wahl%AuswahlEingabe%%%

if not defined IP1 (
    echo Ungueltige Auswahl - Programm wird nach Tastendruck beendet
    pause>nul
    goto :eof
)

echo Wie viele Abschnitte sollen auf der Leitung bis zum Server Ueberprueft werden?
echo.
set /p router=Als Standard sollte 15 eingetragen werden: 
echo.
echo -------------------------------------------------------------------------------
echo Datei wird gerade erstellt, Sie finden die Dabei in dem Ordner der Batch-Datei.
echo Bitte warten Sie, bis sich das Fenster von selber schliesst.
echo.
echo Danke
echo.
echo Programm beendet sich selbst ...
echo -------------------------------------------------------------------------------
echo.
> "%TraceLog%" echo Start Trace at %Date% %Time:~,8%  
>>"%TraceLog%" ver  
>>"%TraceLog%" tracert -h %router% -d %IP%  
>>"%TraceLog%" tracert -h %router% -d %IP1%  
>>"%TraceLog%" echo END Dark Orbit Tracert Protokoll 3.2  

start "Ergebnis" "%TraceLog%"  

Grüße
bastla

P.S.: Ich habe eben ein Herz für Outdoorworkers werden sollte) ...

Moin Derroterecher,

willkommen im Forum.

Falls Kollege T-Mo diesen Beitrag findet ...dann wird es herzlich hier.
Aber das will ich weder vorwegnehmen noch verhindern.

Von mir die (konstruktiv gemeinte) Fragen:
Was passiert denn in deiner Batchskizze, wenn in der ganzen IF-Goto-IF-Goto-If Gotoerei kein passender Wert gefunden wiird und nirgendwo hingegotoed wird?
Und mit welcher Eingabe könnte jemand ohne Chuck Norris' Fähigkeiten die Zeile beginnend mit "SET traceLog=..." erreichen?

Grüße
Biber

Ah danke Bastla, das ist genau so , wie die Batch es machen sollte.
War wohl ein Bisschen Verplant und Verlesen mit hilfe von Google.
Und danke auch an Xaero1982

Bin gerade dabei mich schön tief ins Batch Weltall vor zu dringen, da ich noch nicht so richtig weis, wie es funktioniert, Bastle ich so lange daran rum, bis es meistens nach meiner Vorstellung das Ergebniss kommt. mit dem Menü punkt hat bich mich diesemal ein bischen weit rausgetraut.
Da ich noch sehr viel Laienhaft was mache, können mir noch solche Grob Fahrlässige Ausrutscher Passieren.
Bin ja leider damals ein Bisschen auf der Strecke geblieben, hätte ich lieber vor 15 Jahren mit DOS 3.1 rumgespielt statt Lego technik.

Achja mit IF-Goto werd ich noch ein Bisschen üben

Und anders Herum, die Batch soll ja auch für andere Sein, die auch nicht so viel Ahnung von CMD und so haben, da z.B für das Spiel, wo ich das Schreiben wollte, das mit dem Tracert und der Herauskopieren das beschissen erklährt ist und so eine Batch eine Wahre hilfe ist. für`s Forum und Probleme zu finden

PS. in meiner batch war ja nur das olle goto und menu überflüssig