Batch-Script für die Messung der Netzwerkgeschwindigkeit

@echo off
cls
::Batch-Script zur Messung der Netzwerkgeschwindigkeit
::Geschrieben von: https://administrator.de/user/kraemer/
::
::Das Script schreibt seine Ergebnisse in das Verzeichnis, aus dem es aufgerufen worden ist. 
::Dieses Verzeichnis sollte auf einem Server liegen ;-)
::Die Zugriffsberechtigungen sind entsprechend zu setzen ^^
::Die TMP-Dateien die auf dem Server erstellt werden, werden nicht automatisch gelöscht, da diese in Normalfall mehrfach genutzt werden.
::CSV-Aufbau: Computer, Startzeit, Endezeit, verbrauchte Zeit, MB/s, Mbit/s

::Konfiguration
set FormelDauer="=ZEITWERT(INDEX(D:D))-ZEITWERT(INDEX(C:C))"  
set FormelMbS="=(INDEX(B:B)/INDEX(E:E))/(24*60*60)"  
set FormelMbitS="=(INDEX(B:B)/INDEX(E:E))/(24*60*60)*8"  
set ScriptLocation=%~dp0

::Programmablauf
::Hier einfach die StartCopy-Funktion mit den gewünschten Größen einfügen
call:StartCopy "1"  
call:StartCopy "5"  
call:StartCopy "50"  
pause
goto:eof

:StartCopy
::Prüfen ob TMP-Datei vorhanden
  if not exist %ScriptLocation%%~1MB.tmp call:CreateTmp %~1
::Beginn ermitteln
  set StartTime=%time%
  echo Beginn der Messung: %StartTime%
::Datei kopieren
  copy %ScriptLocation%%~1MB.tmp %temp%\
::Werte in CSV eintragen
  echo %computername%;%~1;%StartTime%;%time%;%FormelDauer%;%FormelMbS%;%FormelMbitS% >>%ScriptLocation%Zeiten.csv
  echo Ende der Messung: %time%
::Prüfen ob Versuch überhaupt erfolgreich
  fc %ScriptLocation%%~1MB.tmp %temp%\%~1MB.tmp |if %errorlevel%==1 echo %computername% meldet Fehler beim kopieren von %~1MB.tmp >>%ScriptLocation%Fehler.txt
::lokal Aufräumen
  del %temp%\%~1MB.tmp
goto:eof

:CreateTmp
::Temporäre Datei erstellen
  set TmpMB=%~1
  set TmpMulti=1048576
  set /a TmpByte=%TmpMB%*%TmpMulti%
  fsutil file createnew %ScriptLocation%%~1MB.tmp %TmpByte%
goto:eof