25.05.2010

8114

Add To Domain Vorschläge mit netdom

Habt Ihr ein paar Vorschläge was man hier noch ändern könnte?!?!

@echo off & setlocal
net use z: \\servershare\directory
SET /p MAC=MAC-Addresse der neuen VMware eingeben:
REG add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Class\{4D36E972-E325-11CE-BFC1-08002bE10318}\0001" /v NetworkAddress /t REG_SZ /d %MAC% /f  

SET /p COMPUTER=Computernamen der neuen VMware eingeben:
REG add "HKLM\SYSTEM\ControlSet001\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d %COMPUTER% /f  

SET /p COMPUTER=Computernamen der neuen VMware wiederholen:
Z:\servershare\directory\netdom.exe JOIN %COMPUTER% /Domain:domänenpfad.biz /UserO:_admin_user /PasswordO:* 

PAUSE
shutdown -r -t 10

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 143492

Url: https://administrator.de/forum/add-to-domain-vorschlaege-mit-netdom-143492.html

Ausgedruckt am: 22.04.2025 um 21:04 Uhr

12 Kommentare

Neuester Kommentar

aus welchem grund bringt er mir sehr oft die Meldung: NETZWERKPFAD WURDE NICHT GEFUNDEN????? Über die GUI Oberfläche klappts immer, ueber CMD nicht

Zitat von @84075:

aus welchem grund bringt er mir sehr oft die Meldung: NETZWERKPFAD WURDE NICHT GEFUNDEN????? Über die GUI Oberfläche
klappts immer, ueber CMD nicht

Ach jetzt hab ich den Fehler raus!!
ich muss zuerst in zeile 13 nicht JOIN ausführen sondern zuerst ADD. Danach ein Neustart und dann soll er JOIN machen nur wie sage ich dem Skript das er nach dem Neustart JOIN machen soll???

Hallo cyaency!

nur wie sage ich dem Skript das er nach dem Neustart JOIN machen soll???

Du könntest bei ersten Durchlauf des Scripts eine Datei erstellen und beim zweiten Durchlauf prüfen, ob diese vorhanden ist, also etwas in der Art:

@echo off & setlocal
set "Check=%temp%\Warschonda.txt"  

if exist "%Check%" goto :ZweiterDurchlauf  
>"%Check%" echo\  
echo Erster Durchlauf
:: was eben so anliegt ...
goto :eof

:ZweiterDurchlauf
echo Zweiter Durchlauf
:: Bei Bedarf aufraeumen
:: del "%Check%" 

Du könntest sogar die Nummer des Durchlaufes in der Datei vermerken und so auch feststellen, ob es vielleicht schon der 3. oder 4. Lauf des Batches ist ...

Grüße
bastla

servus bastla,

ja genau sowas in der art brauch ich

))) Das erste Skript das ich ausführe ist folgendes (hier wird am ende ADD ausgeführt):

@echo off & setlocal

net use z: \\caewinsoft\caewinsoft

SET /p MAC=MAC-Addresse der VMware eingeben:
REG add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Class\{4D36E972-E325-11CE-BFC1-08002bE10318}\0001" /v NetworkAddress /t REG_SZ /d %MAC% /f  

SET /p COMPUTER=Computernamen der VMware eingeben:
REG add "HKLM\SYSTEM\ControlSet001\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d %COMPUTER% /f  

SET /p DOMAINPC=Computernamen der VMware wiederholen:
Z:\server\netdom.exe ADD %DOMAINPC% /Domain:domainpfad /UserD:_admin_user /PasswordD:* 

PAUSE
shutdown -r -t 0

Dann nachdem Neustart soll die folgende cmd2.bat ausgeführt werden:

@echo off & setlocal
net use z: \\server\share
SET /p DOMAINPC=Computernamen der VMware wiederholen:
Z:\server\netdom.exe JOIN %DOMAINPC% /Domain:domainpfad /UserD:_admin_user /PasswordD:*
PAUSE
shutdown -r -t 0

Wie baue ich denn nun deinen Vorschlag hier ein? Beide *.bat Files befinden sich unter C:\tmp
Ich danke dir im voraus!

Hallo cyaency!

@echo off & setlocal
::Schritt nur einmal ausfuehren 
if exist "%temp%\Step1.txt" goto :Step2  

