VBScript, Active Directory User Properties auslesen

OPTION EXPLICIT

Dim objDSE
Dim strAdPfad
Dim objWF
Dim objFile
Dim objLdapConnection
Dim objAdObject
Dim strsollname
Dim intgesamt
Dim intneu
Dim strAdresses
Dim strPEMail
Dim strNewName

intgesamt = 0
intneu = 0

Set objDSE = GetObject("LDAP://rootDSE")  
Set objWF = CreateObject("Scripting.FileSystemObject")  

Set objFile = objWF.CreateTextFile("C:/Documents and Settings/User/Desktop/Change Display Name/Test.txt", True)  

strAdPfad = "ou=Users," & objDSE.Get("defaultNamingContext")  

Set objLdapConnection = GetObject("LDAP://" & strAdPfad)  

For Each objAdObject In objLdapConnection
	Select Case objAdObject.Class
	Case "user"  
		If objAdObject.AccountDisabled = FALSE Then
			strPEMail = ""  
			On error Resume Next
			For Each strAdresses In objAdObject.proxyAddresses
				If instr(1,strAdresses,"SMTP") Then  
					strPEMail = Replace(strAdresses,"SMTP:","")  
				End If
			Next
			strsollname = objAdObject.sn & " " & objAdObject.givenname & " (" & strPEMail & ")"   
			intgesamt = intgesamt + 1
			If objAdObject.displayname = strsollname Then
				WScript.echo objAdObject.samaccountname & " in Ordnung"  
			Else
				WScript.echo objAdObject.samaccountname & " geändert"  
				If strPEMail = "" Then  
					strNewName = objAdObject.sn & " " & objAdObject.givenname  
				Else
					strNewName = objAdObject.sn & " " & objAdObject.givenname & " (" & strPEMail & ") "  
				End If
				objFile.WriteLine objAdObject.samaccountname & vbTab & objAdObject.displayname & vbTab & strNewName
				objAdObject.displayname = strNewName
				objAdObject.setinfo
				intneu = intneu + 1
			End If
		End If
	End Select
Next
objFile.Close
Set objWF = Nothing
WScript.echo "Neu geschrieben: " & intneu & " Gesamt: " & intgesamt