Kix Daten auswerten

Kix Daten in einer Datenbank oder z.B. Excel Tabelle auswerten

Hallo
habe viel gesucht doch leider nicht gefunden. Ich habe in unserem Netzwerk (200 PC´s) Kix jetzt an den start gebracht. Ich möchte jetzt die Rechner inventarisieren. Bekomme von jedem Rechner eine Txt Datei mit allen Daten.
Habe jetzt aber noch keine Möglichkeit gefunden diese Daten in irgendeiner Form zusammen zu bringen.

Ich hoffe es kann mir jemand helfen.

Es würde mir schon reichen diese Daten in eines Excel Tabelle zusammen zu führen.

Besser natürlich in eine Datenbank. Ich möchte die Daten für den Support auswerten.
Oder Gibt es ein Tool wie z.b. I-doit in dem ich die Daten ausbereiten kann.
Kennt da jemand eine Möglichkeit oder kann mir aus die Sprünge helfen.

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 94636

Url: https://administrator.de/forum/kix-daten-auswerten-94636.html

Ausgedruckt am: 20.04.2025 um 18:04 Uhr

6 Kommentare

Neuester Kommentar

Hallo,

wenn Du schon bei I-doit "angekommen" bist, warum machst Du es denn nich damit oder nagios oder so?

Es gibt hier auch ein TuT wie man mit BGInfo inventrarisieren kann. BGInfo kann auch gleich in eine DB schreiben.

Ralf

Danke.
Diese Tools habe ich mir schon alle angeschaut.
Möchte aber die Daten nutzen die KIx mir ausgibt. Diese Dateien sollen dann importiert werden.
BG Info z.b. kann ja die Daten auslesen. Aber ich kann da ja nicht die txt Datei( von KIx) importieren.
Da wir keinen Linux Rechner im Einsatz haben wollte ich auch hier auf Linux verzichten.
I-doit soll xml Dateien importieren können. Leider habe ich nicht gefunden wo und wie.

Vielleicht kann mir ja jemand helfen.

Wollte auf die oft sehr teuren Tools wie Quadrig usw. verzichten.
Soll wie immer nichts kosten und alles können.

Hi,

ich mache das auch in der Form. Das Loginscript schreibt die Werte per Kix in eine CSV-Datei (alle Werte in eine Textdatei, mit ";" getrennt).
Um die Dateien zusammen zu fassen, habe ich noch Kix-Script, welches einfach alle Dateien einliest und die Zeilen in eine neue Datei untereinander schreibt.
So habe ich dann eine CSV-Datei mit allein Rechnern drin.

Hier das Script:

;----------------------------------------
$path="\\Server1\Logs$\Logon\"  
$tz=";"  
$tempfile="%temp%\logfiles.txt"  
;----------------------------------------

$jahr=@year
If Len(@MONTHNO)=1 $monat="0"+@MONTHNO Else $monat=@MONTHNO EndIf  
If Len(@MDAYNO)=1 $tag="0"+@MDAYNO Else $tag=@MDAYNO EndIf  


$pcfile=$path+"PCs_"+$jahr+$monat+$tag+".csv"  
If Exist ($pcfile) Del ($pcfile) EndIf

Shell "%COMSPEC% /c DIR "+$path+"PCs /b > "+$tempfile  

$handle1=FreeFileHandle()
$rc=Open($handle1,$pcfile,5)
$rc=WriteLine($handle1,"Rechner;User;Berechtigung;Datum;Uhrzeit;Prozessor;Taktfreq.;RAM;Betriebssystem;ServicePack;IP-Adresse;MAC-Adresse;Floppy aktiv;CDRom aktiv;Sitzungsart;HD-Größe;frei(MB);FileSystem"+@CRLF)  

$handle2=FreeFileHandle()
$rc=Open($handle2,$tempfile,2)
$zeile=ReadLine($handle2)
While @ERROR=0
  $handle3=FreeFileHandle()
  $rc=Open($handle3,$path+"PCs\"+$zeile,2)  
  $line=ReadLine($handle3)
  While @ERROR=0
    $lastline=$line
    $line=ReadLine($handle3)
  Loop
  $rc=WriteLine($handle1,SubStr ($zeile,1,Len($zeile)-4)+";"+$lastline+@CRLF)  
  $rc=Close($handle3)
  $zeile=ReadLine($handle2)
Loop
$rc=Close($handle2)
$rc=Close($handle1)
Del ($tempfile)  



$rc=MessageBox("Habe Fertig!",@ScriptName,64)  
Run("Explorer $path")  

Das werde ich Heute mal Probieren.
Vielleicht komme ich dann ja zu dem Ergebnis!!!

Also irgendwie bekomme ich das nicht hin!!!
Deine Daten sind ja auch ganz anders wie meine. kannst Du mir Deine logon.kix mal zeigen vielleicht verstehe ich ja dann was ich immer falsch mach.
Im Mom habe ich keinen Plan!!!

Hi,

der relevante Teil ist dies hier:

; User- und Hardware-Logfile in je eine CSV-Datei schreiben
;----------------------------------------
$path="\\Server\Logs$\Logon\"  
$tz=";"  
;----------------------------------------
If @TsSession=1 $Session="RDP" Else $Session="Konsole" EndIf  
For Each $HD In DiskDriveInfo() $HDSize=$HDSize+$HD[2]+" / " Next $HDSize=Left($HDSize,Len($HDSize)-3)  
$rc=GetDriveSize("%SYSTEMDRIVE%") $HDSizeFree=$rc[1]  
$rc=ScreenRes $Resolution=""+$rc+"x"+$rc[1]  
; Hardware-Daten in CSV-Datei schreiben
$zeile=@USERID+$tz+@PRIV+$tz+@DATE+$tz+@TIME+$tz+Trim(@CPU)+$tz+@MHZ+$tz+MemorySize()+$tz+@ProductType+$tz+@CSD+$tz+@IPADDRESS0+$tz+@ADDRESS+$tz+DiskDriveActive()+$tz+CDRomActive()+$tz+$Session+$tz+$HDSize+$tz+$HDSizeFree+$tz+Filesystem("%SYSTEMDRIVE%")+$tz+$Resolution+@CRLF  
$handle=FreeFileHandle()
$rc=Open($handle,$path+"PCs\"+@WKSTA+".csv",5)  
$rc=WriteLine($handle,$zeile)
$rc=Close($handle)
; User-Daten in CSV-Datei schreiben
$zeile=@DATE+$tz+@TIME+$tz+@Wksta+$tz+@PRIV+$tz+@LSERVER+$tz+@PWAGE+$tz+Round((GetFolderSize(H:)/1024/1024),2)+@CRLF
$handle=FreeFileHandle()
$rc=Open($handle,$path+"User\"+@USERID+".csv",5)  
$rc=WriteLine($handle,$zeile)
$rc=Close($handle)