Alte Server Verknüpfung bei Clients löschen

Hallo zusammen,

ich habe eine Problem nach einer Server-Migration von SBS2003 auf Server 2012.
In einem bestehenden Netzwerk mit SBS2003 Server (DNS und DHCP auf dem Server aktiv) und mehreren Win7 und Win8 Clients wurde der Server durch einen 2012ér Server abgelöst. Dazu wurde der neue Server in die Domäne des SBS2003 Servers aufgenommen und der 2012ér dann als Domänen Master benannt. Damit hatte der 2012ér Server dann alle AD-Daten, DNS-Einträge usw. Der SBS2003 Server wurden dann abgeschaltet.
Auf den Clients gabe es per Login Script verschiedene freigegebene Laufwerke des alten Servers mit Namen "\\Server\\xxx". Diese wurden per neuem Login Script auf den neuen Server mit Namen "\\Server1\xxx umgeschlüsselt. Soweit so gut dies hat alles funktioniert.
Dann wurde auf den Clients aus Office365 noch die neue Office 2013 Version aufgespielt. Die Clients benutzen in Word und Excel Vorlagen. Diese haben sich auf einer Laufwerksverknüpfung Namens "\\Server\Vorlagen" befunden. Die Vorlagen wurden in gleichnamiges Verzeichnis auf dem neuen Server kopiert "\\Server1\Vorlagen" und entsprechend mit einem Laufwerksbuchstaben verknüpft.

Jetzt kommt der Fehler: Öffnet ein Client eine Word- oder Excel-Datei, die über eine Vorlage auf dem alten Server erstellt wurde, dann braucht das öffnen der Datei teilweise bis zu einer Minute. Es kommt zusätzlich auch eine Fehlermeldung, dass die Vorlage auf "\\Server\Vorlagen" nicht gefunden werden kann. Klickt man diese weg, wird die Datei geladen. Dieser Vorgang dauert aber wie beschrieben bis zu einer Minute für eine Datei die nur wenige KB groß ist.


Versuch der Fehlerbehebung: Es wurde auf dem 2012ér Server im DNS ein zusätzlicher Alias Namen "Server" angelegt mit dem verweis auf die IP-Adresse des "Server1". Pingen kann man den Server jetzt unter beiden Namen.
Dann wurde auf allen Clients der DNS Cache mit ipconfig /flushdns gelöscht. Bis dorthin war in der Netzwerkübersicht sogar noch der Alter Server "Server" sichtbar.
Ein Versuch einer Laufwerksverknüfung mit "\\Server\Voralgen" auf einem der Clients scheiter allerdings. Eine Verknüpfung mit "\\Server" fördert sogar alte Laufwerksfreigaben des SBS2003 Servers in der Übersicht zu Tage.

Wie kann ich den Pfad der wohl beim Starten von Office Dokumenten die über eine Vorlage erstellt wurden und im Hintergrund immer noch versuchen, die Vorlage dazu unter "\\Server\Vorlagen" zu finden so umbiegen, dass diese die Vorlage jetzt unter "\\Server1\Vorlagen" suchen? Und warum braucht ein Office Dokument überhaupt die ehemalige Vorlage wieder? Dann könnte doch auch keiner außerhalb der Firma ein Dokument öffnen, dass mit einer Vorlage erstellt wurde?

Kann mir jemand bei diesem Problem helfen, ich bastele daran jetzt schon mehrere Tage rum und hab auch schon genügend in Foren gesucht und gelesen.

Vielen Dank schon mal...

debug.print ActiveDocument.AttachedTemplate.FullName

'Pfad zu den Dokumenten  
Const strPathDocs = "\\Server1\docs"  
'Logfile für eventuell auftretende Fehler  
Const strPathLogfile = "c:\logfile.txt"  
'Alter Servername  
Const strOldServer = "\\Server"  
'Neuer Servername  
Const strNewServer = "\\NewServer"   

Set fso = Wscript.CreateObject("Scripting.Filesystemobject")  
Set objWord = WScript.CreateObject("Word.Application")  
'Wenn das ganze unsichtbar ablaufen soll nächste Zeile auf false setzen  
objWord.Visible = True
objWord.DisplayAlerts = 0
'Im Ordner Rekursiv alle Word-Dokumente verarbeiten  
parseFolders fso.GetFolder(strPathDocs), True
objWord.DisplayAlerts = -1
objWord.Quit True
Set fso = Nothing
Set objWord = Nothing

Function parseFolders(fldr, boolRecursion)
    
    For Each file In fldr.Files
   		'Verarbeite nur Dateien mit den Endungen *.doc, *.docx, *.docm   
        If LCase(Right(file.Name, 3)) = "doc" Or LCase(Right(file.Name, 4)) = "docx" Or LCase(Right(file.Name, 4)) = "docm" Then  
            On Error Resume Next
            Set objDoc = objWord.Documents.Open(file.Path)
            If Err.Number <> 0 Then
            	Set objLog = fso.OpenTextFile(strPathLogfile,8,True)
            	objLog.WriteLine("Fehler beim öffnen der Datei: -> " & file.Path)  
            	objLog.Close
            Else
              Set dlgTemplate = objWord.Dialogs(87)
              If InStr(1,dlgTemplate.Template,strOldServer,1) Then
                        ' neuen Templatepfad erstellen  
	            	newTemplate = Replace(dlgTemplate.Template,strOldServer,strNewServer,1,1,1)
	            	' Alle alten Vorlageninformationen entfernen  
	            	objDoc.RemoveDocumentInformation (9)
	            	' Neue Vorlage zuweisen  
	            	objDoc.AttachedTemplate = newTemplate
		        ' Dokument speichern  
		        objDoc.Save
		        objDoc.Close True
	      Else
	       		objDoc.Close False
              End If
            End if
        End If
    Next
    
    If boolRecursion Then
		For Each subFolder in fldr.SubFolders
			parseFolders subFolder, True
		Next
	End If
End Function

'Pfad zu den Dokumenten
Const strPathDocs = "\\Server1\docs"
'Logfile für eventuell auftretende Fehler
Const strPathLogfile = "c:\logfile.txt"
'Alter Servername
Const strOldServer = "\\Server"
'Neuer Servername
Const strNewServer = "\\NewServer"