Email Benachrichtigung wenn Festplattenplatz unterschritten wird

@echo off&setlocal
for /f "tokens=3" %%i in ('dir /ad /-c^|findstr /c:" Verzeichnis(se)"^|findstr /e /c:" Bytes frei"') do set "DirSize=%%i"  

:: Maximum auf der Linken Vergleichsseite 2147483647 bytes
if %Dirsize% gtr 2147483647 goto :Mail
goto :eof
:Mail
::hier kommt dein Mailsendeding hin

' ===========================================  
' Run this script with administrative rights!  
' ===========================================  



'/////////////////////////////// Configure script's job ///////////////////////////////  

'******************** Customize according to your specific needs **********************  

'------------------ Set event description and job related variables -------------------  

strEventDescription  = "Security Center Stopped"  
strEventLog          = "Application"  
strEventID           = "2"  
strPollingIntervall  = "1"  



'----------------------------- Set WMI Event Filter query -----------------------------  

strEventFilterQuery  = "SELECT * FROM __InstanceCreationEvent" _  
                     & " WITHIN " & strPollingIntervall _  
                     & " WHERE TargetInstance ISA 'Win32_NTLogEvent'" _  
                     & " AND TargetInstance.LogFile='" & strEventLog & "'" _  
                     & " AND TargetInstance.EventIdentifier='" & strEventID & "'"  



'-------------- Set WMI Namespace where the monitored event will occure ---------------  

strEventNamespace    = "root\Cimv2"  



'----------- Set parameters which should be passed to Event Handler script ------------  

strEventHandlerParam = """" _  
                     & "%TargetInstance.LogFile%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.RecordNumber%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.SourceName%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.EventIdentifier%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.EventCode%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.EventType%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.Type%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.Category%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.CategoryString%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.TimeGenerated%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.TimeWritten%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.ComputerName%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.User%" _  
                     & """" _  
                     & " " _  
                     & """" _  
                     & "%TargetInstance.Message%" _  
                     & """"  

'**************************************************************************************  





'//////////////////////////////// Set script variables ////////////////////////////////  

'- Set Event Handler path, quote it and prepare it and its working directory for WMI --  

Set FSO           = CreateObject("Scripting.FileSystemObject")  

