Mit Batch Job eine bestimmte Zeile von einer XML- in eine andere XML-Datei übertragen

Hallo,

ich möchte aus der Datei "c:\config\config.xml" den Inhalt der Zeile 4 (<ID>wert</ID>) in die Datei "c:\update\config.xml" (<ID>standardwert</ID>) auch Zeile 4 übertragen. Hab schon einiges versucht, aber irgendwie will es nicht.

Leider muss es ein Batch-Job sein.

Schon mal Danke für Eure Hilfe

LG
Marius

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 219664

Url: https://administrator.de/forum/mit-batch-job-eine-bestimmte-zeile-von-einer-xml-in-eine-andere-xml-datei-uebertragen-219664.html

Ausgedruckt am: 29.04.2025 um 23:04 Uhr

2 Kommentare

Neuester Kommentar

Hallo MariusAP und willkommen im Forum!

Wenn es nur darum geht, die gesamte Zeile 4 auszutauschen, könntest Du es so versuchen:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off & setlocal
set "Quelle=c:\config\config.xml"  
set "Ziel=c:\update\config.xml"  
set /a ZNr=4

set "XMLTemp=%temp%\xml.tmp"  
for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%Quelle%"^|findstr /b "%ZNr%:"') do set "ZeileNeu=%%j"  
move "%Ziel%" "%XMLTemp%"  
(for /f "tokens=1* delims=:" %%i in ('findstr /n "^" "%XMLTemp%"') do (  
    set "Zeile=%%j"  
    setlocal enabledelayedexpansion
    if %%i==%ZNr% (
        echo(!ZeileNeu!
    ) else (
        echo(!Zeile!
    )
    endlocal
))>>"%Ziel%"  
del "%XMLTemp%"  