Auslesen der Datei und dann umbennen

Hallo !
Hoffe auf eure Hilfe und ja ich habe das Forum vorher durchgelesen. Finde aber keine passende Antwort mit der es gelingt.

Habe viele Datein in meinem Unterverzeichnis nach folgedem Muster:

Variante 1: 00626E4032FF()_1_20120804172115_3245.jpg = Aufgenommen 04.08.2012 17:21:15 Uhr
Variante 2: 00EA21634B5D()_1_20120728212744_3390.jpg = Aufgenommen 28.07.2012 21:27:44 Uhr

Diese befinden sich in vielen Unterverzeichnissen.

Also in den Verzeichnissen sollen sie blieben aber automatisch umbenannt werden nach folgedem Schema:
HH-MM-SS__TAG-MONAT-JAHR.jpg

Kann mir da bitte jemand helfen ?

Grüße

Marc

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Kommentar vom Moderator Biber am 04.08.2012 um 23:33:33 Uhr

Auslesen der Datei und dann umbennen

tiefer Seufzer
Same procedure as last thread
#842

Content-ID: 189119

Url: https://administrator.de/forum/auslesen-der-datei-und-dann-umbennen-189119.html

Ausgedruckt am: 15.04.2025 um 15:04 Uhr

8 Kommentare

Neuester Kommentar

Hallo Marc.P.Neumann!

[OT]
Bibers "Running Gag Counter" wird dich wohl auch diesmal wieder ereilen.
Ich glaube, wenn du dieses Forum nach dem Stichwort "Umbennen" durchsuchst, gibt es mehr Hits als würdest du nach "Umbenennen" suchen. Schon erstaunlich

[/OT]

Teste:

@echo off &setlocal
for /r %%i in (*.jpg) do (
  for /f "tokens=3 delims=_" %%j in ("%%~ni") do (  
    if "%%j" neq "" (  
      set "file=%%i"  
      set "d=%%j"  
      setlocal EnableDelayedExpansion
        ECHO ren "!file!" "!d:~8,2!-!d:~10,2!-!d:~-2!__!d:~6,2!-!d:~4,2!-!d:~,4!.jpg"  
      endlocal
    )
  )
)
PAUSE

Entferne ECHO und PAUSE, wenn du glaubst es würde funktionieren.

Grüße
rubberman

Super Danke !!!

Gibts denn irgendwo sowas zum lernen für Dummys ? Irgendwas zum empfehlen?

Zitat von @Marc.P.Neumann:

Gibts denn irgendwo sowas zum lernen für Dummys ?

Hallo Marc.P.Neumann!

[_days=3650&id=1101995812#content-6-tab da] und nicht zuletzt dort, sowie [OT]dies[/OT].

Grüße
rubberman

Hallo rubberman!

Die Variable !file! fällt eigentlich unter "Luxus" ...

Grüße
bastla

Hallo bastla!

Nicht so ganz. Denk mal an das "DelayedExpansion".
Im vorliegenden Fall solltest du aber recht haben, da es unwahrscheinlich ist, dass sich ein '!' im Dateiname verbirgt (aber vielleicht im Pfad?).

Grüße
rubberman

Hallo rubberman!

Eigentlich hatte ich gemeint, dass Du gleich "%%i" verwenden könntest [Edit] - aber Du hast schon recht

- darauf wirkt sich letztlich "delayedexpansion" auch aus [/Edit] ...

Grüße
bastla

Hallo bastla!

Genau das hatte ich auch gemeint

Zum Test:

@echo off &setlocal
>abc!def.ext type nul
for %%i in (*.ext) do (
  set "file=%%i"  
  setlocal EnableDelayedExpansion
    echo %%i
    echo !file!
  endlocal
)
pause