Habt/Kennt Ihr ein Tool mit dem man Registrywerte bzw. Umgebungsvariablen per Kommandozeile editieren kann?

  if "%1"=="" goto hilfe  
    if "%1"=="/?" goto hilfe  
    if "%1"=="?" goto hilfe  
    if "%1"=="-?" goto hilfe  
    if "%1"=="help" goto hilfe  
    if "%1"=="--help" goto hilfe  
    if "%1"=="/help" goto hilfe  

    goto argchk


:hilfe
    echo Dieses BatchFile sollte immer mit Befehlserweiterungen gestartet 
    echo werden, ansonsten werden bestimmte Zeichenfolgen falsch inte-
    echo pretiert. siehe dazu "cmd /?"  
    echo -----------------------------------------------------------------
    echo Syntax:
    echo varedit [Variablenname] [String] [d] [m]
    echo -----------------------------------------------------------------
    echo Option d:  String wird aus Variable geloescht.
    echo Option m:  String wird als Systemvariable hinzugefuegt/geloescht.
    echo            ohne diese Option wird der String standardmaessig fuer
    echo            den Benutzer gesetzt.
    echo            Hier nur Kleinbuchstaben verwenden.
    echo -----------------------------------------------------------------
    echo Es kann auch der Inhalt einer anderen Umgebungsvariable als 
    echo String uebergeben werden. Diese sollte dann wegen der NameSpaces
    echo in Anfuehrungszeichen stehen (siehe Beispiel 2).
    echo 
    echo Wenn eine Variable IMMER mit einer anderen Variablen gleich sein
    echo soll, muss statt "%%" das Zeichen "~" zu Beginn und am Ende ge-  
    echo setzt werden. Wenn VAR1=%%VAR2%% ergeben soll (siehe Beispiel 3).
    echo -----------------------------------------------------------------
    echo Wert zur USER-Umgebungsvariable hinzufuegen:
    echo Beispiel1: varedit LM_LIC_FILE C:\test 
    echo Beispiel2: varedit HOME "%%USERPROFILE%%"  
    echo Beispiel3: varedit HOME "~USERPROFILE~"  
    echo -----------------------------------------------------------------
    echo Wert aus USER-Umgebungsvariable loeschen (Argument d anfuegen!):
    echo Beispiel1: varedit LM_LIC_FILE C:\test d
    echo Beispiel2: varedit HOME "%USERPROFILE%" d  
    echo -----------------------------------------------------------------
    echo Wert zur SYSTEM-Umgebungsvariable hinzufuegen (Arg. m anfuegen!):
    echo Beispiel1: varedit LM_LIC_FILE C:\test m 
    echo Beispiel2: varedit HOME "%%USERPROFILE%%" m  
    echo -----------------------------------------------------------------
    echo Wert aus SYSTEM-Umgebungsvariable loeschen (Argument d anfuegen!)
    echo Beispiel1: varedit LM_LIC_FILE C:\test d m
    echo Beispiel2: varedit HOME "%USERPROFILE%" m d  
    echo -----------------------------------------------------------------
    
    goto fin




:argchk

    set stat=
    set tmp0=
    set tmp1=

    set tmp0=%1
    set tmp1=%2

rem Anfuehrungszeichen aus tmp1 entfernen
rem Wird nur in der "echten" Dos Box benoetigt, die CCM Konsole intepretiert diese nicht  
rem daher ist der Befehl auskommentiert
rem set tmp1=!tmp1:"=!  

    if "%3"=="m" set stat=m  
    if "%4"=="m" set stat=m  
    if "%3"=="d" goto delvar  
    if "%4"=="d" goto delvar	  




:addvar

rem falls Argument %2 schon existiert, rausloeschen -> keine doppelten Eintraege!

    if not "!%tmp0%!"=="" set %tmp0%=!%tmp0%:%tmp1%=!  
 rem   if not "!%tmp0%!"=="" set %tmp0%=!%tmp0%:~=!  
 rem   if "!%tmp0%:%%!"=="=" set %tmp0%=!%tmp0%:~1,256!  
 rem   if "!%tmp0%:%!"==  


rem Argument %2 setzen

    set %tmp0%=!%tmp0%!;%tmp1%

    echo INFO:
    echo ------------------------------------
    echo Der String "%tmp1%" wurde der    
    echo Umgebungsvariable "%tmp0%" hinzugefuegt.  

goto start1




:delvar

rem "" entfernen  
    set tmp1=!tmp1:"=!  
    set tmp1=!tmp1:"=!  

rem Argument %2 loeschen
    set %tmp0%=!%tmp0%:%tmp1%=!

    echo INFO:
    echo ------------------------------------
    echo Der String "%tmp1%" wurde aus der    
    echo Umgebungsvariable "%tmp0%" geloescht.  




:start1

rem Befehl doppelt, falls 3 mal ";" in der VAR vorkommen sollten  

    set %tmp0%=!%tmp0%:;;=;!
    set %tmp0%=!%tmp0%:;;=;!
    set %tmp0%=!%tmp0%:"=!  
    set %tmp0%=!%tmp0%:"=!  

:loop1

rem Falls am Anfang ein ";" oder "="steht -> löschen  

    if "!%tmp0%:~0,1!"==";" set %tmp0%=!%tmp0%:~1,256!  
    if "!%tmp0%:~0,1!"==";" goto loop1  
    if "!%tmp0%:~0,1!"=="=" set %tmp0%=!%tmp0%:~1,256!  
    if "!%tmp0%:~0,1!"=="=" goto loop1  
    if "!%tmp0%!"==";" set %tmp0%=  
    if "!%tmp0%!"=="=" set %tmp0%=  

    if "%stat%"=="m" goto machine  




rem in der "echten" DOS Box muesste der Befehl so lauten:  
rem setx %tmp0% !%tmp0%!
    setx %tmp0% "!%tmp0%!"  

rem Leere Eintraege rauskicken:
    if "!%tmp0%!"=="" regdat3 -d varu.txt  

    echo ------------------------------------
    echo Die User-Variable "%tmp0%" wurde mit setx dauerhaft gesetzt.  
    echo ------------------------------------
    goto end




:machine

rem in der "echten" DOS Box muesste der Befehl so lauten:  
rem setx %tmp0% !%tmp0%! -m


    setx %tmp0% "!%tmp0%!" -m  

rem Leere Eintraege rauskicken:
    if "!%tmp0%!"=="" regdat3 -d varm.txt  

    echo ------------------------------------
    echo Die SystemVariable "%tmp0%" wurde mit setx dauerhaft gesetzt.  
    echo ------------------------------------




:end

    if not errorlevel 1 goto allesok
    echo Bei der Verarbeitung sind Fehler aufgetreten!
    echo ------------------------------------

:allesok
    echo Keine Fehler bei der Verarbeitung.
    echo ------------------------------------
:fin