Excel 2013 Suche nach einem Wert in mehreren Excel-Dateien und Ausgabe weiterer Werte zum Suchergebnis incl. Angabe der Quelldatei mittel Makro

Sub SearchAndCopyData()
    'Variablen  
    Dim fso As Object, strFind As String, wsTarget As Worksheet, file As Object, sh As Worksheet, rngCol As Range, c As Range, firstAddress As String, dblKosten As Double, strFolder As String, strHeader As Variant
    
    'Ordner in dem sich die xlsx-Dateien befinden (im Beispiel der aktuelle Pfad in dem sich diese Mappe befindet)  
    strFolder = ThisWorkbook.Path
    
    'Objekte  
    Set fso = CreateObject("Scripting.FileSystemObject")  
    
    'Sheet festlegen in das die Daten kopiert werden  
    Set wsTarget = Sheets(1)
    
    'Eingabeaufforderung für die Nummer  
    strFind = InputBox("Bitte geben sie Ihre Nummer ein:", "Nummer suchen", "123456")  
    If strFind <> "" Then  
        'Screenflicker und Dialoge unterdrücken  
        Application.ScreenUpdating = False
        Application.DisplayAlerts = False
        
        'Ausgabebereich löschen  
        wsTarget.Range("A2:C10000").Clear  
        
        'Für jede Datei im Ordner ...  
        For Each file In fso.GetFolder(strFolder).Files
            'Wenn es eine 'xlsx' Datei ist  
            If LCase(fso.GetExtensionName(file.Name)) = "xlsx" Then  
                'Mappe öffnen  
                Set wbSearch = GetObject(file.Path)
                ' Alle Sheets der Datei durchsuchen  
                For Each sh In wbSearch.Sheets
                    With sh.UsedRange
                        'Suche Spaltenüberschrift 'POS_BTR NETTO' oder 'Betrags_Hauswähr' oder 'Pos_Betr incl Skonto'  
                        For Each strHeader In Array("POS_BTR NETTO", "Betrags_Hauswähr", "Pos_Betr incl Skonto")  
                            Set rngCol = sh.UsedRange.Find(strHeader, LookIn:=xlValues, LookAt:=xlWhole)
                            If Not rngCol Is Nothing Then Exit For
                        Next
                        'Wurde eine der Spalten gefunden, suche Inventarnummer  
                        If Not rngCol Is Nothing Then
                            Set c = .Find(strFind, LookIn:=xlValues, LookAt:=xlWhole)
                            If Not c Is Nothing Then
                                firstAddress = c.Address
                                Do
                                    'Nummer wurde gefunden ... extrahiere Wert  
                                    dblKosten = sh.Cells(c.Row, rngCol.Column).Value
                                    ' und schreibe Ihn in unser Sammelsheet in die nächste freie Zeile zusammen mit Inventarnummer und Pfad zur Datei  
                                    wsTarget.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0).Resize(1, 3).Value = Array(strFind, dblKosten, file.Path)  
                                    'Suche weiter  
                                    Set c = .FindNext(c)
                                Loop While Not c Is Nothing And c.Address <> firstAddress
                            End If
                        End If
                    End With
                Next
                ' schließe die Mappe  
                wbSearch.Close False
            End If
        Next
        'Spaltenbreiten automatisch anpassen  
        wsTarget.Range("A:C").EntireColumn.AutoFit  
        
        Application.DisplayAlerts = True
        Application.ScreenUpdating = True
    End If
End Sub