VBS: Ordnerinhalt als Anhang per Mail versenden

Hallo,

ich bin gerade bei einem Projekt am verzweifeln und dabei auf dieses Forum gestoßen. Ich hoffe, es kann mir jemand helfen.

Mein Ziel: Ich habe einen Ordner mit vielen Textdateien. Jede Textdatei aus diesem Ordner soll als Mail einzeln verschickt werden, also pro Mail immer nur eine Datei. Nach dem erfolgreichen Mailversand sollte die Datei aus dem Ordner gelöscht werden und die nächste Datei verschickt werden. Ich habe bisher folgendes VBSkript:

dim MailAdresseEmpfaenger
dim MailAdresseCC

MailAdresseEmpfaenger="empfaenger@administrator.de"  
MailAdresseCC="ich@web.de"  


Set outlook = CreateObject("Outlook.Application")  
Set email = outlook.CreateItem(0)

with email

	.to = MailAdresseEmpfaenger
	.CC = MailAdresseCC
	.Subject = "Name der Textdatei"  
	.Attachments.Add "C:\Users\XXX\Documents\Test\123.txt"  
	.HTMLBody = "Dies ist ein Test"  
	.send

End with

msgbox("Email an" & vbCrLf & MailAdresseEmpfaenger & vbCrLf & "versendet." & vbCrLf & vbCrLf & vbCrLf & "Kopie an" & vbCrLf & MailAdresseCC & vbCrLf & "versendet. ")  

wscript.quit

Damit habe ich zwar den reinen Mailversand schon mal hinbekommen, es fehlt aber natürlich eine Schleife, die auch wirklich den kompletten Ordnerinhalt ausliest.

Vielleicht hat ja jemand eine Idee - für mich als Anfänger scheint es gerade irgendwie unlösbar... Vielen Dank schon mal

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 2494609300

Url: https://administrator.de/contentid/2494609300

Ausgedruckt am: 24.11.2024 um 00:11 Uhr

2 Kommentare

Neuester Kommentar

Hallo Stephan788,

man kann mit VBS unter anderem Dateien aus einem Order wie folgt auflisten:

For Each file In ordner.files
		Pfadangabe =file.path
                MsgBox Pfadangabe
Next

Im Netz findet man viele Beispiele.

Grüße

Tsuki

Damit der Beitrag hier noch abschließend abgehakt werden kann, hier eine mögliche Variante:

dim MailAdresseEmpfaenger, MailAdresseCC, fso, folder, file, outlook
MailAdresseEmpfaenger = "empfaenger@administrator.de"  
MailAdresseCC = "ich@web.de"  
folder = "D:\Ordner"  
Set fso = CreateObject("Scripting.FileSystemObject")   
Set outlook = CreateObject("Outlook.Application")  

For Each file In fso.GetFolder(folder).Files
	If LCase(fso.GetExtensionName(file.Name)) = "txt" Then  
		With outlook.CreateItem(0)
			.to = MailAdresseEmpfaenger
			.CC = MailAdresseCC
			.Subject = file.Name
			.Attachments.Add file.Path
			.HTMLBody = "Dies ist ein Test"  
			.send
                        file.Delete True
		End With
	End If
Next