WakeOnLan Stapelverarbeitend

'  
' Soll automatisch Computer zu einer bestimmten zeit Starten  
' Oder Herunterfahren  
' (c)  M. Neumann  
' 16.06.2009  
' rw.exe http://www.sysworksoft.net/products/rw.html  

Option Explicit

Dim wol_ipadressenDatei, ipadressen
Dim wait, iArgument, FSO, sCommand, sModus, iLfdNr
Dim oArgumente, WshShell
Dim sDatei, sWait, COPYLOGO, copyRight, sLaenge, sZeichen, vVariable, zZeichen

Const ForReading = 1

Set oArgumente = WScript.Arguments
Set WshShell = WScript.CreateObject("WScript.Shell")  
Set fso = CreateObject("Scripting.FileSystemObject")  
copyRight = COPYLOGO & " 16.06.2009, M. Neumann"  
'wait = 5  
iArgument = 0 
COPYLOGO = Chr(169) ' entspricht dem Zeichen (c)  
sZeichen = "="  
iLfdNr = 0
Function zHeader(vVariable, zZeichen)
	sLaenge = Len(vVariable)
	wscript.Echo(String(sLaenge, zZeichen))
	WScript.Echo(vVariable)
	wscript.Echo(String(sLaenge, zZeichen))
End Function

If oArgumente.Count > 0 Then
	Do
		If UCase(oArgumente(iArgument)) = "-D" Or _  
			UCase(oArgumente(iArgument)) = "/D" Or _  
			UCase(oArgumente(iArgument)) = "-Datei" Then  
			'---- Dateiargument  
			iArgument = iArgument + 1
			sDatei = oArgumente(iArgument)
			Set wol_ipadressenDatei = fso.OpenTextFile(sDatei,ForReading)
		
		ElseIf UCase(oArgumente(iArgument)) = "-W" Or _  
			UCase(oArgumente(iArgument)) = "/W" Or _  
			UCase(oArgumente(iArgument)) = "-Wait" Then  
			'---- Zeitargument  
			iArgument = iArgument + 1
			sWait = oArgumente(iArgument)
			sWait = sWait * 1000
						
		ElseIf UCase(oArgumente(iArgument)) = "-M" Or _  
			UCase(oArgumente(iArgument)) = "/M" Or _  
			UCase(oArgumente(iArgument)) = "-Modus" Then  
			'---- Betriebsart (sCommand / Stop)  
			iArgument = iArgument + 1
			sModus = oArgumente(iArgument)
		End If
		
		iArgument = iArgument +1
	Loop Until iArgument >= oArgumente.Count
End If

If sDatei = "" Or sWait = "" Or sModus = "" Then  
	' Es wurde kein Argument übergeben  
	zHeader copyRight,sZeichen
	WScript.Echo("Es wurde kein oder falsche Parameter übergeben.")  
	WScript.Echo(vbTab + "-d dateiname oder -datei dateiname: " & sDatei)  
	WScript.Echo(vbTab + "-w zeit(in sekunden) oder -wait zeit(in sekunden): " & sWait)  
	WScript.Echo(vbTab + "-m Betriebsart Start (START) oder Heruntrfahren (STOP) " & vbCrLf & vbTab &" von Computer: " & sModus)  
	
Else
	If sDatei	<> "" And sWait <> "" And sModus <> "" Then  
		Do While wol_ipadressenDatei.AtEndOfStream <> True
			iLfdNr = iLfdNr +1
			ipadressen = Split(wol_ipadressenDatei.ReadLine, ";")  
			WScript.Echo("LfdNr.: " & iLfdNr & ", IP: " & ipadressen(0) & ", mac: " & ipadressen(1) & ", Hostname: " & ipadressen(2))  
			If sModus = "start" Then  
				 		sCommand = "cmd\rw.exe /m:" & ipadressen(1)  
				 		WshShell.Run(sCommand)
				 		WScript.Echo(sCommand)
				 		WScript.Sleep sWait
			ElseIf sModus = "stop" Then  
				 		sCommand = "shutdown -s -f -t " & sWait & " -m \\" & ipadressen(0)  
						WshShell.Run(sCommand)
				 		WScript.Echo(sCommand)
			End If
		Loop
	End If		
End If