Service-PC soll, wenn kein anderer PC im Netz ist, nach Zeit X, selber ausschalten.

Hallo Alaska,

auf die Idee mit einer BATCH-Datei hätte ich eigentlich auch kommen können.
Ich benutze solche selbstgeschriebenen Dateien zum archivieren / sortieren / sichern von Dateien seit mehr als 15 Jahren. Selbst unter WinXP kein Problem. Davor habe ich mich mit BASIC über Wasser gehalten J.

Danke für den Tipp.

Hallo Pretre,

einfach mal bei GOOGLE ?batch? (deutsch) eingeben. Die ersten 10 Einträge sehen vielversprechend aus.

vy 73 Andreas

So funktioniert schon mal;

Programm:

@echo off
cls
set ip=3
IF EXIST ping.txt del ping.txt

:start

ping -w 25 -n 1 192.168.200.%ip% | FIND "TTL" >nul
if not errorlevel 1 echo 192.168.200.%ip% >ping.txt
if /i %ip% NEQ 10 set /a ip=%ip%+1
if %ip% NEQ 10 goto start

IF EXIST ping.txt goto ende
IF NOT EXIST ping.txt shutdown -u -t 10

:ende

echo.
echo Suche abgeschlossen.
echo.

Leider nur unter WinXP !
Unter Win98 funktioniert die Schleife mit Zähler nicht!

Wer hat da eine Idee ?

vy 73 Andreas

Hallo zusammen,

nach einigen Versuchen nun das Ergebnis:

@echo off
IF EXIST ping.txt del ping.txt
cls
set C1=0
echo.
echo Clients im Netzwerk:
echo. >ping.txt
:LOOP
ECHO Suche 192.168.0.%C1%
ping -w 25 -n 1 192.168.0.%C1% | FIND "TTL" >nul
if not errorlevel 1 echo 192.168.0.%C1% >>ping.txt
XCALC %C1% + 1
SET STEP=M1
SET VAR=C1
GOTO ENV
:M1
IF ERRORLEVEL 254 GOTO EXIT
GOTO LOOP
:ENV
FOR %%a IN (0 1 2) DO IF ERRORLEVEL %%a00 SET $1=%%a
GOTO %$1%
:2
FOR %%a IN (0 1 2 3 4 5) DO IF ERRORLEVEL 2%%a0 SET $2=%%a
FOR %%a IN (0 1 2 3 4 5 6 7 8 9) DO IF ERRORLEVEL 2%$2%%%a SET $3=%%a
IF NOT '%$1%%$2%%$3%' == '259' GOTO SET_E
FOR %%a IN (0 1 2 3 4 5) DO IF ERRORLEVEL 2%$2%%%a SET $3=%%a
GOTO SET_E
:1
:0
FOR %%a IN (0 1 2 3 4 5 6 7 8 9) DO IF ERRORLEVEL %$1%%%a0 SET $2=%%a
FOR %%a IN (0 1 2 3 4 5 6 7 8 9) DO IF ERRORLEVEL %$1%%$2%%%a SET $3=%%a
:SET_E
SET %VAR%=%$1%%$2%%$3%
IF NOT '%$1%'== '0' GOTO OK
SET %VAR%=%$2%%$3%
IF NOT '%$2%'== '0' GOTO OK
SET %VAR%=%$3%
:OK
SET $1=
SET $2=
SET $3=
GOTO %STEP%
:EXIT
SET C1=0
:ende
Find /C "192.168.0" ping.txt
if errorlevel 1 rundll32.exe shell32.dll,SHExitWindowsEx 1
echo.
echo Suche abgeschlossen.

Zeile 17 (IF ERRORLEVEL 254 GOTO EXIT) der Wert entspricht den vorhandenen Rechnern, die überwacht werden sollen.
Zeile 4 (set C1=0) Beginn mit Adresse 0

XCALC Uraltes Basicprogramm (Compailt in exe für einen 80286)

vy 73 Andreas