Batch einlesen und suchen aus einer Datei ?

Hi, ich habe folgendes Problem:

Ich will das meine Batch diverse unbekannte Dateien auf ihre Hex-Signatur hin überprüft.
Damit ich nicht alle bekannten Signaturen in der batch per IF Anweisung überprüfen muss,
sollen diese aus einer zweiten Textdatei, die ich als Datenbank verwenden will eingelesen werden.

Die ersten 20 Zeichen lese ich per SFK ein und überprüfe sie dann mit dem IF Befehl.
etwa so:

:start
sfk hexdump -offlen 0 20 %1 >%temp%\finf.tmp

:dallmeier
grep 34484B48 %temp%\finf.tmp
if errorlevel == 1 goto :exe     REM um auf den nächsten Dateityp zu überprüfen. 
echo.
echo Dateityp erkannt: Dallmeier
goto :end

Die Datenbank hatte ich mir in etwa so vorgestellt:
34484B48 Dallmeier
4D5A9000 .exe
25504446 .pdf
52494646 .k26

Frage: Wie greife ich jetzt lesend auf eine zweite Datei zu ?

Das ganze soll auf verschiedenen Rechnern mit unterschiedlichen Windowsversionen laufen.

Wäre toll, wenn mir da irgend jemand einen Tip gegen könnte.

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 122073

Url: https://administrator.de/forum/batch-einlesen-und-suchen-aus-einer-datei-122073.html

Ausgedruckt am: 23.12.2024 um 07:12 Uhr

9 Kommentare

Neuester Kommentar

Hallo Blarks und willkommen im Forum!

Weshalb 20 Zeichen - lässt sich der Typstring nicht exakt extrahieren? Wenn das möglich wäre, würde ich die Suche umkehren und eine Datei "Typenliste" als "Datenbank" verwenden, aus der per "findstr" (oder "grep") die passende Zeile gefiltert und mit einem "for /f" zerlegt werden könnte ...

Ansonsten etwa:

:start
for /f "delims=" %%i in ('sfk hexdump -offlen 0 20 %1') do set "String=%%i"  
set Typ=
for /f "usebackq tokens=1,2" %%i in ("D:\Typenliste.txt") do (echo %String%|findstr "%%i">nul && set "Typ=%%j")  
if not defined Typ echo Kein passender Typ gefunden & goto :eof
echo.
echo Dateityp erkannt: %Typ%

Grüße
bastla

[Edit] "defined" in Zeile 5 korrigiert [/Edit]

Hallo Bastla,

erstmal vielen Dank für Deine schnelle Hilfe!
Ich habe Deinen Vorschlag angepasst & ausprobiert, aber leider bekomme ich beim Aufruf
immer eine "Zugriff verweigert" Fehlermeldung.

Auf meine Typenliste.txt hat aber "Jeder" vollzugriff.
Oder mache ich da einen Denkfehler ?

Hallo Blarks!

Es genügen Leserechte für die "Typenliste.txt" ...

Der Fehler tritt in Zeile 4 auf?

Grüße
bastla

Na, leider gibt mir Vista keinerlei Rückmeldung in welcher Zeile der Fehler auftritt..

Das ganze sieht dann in etwa so aus:

C:\typ.cmd unbekannte

C:\>for /F "delims=" %i in ('sfk hexdump -offlen 0 20 Zelle2_28.07.2009') do set "String=%i"  
C:\>set "String=Zelle2_28.07.2009 :"  
C:\>set "String= >34484B48 FEB3D0D6 08030420 00000000< 4HKH....... .... 00000000"  
C:\>set "String= >01100110 01101000 803E0000 C0024002< .........>....@. 00000010"  
C:\>set Typ= ""  
C:\>for /F "usebackq tokens=1,2" %i in ("c:\finfdb") do (echo   01101000 803E0000 C0024002 00000010 0<......... 1>....@.  | findstr "%i"  1>nul  && set "Typ=%j" )  

C:\>(echo   01101000 803E0000 C0024002 00000010 0<......... 1>....@.  | findstr "34484B48"  1>nul  && set "Typ=Dallmeier" )  
Zugriff verweigert

C:\>if not exist Typ echo Kein passender Typ gefunden   & goto :eof
Kein passender Typ gefunden

Hallo Blarks!

Die enthaltenen Sonderzeichen "<" bzw ">" werden als Umleitung (der Ein- bzw Ausgabe) interpretiert - in Deinem Beispiel wird daher versucht, aus einer Quelle

.........

zu lesen, was natürlich nicht klappen kann ...

Unter Verwendung einer Temporärdatei (analog zu Deiner ursprünglichen Fassung) sollte es aber funktionieren:

@echo off & setlocal
set "Typenliste=D:\Typenliste.txt"  
set "TempFile=%temp%\finf.tmp"  

sfk hexdump -offlen 0 20 %1 >"%TempFile%"  

set "Typ="  
for /f "usebackq tokens=1,2" %%i in ("%Typenliste%") do (findstr "%%i" "%TempFile%">nul && set "Typ=%%j")  
if not defined Typ echo Kein passender Typ gefunden & goto :eof
echo.
echo Dateityp erkannt: %Typ%

Außerdem musste anstelle von "exist" ein "defined" in die anschließende Abfrage (darauf wären wir als nächstes gekommen

) ...
Grüße
bastla

Whow!

Jetzt klappts!
Vielen Dank, ich küsse den Boden unter Deinen Füssen

Bisher habe ich ja mit batchscripten alles hinbekommen, was ich wollte, aber offenbar muss ich mich mit dem
Thema doch noch eingehender beschäftigen. Ein paar von den Befehlen die Du verwendet hast waren mir
komplett unbekannt.

Nochmals vielen Dank für Deine Hilfe!
Viele Grüße & schönes Wochenende,
Jens