Durchsuchen einer Spalte nach Variable, wenn gefunden, kopiere Zeile

Option Explicit
Option Compare Text

Const SheetHome = "Abgleich"    'Suchwerte Tabellenname  
Const RangeHome = "B2:B"        'Suchwerte Zell-Teilbereich  
Const SpalteHome = "B"          'Suchwerte Spalte  

Const SheetFind = "LOP"         'Suchen in Tabellenname  
Const SpalteFind = "K"          'Suchen in Spalte  

Const Err1 = "Der vorgebene Zahlenbereich ist unzulässig!"  

Sub SearchAndCopy()

    Dim Wks As Worksheet, c As Range, Found As Range, EndLine As Long, Von As Integer, Bis As Integer
    
   'Abfrage-Boxen für Werte Von und Bis (Type 1 = Integer)  
    Von = Application.InputBox("Bitte den Zahlenbereich [Von] angeben:", "Suchen Von", 1, Type:=1)  
    Bis = Application.InputBox("Bitte den Zahlenbereich [Bis] angeben:", "Suchen Bis", 1, Type:=1)  
    
   'Prüfen auf Wert 0 (Abbrechen) und Prüfen Wert Von größer Bis  
    If Von <= 0 Or Bis <= 0 Or Von > Bis Then MsgBox Err1, vbExclamation, "Fehler": Exit Sub  
    
   'Tabelle Abgleich aktivieren  
    Sheets(SheetHome).Activate
    
   'Tabelle "LOP" als Alias Wks festlegen  
    Set Wks = Sheets(SheetFind)
    
   'Letzte Zeile in Tabelle Abgleich Spalte B ermitteln  
    EndLine = Cells(Rows.Count, SpalteHome).End(xlUp).Row
    
   'Alle Zell-Objecte (c=Range) in Tabelle Abgleich Spalte B durchlaufen  
    For Each c In Range(RangeHome & EndLine)
       
       'Prüfen ob Zellinhalte im Bereich Von und Bis liegt  
        If c >= Von And c <= Bis Then
           
           'Wenn ja, dann in Tabelle "LOP" in Spalte K den Wert suchen  
            Set Found = Wks.Columns(SpalteFind).Find(c, LookIn:=xlValues, LookAt:=xlWhole)
           
           'Prüfen ob der Wert gefunden wurde  
            If Not Found Is Nothing Then
               
               'Wenn ja, dann in der Found-Zeile (Found=Range) Spalte A-G kopieren und in Tabelle Abgleich  
               'Spalte O in aktueller Zeile einfügen  
                Range(Wks.Cells(Found.Row, "A"), Wks.Cells(Found.Row, "G")).copy Destination:=Cells(c.Row, "O")  
            End If
        End If
   
   'Nächste Zelle bis Letzte Zelle erreicht ist  
    Next
End Sub