net use z: \\caewinsoft\caewinsoft
SET /p MAC=MAC-Addresse der VMware eingeben:
REG add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Class\{4D36E972-E325-11CE-BFC1-08002bE10318}\0001" /v NetworkAddress /t REG_SZ /d %MAC% /f  

SET /p COMPUTER=Computernamen der VMware eingeben:
REG add "HKLM\SYSTEM\ControlSet001\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d %COMPUTER% /f  
REG add "HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d %COMPUTER% /f  

SET /p DOMAINPC=Computernamen der VMware wiederholen:
Z:\server\netdom.exe ADD %DOMAINPC% /Domain:domainpfad /UserD:_admin_user /PasswordD:* 

PAUSE
>"%temp%\Step1.txt" echo\  
shutdown -r -t 0

:Step2
::Schritt nur einmal ausfuehren
if exist "%temp%\Step2.txt" goto :eof  

net use z: \\server\share
SET /p DOMAINPC=Computernamen der VMware wiederholen:
Z:\server\netdom.exe JOIN %DOMAINPC% /Domain:domainpfad /UserD:_admin_user /PasswordD:*
>"%temp%\Step2.txt" echo\  
PAUSE
shutdown -r -t 0

Im einfachsten Fall kannst Du den Batch in den "Autostart"-Ordner legen - die beiden Dateien "%temp%\Step1.txt" und "%temp%\Step2.txt" sorgen dafür, dass jeder Schritt nur einmal ausgeführt wird.

Grüße
bastla

step1.txt und step2.txt werden automatisch angelegt sowie ich das sehe also nur diese batch ausführen ????

... also nur diese batch ausführen ????

Das wäre der Plan ...

Grüße
bastla

klappt natürlich wunderbar

ich führe das skript aus rechner startet neu. Nachdem neustart führeich das skript nochmals aus und rechner ist in der domäne. Eine letzte Frage hätte ich...ist es möglich dem Skript zu sagen das er nachdem neustart das skript selber ausführen soll ohne das ich doppelklicke?

Wäre es denn möglich das ich die Eingaben die ich dann beim joinen eingebe bereits irgendwo abgespeichert abruft???Es sind nämlich die gleichen Eingaben wie bei ADD.

Am liebsten hätte ich das ganze ohne Neustart erledigt, ist wohl nicht möglich?!?!?
Naja falls nicht wäre es nicht schlecht wenn ich im skript etwas einbaue wo er dann automatisch ohne meine interaktion das skript startet.

Hallo cyaency!

ist es möglich dem Skript zu sagen das er nachdem neustart das skript selber ausführen soll ohne das ich doppelklicke?

Leg den Batch doch einfach in den Autostart des Users, mit dem Du die Aktionen ausführst ...

Wäre es denn möglich das ich die Eingaben die ich dann beim joinen eingebe bereits irgendwo abgespeichert abruft???Es sind nämlich die gleichen Eingaben wie bei ADD.

Mit einer passenden Wahl des Variablennamens lassen sich auch mehrere Werte recht einfach in einer Textdatei zwischenspeichern und später wieder als Variable einlesen - ungetestet etwa so:

SET /p _COMPUTER=Computernamen der VMware eingeben: 
SET "_DOMAINPC=%_COMPUTER%"  
SET /p _DOMAINPC=Computernamen der VMware wiederholen (Enter fuer %_COMPUTER%): 
...
set _>%temp%\Variable.txt

Zum Einlesen der gespeicherten Variablen dann einfach an passender Stelle:

for /f "delims=" %%i in (%temp%\Variable.txt) do set "%%i"

Grüße
bastla

du bist ab heute mein BATCH-GURU

)))))

da ich mich ja wenig auskenne noch kurze starthilfe, bitte:

1. in dem o.g. skript von dir - wo baue ich die soeben erwähnten codezeilen ein? in welcher zeile zwischen 1 und 31???
2. wo baue ich for /f "delims=" %%i in (%temp%\Variable.txt) do set "%%i" ein? in welcher zeile zwischen 1 und 31???
3. ich möchte eigetlich alle Eingaben die ich vor dem Neustart gemacht habe speichern damit ich im STEP2 nicht mehr eingeben muss
DANKE DANKE DANKE im voraus grosser Guru

Hallo cyaency!

Lass mal stecken ...

Der erste Block passt dort, wo alle Eingaben erfolgt sind - also nach Zeile 15

Das Einlesen wird für den "Step2" benötigt, daher zB als Ersatz der Zeile 27

Grüße
bastla