Definierten Abschnitt aus Textdokument in Excel importieren

Sub Importieren()
Datei = "D:\Textdokument.txt"  
Von = "NORMALSTRESS" 'ab Zeile mit diesem Inhalt importieren  
Bis = "FLOWSTRESS" 'ab Zeile mit diesem Inhalt nicht mehr importieren  
Trenn = " " 'Leerzeichen als Trennzeichen zwischen den Feldern  
'Trenn = vbTab 'TAB als Trennzeichen zwischen den Feldern  

SpNr = 1 'Daten ab Spalte A ...  
ZNr = 3 'der Zeile 3 eintragen  


Set DateiEin = CreateObject("Scripting.FileSystemObject").OpenTextFile(Datei) 'Textdatei öffnen  
Fertig = False 'Schalter initialisieren  
Import = False 'Schalter initialisieren  
Do While Not DateiEin.AtEndOfStream And Not Fertig
    Satz = DateiEin.ReadLine 'Datensatz aus Datei einlesen  
    If Import Then 'Satz ist zu importieren  
        If InStr(Satz, Bis) = 0 Then 'Ende des Datenbereiches noch nicht erreicht  
            SatzEintragen Satz, ZNr, SpNr 'eingelesenen Satz in Tabellenzeile ZNr ab Spalte SpNr eintragen  
            ZNr = ZNr + 1 'nächste Tabellenzeile  
        Else
            Fertig = True 'Ende des vorgegebenen Bereiches - keine weiteren Daten einlesen  
        End If
    Else 'bisher wurde nicht importiert - ...  
        If InStr(Satz, Von) > 0 Then '... beginnt hier der Datenbereich?  
            Import = True 'ja; ab jetzt Zeilen importieren  
            SatzEintragen Satz, ZNr, SpNr 'eingelesenen Satz in Tabellenzeile ZNr ab Spalte SpNr eintragen  
            ZNr = ZNr + 1 'nächste Tabellenzeile  
        End If
    End If
Loop
DateiEin.Close 'Textdatei schließen  
MsgBox "Fertig."  
End Sub

Sub SatzEintragen(D, Z, S)
Felder = Split(D) 'Zeile in Felder zerlegen  
Cells(Z, S).Resize(1, UBound(Felder) + 1).Value = Felder 'in der Zeile Z die Spalten ab Spalte S mit den Feldwerten füllen  
End Sub