Hosts Datei per batch bearbeiten?

@echo off

setlocal


set "FirstLine=xxx"  
set "SecondLine=xxx"  


set "HostsFile=%SystemRoot%\System32\Drivers\etc\hosts"  


if /i "%~1" equ "A" goto :Append  
if /i "%~1" equ "E" goto :Erase  
if /i "%~1" equ "C" goto :Comment  
if /i "%~1" equ "D" goto :DeComment  

exit /b



:Append
>>"%HostsFile%" (<NUL set /p "=%FirstLine%" & echo.)  
>>"%HostsFile%" (<NUL set /p "=%SecondLine%" & echo.)  
exit /b


:Erase
call :GetNLines
set /a nLines-=2

type NUL > "%HostsFile%.new"  

for /f "eol= tokens=1* delims=:" %%k in ('findstr /n "^" "%HostsFile%"') do (  
  if %%k leq %nLines% (
    >>"%HostsFile%.new" echo\%%l  
  )
)

goto :RenameFile


:Comment
call :GetNLines
set /a nLines-=2

type NUL > "%HostsFile%.new"  

for /f "eol= tokens=1* delims=:" %%k in ('findstr /n "^" "%HostsFile%"') do (  
  if %%k leq %nLines% (
    >>"%HostsFile%.new" echo\%%l  
  ) else (
    >>"%HostsFile%.new" echo\#%%l  
  )
)

goto :RenameFile


:DeComment
call :GetNLines
set /a nLines-=2

type NUL > "%HostsFile%.new"  

for /f "eol= tokens=1* delims=:" %%k in ('findstr /n "^" "%HostsFile%"') do (  
  if %%k leq %nLines% (
    >>"%HostsFile%.new" echo\%%l  
  ) else (
    for /f "eol= delims=#" %%a in ("%%l") do (  
      >>"%HostsFile%.new" echo\%%a  
    )
  )
)


:RenameFile
move /y "%HostsFile%.new" "%HostsFile%" > NUL  
exit /b



:GetNLines
for /f "delims=:" %%n in ('findstr /n "^" "%HostsFile%"') do set /a nLines=%%n  
exit /b

EditHosts A

EditHosts C

EditHosts D

EditHosts E