strEventHandlerWD = Replace(FSO.GetParentFolderName(WScript.ScriptFullName), "\", "\\")  

strEventHandler   = Replace(strEventDescription, " ", "") & "EventHandler.vbs"  
strEventHandler   = """" & strEventHandlerWD & "\\" & strEventHandler & """"  

Set FSO           = Nothing



'----------------------- Test for existing Event Handler script -----------------------  

Set FSO = CreateObject("Scripting.FileSystemObject")  

If Not FSO.FileExists(Replace(Replace(strEventHandler, "\\", "\"), """", "")) Then  
  MsgBox "The Event Handler script " & vbCRLF _  
          & Replace(strEventHandler, "\\", "\") & vbCRLF _  
          & "does not exist. Please create it.", _  
         vbExclamation, _
         "Missing Event Handler script"  
End If

Set FSO = Nothing



'-------------------------- Build parameters for CScript.exe --------------------------  

strCScriptParam = strEventHandler & " " & strEventHandlerParam  



'---------------- Get path of Windows Directory and prepare it for WMI ----------------  

Set WshShell    = WScript.CreateObject("WScript.Shell")  

strWinDir       = Replace(WshShell.ExpandEnvironmentStrings("%SystemRoot%"), "\", "\\")  

Set WshShell    = Nothing
 


'---------------------- Set path of CScript.exe prepared for WMI ----------------------  

setCScriptPath  = strWinDir & "\\System32\\cscript.exe"  





'////////////////////////// Install permanent Event Consumer //////////////////////////  

'------- Get WMI Scripting API object (SWbemServices), Namespace: Subscription --------  

strComputer                          = "."  
Set objWMIService                    = GetObject("winmgmts:" _  
                                                 & "{impersonationLevel=impersonate}!" _  
                                                 & "\\" & strComputer & "\root\Subscription")  



'------------------------------ Create the Event Filter -------------------------------  

Set objFilterClass                   = objWMIService.Get("__EventFilter")  
Set objFilter                        = objFilterClass.SpawnInstance_()

objFilter.Name                       = strEventDescription & " Event Filter"  
objFilter.EventNamespace             = strEventNamespace
objFilter.QueryLanguage              = "WQL"  
objFilter.Query                      = strEventFilterQuery

Set EventFilterPath                  = objFilter.Put_()



'----------------------- Create the Commandline Event Consumer ------------------------  

Set objEventConsumerClass            = objWMIService.Get("CommandLineEventConsumer")  
Set objEventConsumer                 = objEventConsumerClass.SpawnInstance_()

objEventConsumer.Name                = strEventDescription & " Commandline Event Consumer"  
objEventConsumer.CommandLineTemplate = setCScriptPath & " " & strCScriptParam  
objEventConsumer.ExecutablePath      = setCScriptPath
objEventConsumer.WorkingDirectory    = strEventHandlerWD
objEventConsumer.ShowWindowCommand   = 0

Set CommandlineEventConsumerPath     = objEventConsumer.Put_()



'------------------ Bind Event Filter to Commandline Event Consumer -------------------  

Set objBindingClass                  = objWMIService.Get("__FilterToConsumerBinding")  
Set objBinding                       = objBindingClass.SpawnInstance_()

objBinding.Filter                    = EventFilterPath
objBinding.Consumer                  = CommandlineEventConsumerPath

objBinding.Put_()

Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory.  
Const cdoSendUsingPort   = 2 'Send the message using the network (SMTP over the network).  

Const cdoAnonymous       = 0 'Do not authenticate  
Const cdoBasic           = 1 'basic (clear-text) authentication  
Const cdoNTLM            = 2 'NTLM  


Set listArgs = WScript.Arguments

If listArgs.Count = 14 Then
  strSenderName     = "Your Name"  
  strSenderEMail    = "YourEMailAddress@Provider.com"  
  strRecipientEMail = "RecipientEMailAddress@Provider.com"  

  strSMTPServer     = "Your.SMTP.Server"  
  intSMTPPort       = 465
  strSMTPUserName   = "YourSMTPUserName"  
  strSMTPPassWord   = "YourSMTPPassword"  

  strSubject        = "Ereignis aufgetreten"  
  strMailBody       = "Logfile  : " & listArgs(0) & vbCRLF & _  
                      "RecordNo : " & listArgs(1) & vbCRLF & _  
                      "Source   : " & listArgs(2) & vbCRLF & _  
                      "EventID  : " & listArgs(3) & vbCRLF & _  
                      "EventCode: " & listArgs(4) & vbCRLF & _  
                      "EventType: " & listArgs(5) & " (" & listArgs(6) & ")" & vbCRLF & _  
                      "Category : " & listArgs(7) & " (" & ConvertCategory(listArgs(8)) & ")" & vbCRLF & _  
                      "GenTime  : " & ConvertDateTime(listArgs(9)) & vbCRLF & _  
                      "WriteTime: " & ConvertDateTime(listArgs(10)) & vbCRLF & _  
                      "Computer : " & listArgs(11) & vbCRLF & _  
                      "LogedUser: " & ConvertUser(listArgs(12)) & vbCRLF & _  
                      "Message  : " & listArgs(13) & vbCRLF  
  strAttachmentFile = ""  


  Set objMessage      = CreateObject("CDO.Message")  

  objMessage.Subject  = strSubject
  objMessage.From     = """" & strSenderName & """ <" & strSenderEMail & ">"  
  objMessage.To       = strRecipientEMail
  objMessage.TextBody = strMailBody

  If strAttachmentFile <> "" Then  
    objMessage.AddAttachment strAttachmentFile
  End If
  

  '==This section provides the configuration information for the remote SMTP server.  

  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort  

  'Name or IP of Remote SMTP Server  
  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strSMTPServer  

  'Type of authentication, NONE, Basic (Base64 encoded), NTLM  
  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic  

  'Your UserID on the SMTP server  
  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/sendusername") = strSMTPUserName  

  'Your password on the SMTP server  
  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = strSMTPPassWord  

  'Server port (typically 25 or 465 (SMTP over SSL))  
  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = intSMTPPort  

  'Use SSL for the connection (False or True)  
  Select Case intSMTPPort
    Case 25 :
      objMessage.Configuration.Fields.Item _
      ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False  

    Case 465:
      objMessage.Configuration.Fields.Item _
      ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True  
      
  End Select

  'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)  
  objMessage.Configuration.Fields.Item _
  ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60  

  objMessage.Configuration.Fields.Update

  '==End remote SMTP server configuration section==  


  objMessage.Send

  Set objMessage = Nothing
End If

Set listArgs = Nothing

WScript.Quit



Function ConvertCategory(strCategory)
  If strCategory = "<null>" Then  
    ConvertCategory = "Keine"  
  Else
    ConvertCategory = strCategory
  End If
End Function


Function ConvertUser(strUserName)
  If strUserName = "<null>" Then  
    ConvertUser = "Nicht zutreffend"  
  Else
    ConvertUser = strUserName
  End If
End Function


Function ConvertDateTime(strDateTime)
  Set dateTime    = CreateObject("WbemScripting.SWbemDateTime")  
  dateTime.Value  = strDateTime
  strResult       = dateTime.GetVarDate(True)
  Set dateTime    = Nothing

  ConvertDateTime = strResult
End Function