MSAccess xml-Datei nach Vorlage(Schema) erzeugen

Sub ExportDataToXMLSchema()
    Dim db As Database, rs As Recordset, xml As Object, pi As Object, root As Object, client As Object, el As Object, dbFolder As String, fso As Object, c As Long
    ' process current database  
    Set db = CurrentDb
    ' create XML Document  
    Set xml = CreateObject("MSXML2.DomDocument.6.0")  
    Set fso = CreateObject("Scripting.FileSystemObject")  
    Set pi = xml.createProcessingInstruction("xml", "version=""1.0"" encoding=""utf-8""")  
    xml.insertBefore pi, xml.childNodes.Item(0)
    ' create document element  
    Set root = xml.createElement("Adressen")  
    ' and add it to the document  
    xml.appendChild root
    ' get data from the source table  
    Set rs = db.OpenRecordset("Kunden")  
    ' move to the first recordset  
    rs.MoveFirst
    ' process each record from data source  
    While Not rs.EOF
        ' create element for row  
        Set client = xml.createElement("Kunde")  
        ' append the row node to the document element  
        root.appendChild client
        ' for each column in the record  
        For c = 0 To rs.Fields.Count - 1
            ' create a new element  
            Set el = xml.createElement(rs.Fields(c).Name)
            ' and assign the data from the column to the element  
            el.Text = rs.Fields(c).Value
            ' append the element as childnode to he row node  
            client.appendChild el
        Next
        ' process next row  
        rs.MoveNext
    Wend
    ' get the folder of the current database  
    dbFolder = fso.GetParentFolderName(db.Name)
    ' save the xml as a file  
    xml.Save dbFolder & "\" & "test-export.xml"  
End Sub

<?xml version="1.0" encoding="utf-8"?>  
<Adressen>
	<Kunde>
		<ID>1</ID>
		<Vorname>Max</Vorname>
		<Nachname>Muster</Nachname>
		<Straße>Musterstr. 55</Straße>
		<PLZ>66666</PLZ>
		<Ort>Musterhausen</Ort>
	</Kunde>
	<Kunde>
		<ID>2</ID>
		<Vorname>Erika</Vorname>
		<Nachname>Musterfrau</Nachname>
		<Straße>Musterweg 11</Straße>
		<PLZ>99999</PLZ>
		<Ort>Musterdorf</Ort>
	</Kunde>
</Adressen>