Script für Dateiumbenennung, Speichern anhand des Dateinamens und löschen der Ursprungsdatei

Hallo Administrator Community

Ich habe eine große bitte an euch. Ich benötige ein Script für Adobe Acrobat, mit dem ich verschiedene zeitraubende Aktionen automatisieren kann.

In meinem Praktikum muss ich durchlaufend nummerierte Texte einscannen (Eingabe der Nummer über das Scanner Touchpad), doch leider speichert der Scanner sinnlose Zahlen die ich später manuell löschen muss.

z.B 199-023 123456.pdf

Und dann muss die Datei noch in zwei unterschiedliche Laufwerke gespeichert werden.

z.B E:\ECWR\KOMMENTARE\199\ und G:\INTERN\KOMMENTARE\199\

also immer jene Ordner, die gleich sind mit den ersten 3 Ziffern des Dateinamens.

Und wenn das geschehen ist, muss man die Ursprungsdatei, welche auf der lokalen Festplatte ist noch löschen.

z.B C:\SCANS\

Könnt ihr mir vielleicht helfen ein Script zu erstellen, so das Acrobat nach dem automatischen optimieren und Texterkennen diese Aktionen ausführt?

Hier nochmal die Zusammenfassung was das Script tun soll:

1. lösche von hinten die letzten 7 Zeichen (aber nicht die Dateiendung .pdf) aller vorhandenen Dateien im Ordner "C:\SCANS\"
2. speichere die Dateien auf den beiden Laufwerkspfaden in den Ordner, der die mit den ersten 3 Ziffern der Datei übereinstimmt
3. lösche die Ursprungsdatei

Ich glaube wenn ich bei meinem Praktikum mit solchen Optimierungen aufwarten kann die nächste freie Stelle bekommen werde.

Vielen Dank und freundliche Grüße aus Wien, Roman

echo off &setlocal
for %%a in ("C:\SCANS\*.pdf") do (  
    set "filename=%%~a"  
    set "fname=%%~na"  
    set "fext=%%~xa"  
    setlocal enabledelayedexpansion
    set "nname=!fname:~0,-7!"  
    set "fpre=!fname:~0,3!"  
    copy "!filename!" "E:\ECWR\KOMMENTARE\!fpre!\!nname!!fext!"  
    copy "!filename!" "G:\INTERN\KOMMENTARE\!fpre!\!nname!!fext!"  
    del "!filename!"  
    endlocal
)

echo off & setlocal
for %%a in ("C:\SCANS\*.pdf") do (  
    for /f "tokens=1-2 delims=- " %%i in ("%%~na") do (  
        echo copy "%%a" "E:\ECWR\KOMMENTARE\%%i\%%i-%%j%%~xa"  
        echo copy "%%a" "G:\INTERN\KOMMENTARE\%%i\%%i-%%j%%~xa"  
        echo del "%%a"  
    )
)

> echo off &setlocal
> for %%a in ("N:\RWOCR\SCANS\Aktionsassistent für Optimierung & OCR-Texterkennung\*.pdf") do (  
>     set "filename=%%~a"  
>     set "fname=%%~na"  
>     set "fext=%%~xa"  
>     setlocal enabledelayedexpansion
>     set "nname=!fname:~0,-15!"  
>     set "fpre=!fname:~0,3!"  
>     copy "!filename!" "Q:\!fpre!\!nname!!fext!"  
>     copy "!filename!" "N:\RWOCR\FILME\!fpre!\!nname!!fext!"  
>     del "!filename!"  
>     endlocal
> )
>