Adobe Flash Player Update ohne Nachfrage per (Startup) Skript starten

'Dieses Skript deinstalliert den Flashplayer und installiert  
'im Anschluss die aktuellen Versionen für IE und FF.  
'Korrupte MSI-Installationen werden durch MsiZap ebenfalls  
'entfernt (nur bei Bedarf anwenden)  

Option Explicit

Dim objFSO, strPathLog, strPathUninstaller
Dim strPathFlashAX, strPathFlashPlugin, strPathMmsCfgSource
Dim strPathMsiZap, strSilentSwitch1

'Tip: Wenn sich alle Dateien im selben Verzeichnis befinden:   
	'Einfach Find&Replace benutzen um Pfad anzugeben  
strPathLog = 			"\\servername(keine IP wenn Startupskript)\freigabename\dateiname.txt"  
strPathUninstaller = 	"\\servername(keine IP wenn Startupskript)\freigabename\uninstall_flash_player.exe"  
strPathFlashAX = 		"\\servername(keine IP wenn Startupskript)\freigabename\install_flash_player_ax.exe"  
strPathFlashPlugin = 	"\\servername(keine IP wenn Startupskript)\freigabename\install_flash_player_plugin.exe"  
strPathMmsCfgSource = 	"\\servername(keine IP wenn Startupskript)\freigabename\mms.cfg"  
strPathMsiZap =			"\\servername(keine IP wenn Startupskript)\freigabename\MsiZap.exe"  
strSilentSwitch1 = 		" -install" 'früher /s, hätte man auch so lassen können...  
'###############################################################  
'###############################################################  
Set objFSO = CreateObject("Scripting.FileSystemObject")  

If objFSO.FileExists(strPathLog) Then
	'MsgBox "Datei Log existtiert"  
	Const ForReading = 1, ForWriting = 2, ForAppending = 8
	Dim objLogTxt, blnHostnameFound, strLine
	Dim arrFields
	'Datei öffnen  
	'Was passiert, wenn Datei schon geöffnet ist?  
	Set objLogTxt = objFSO.OpenTextFile(strPathLog, ForReading)
	blnHostnameFound = False
	'Prüfen, ob Computername bereits vorhanden ist  
	Do Until objLogTxt.AtEndOfStream
		strLine = objLogTxt.ReadLine
		arrFields = Split(strLine, vbTab, 1, 1)
		'Prüfen, ob mind. 1 Arrayelement exist.  
		If UBound(arrFields) <> -1 Then
			If InStr(1, arrFields(0), getHostname(), 1) Then
				blnHostnameFound = True
				'MsgBox "Hostname gefunden"  
				'Da Computername schon in der Log-Datei vorkommt _  
				'keine Änderungen vornehmen.  
				objLogTxt.Close
				WScript.Quit
			End If
		'Wenn Hostname nicht gefunden wurde und als letzes eine leere Zeile _  
			'an die Split-Funktion übergeben wurde   
			'(Log-Datei endet immer mit neuer leerer Zeile)  
		ElseIf UBound(arrFields) = -1 Then
			Err.Clear 'Muss gemacht werden, damit nicht ErrorLog geschrieben wird  
		End If
	Loop
	objLogTxt.Close
	
	If blnHostnameFound = False Then
		'MsgBox "Hostname nicht gefunden"  
		UnInstallFlashPlayer()
		CopyMmsCfg()
		Set objLogTxt = objFSO.OpenTextFile(strPathLog,ForAppending)
		objLogTxt.Write getHostname() & vbCrLf
		objLogTxt.Close
	End If	
Else
	WScript.Quit
End If

Set objLogTxt = Nothing
Set objFSO = Nothing
'MsgBox "Erfolgreich ausgeführt"  
WScript.Quit
'###############################################################  
'###############################################################  
Function getHostname()
	Dim objWSHNet
	Set objWSHNet = WScript.CreateObject("WScript.Network")  
	getHostname = objWSHNet.ComputerName
	If (Err.Number <> 0) Then
		GetHostname = "Fehler beim Lesen"  
	End If
End Function
'###############################################################  
'###############################################################  
Function UnInstallFlashPlayer()
	Set objFSO = CreateObject("Scripting.FileSystemObject")  
	If objFSO.FileExists(strPathUninstaller) And _
	objFSO.FileExists(strPathMsiZap) And _
	objFSO.FileExists(strPathFlashAX) And _
	objFSO.FileExists(strPathFlashPlugin) Then
		Dim objShell
		Set objShell = WScript.CreateObject("Wscript.Shell")  
		objShell.Run strPathUninstaller & strSilentSwitch1,0,True
		'Flashplayer 10.0.32.18 Active X: Entfernung eventueller korrupter MSI-Installation.  
		'TWA! funktionierte nicht, es klappt aber mit TWG!  
		objShell.Run strPathMsiZap & " TWG! {B7B3E9B3-FB14-4927-894B-E9124509AF5A}",0,True  
		'Flashplayer 10.0.32.18 Plugin: Entfernung eventueller korrupter MSI-Installation.  
		objShell.Run strPathMsiZap & " TWG! {0DFB3DE8-65B9-44FF-AA0A-3BECC5A2BFD1}",0,True  
		objShell.Run strPathFlashAX & strSilentSwitch1,0,True
		objShell.Run strPathFlashPlugin & strSilentSwitch1,0,True	
		'MsgBox "Erfolgreich deinstalliert"  
	Else
		'MsgBox "Adobe_Flash_Un_Installer: Eine oder mehrere Dateien nicht gefunden."  
		WScript.Quit
	End If
End Function
'###############################################################  
'###############################################################  
Function CopyMmsCfg()
	Set objFSO = CreateObject("Scripting.FileSystemObject")  
	Dim strComputer, objWMIService, colItems, objItem
	Dim strPathSystemDirectory, strPathMmsCfgTarget
	
	strComputer = "."  
	Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")  
	Set colItems = objWMIService.ExecQuery("Select * From Win32_OperatingSystem")  

	For Each objItem in colItems
		strPathSystemDirectory = objItem.SystemDirectory
	Next
	strPathMmsCfgTarget = strPathSystemDirectory & "\Macromed\Flash\mms.cfg"  
	objFSO.CopyFile strPathMmsCfgSource, strPathMmsCfgTarget, True
		
	'MsgBox "MMS erfolgreich kopiert"  
End Function
'###############################################################  
'###############################################################