23.05.2006

19964

In Tabellen rumrechnen mittels BatchElemente finden und Ersetzen (Teil 1)

Dieser Beitrag soll zeigen, wie man mittels Batch einfache Tabellenkalkulationen durchführen kann und Werte in einer Tabelle finden kann mit Ausgabe von Spalte und Zeile. Mit Windows Boardmitteln und mit Nutzung von Cut,Head,Tail,Sed . Hinweise, Kritik und Bemerkungen sind willkommen.

Aufgabenstellung:
- Wo ist der Wert 20 in dieser Tabelle? Ausgabe von Spalten und Zeilen Infos.
- Wie lautet der Wert in Spalte 2 und Zeile 1? Ausgabe des Wertes
- Wie ist die Summe von Element (1,2) und (2,1) ?
- Wie ist die Summe in der zweiten Spalte?
- Addiere in eine bestimmte Zeile/Spalte ohne vorherige Kenntnis des Wertes eine Zahl bzw ersetze den Wert.
- Der ganze Aufriss soll auch mit Tabellen mit mehr als 50 Spalten funktionieren.Bzw wir wollen uns nicht mit einen Haufen tokens zum Auslesen herumplagen.Und zu guter letzt soll alles auch mit beliebigen Tabelleneinträgen funktionieren.Addieren von Strings natürlich nicht.

Anmerkung:
Es ist nicht Ziel dieses Tutorials den Leser in die tiefsten Abgründe von MS Batch zu führen, was nur sehr wenigen vergönt ist, sondern anhand der obengenannten Problematik, Stategien und Tools vorzustellen, wie man die tabellenorientierte Infos (zb auch Eventlog) bearbeiten kann.

Für Diskussionen und neue Codeschnipsel ist der Beitrag:
In Tabellen rumrechnen mittels Batch - Elemente finden und Ersetzen
vorgesehen. Dort entwickelt sich der zweite Teil und Beta Versionen.

Inhaltsverzeichnis

Inhalt der Tabelle in einer Spalte

findstr oder head, tail, cut?

Frage: In welcher Spalte/Zeile befindet sich der Wert 20 ??

Mittels. Head,cut.tail ?

Frage: Welcher Wert enthält Spalte 2, Zeile 1 ?

Welcher Wert enthält Spalte 2, Zeile 1 mittels head, cut, tail?

Bestimmen der Spalten und Zeilenzahl einer Datei mit Semikolons als Trennzeichen.

Spalten und Zeilenzahl mit Cut;head,Tail.

Alles zusammen in einem Skript

Anwendung und weitere Beispiele.

Frage: Element: 1 Zeile und 2 Spalte plus Element: 2 Zeile und 1 Spalte

Frage: Summe der Elemente in der ersten Spalte

Frage: Summe der Elemente in der ersten Zeile

Suchen eines Elementes in der ersten Spalte **

Addiere 8 auf den Wert in der zweiten Spalte und zweiten Zeile und schreibe Ihn in die Tabelle

Gegeben sei der Einfachheit halber folgende Tabelle ohne doppelte Einträge (erstmal), aber jeder Eintrag ist belegt.

1;20
2;21

Trennzeichen sind erstmal Semikolons.

for /L %%c IN (1,1,%tspalt%) DO (for /L %%d IN (1,1,%tzeile%) DO echo %%c %%d >> test.txt)

Erzeugt uns eine Matrix ala:

1 1
1 2
2 1
2 2

Die wir so lesen werden.
2 1 heißt 2. Spalte 1.Zeile usw. Also die Koordinaten der Tabelle.

Inhalt der Tabelle in einer Spalte

Wir gehen die einzelnen Spalten und Zeilen durch und geben Ihren Inhalt in die farben.txt aus.

In der ersten FOR-Schleife werden die Spalten durchgegangen. Im ersten Durchgang wird die erste Spalte ausgewertet. Dann das Token in der zweiten FOR-Schleife geschoben (tokens=%1).
In der inneren FOR-Schleife wird der Beginn der Auswertung (Skip) nach oben gezählt (mittels %azeile%).
Das blöde ist, dass

Die Innere FOR-Schleife mehrere Zeilen auswertet. Deshalb wird ein Counter eingebaut %count%. Der dafür sorgt, dass nur eine Zeile ausgegeben wird (unschön)
In der inneren FOR-Schleife kein skip=0 stehen kann, warum auch immer. Deshalb wird unsere Tabelle mit einem Header ausgestattet, damit der Code funktioniert.

Die Tabelle sieht nun so aus:

--- tabelle----
1;20
2;21

set tspalt=2
set tzeile=2

for /L %%c IN (1,1,%tspalt%) DO (for /L %%d IN (1,1,%tzeile%) DO call :sub %%c %%d)
goto :eof
:sub
    echo %1 %2 >> test.txt
    set aspalte=%1
    set /a "azeile=%2"  
    set /a "count=0"  
    for /f "skip=%azeile% delims=; tokens=%1" %%a in (tabelle.txt) Do call :sub2 %%a  
    goto :eof
    :sub2
	IF %count%==0 echo Wert %1 in Zeile %azeile% Spalte %aspalte% >> farben.txt 
	set /a "count+=1"  
goto :eof

Erkenntnis: %%a ist der Wert in der Zelle.
%%c Spaltencounter
%%d Zeilencounter

Gibt uns aus:

Wert 1 in Zeile 1 Spalte 1
Wert 2 in Zeile 2 Spalte 1
Wert 20 in Zeile 1 Spalte 2
Wert 21 in Zeile 2 Spalte 2

findstr oder head, tail, cut?

findstr /N "20" tabelle.txt gibt uns folgendes aus:
1:1;20
Diese Ausgabe müssen wir so verarzten, dass wir die 1: als Zeileninfo auslesen können. Als Token wird : benutzt. Bietet sich hier ganz gut an.

for /L %%c IN (1,1,2) DO call :sub %%c
goto :eof
:sub
	set spalte=%1	
	for /f "delims=; tokens=%1" %%a in (tabelle.txt) Do call :sub2 %%a   
	goto :eof
	:sub2
        REM Suchen in findstr /N "%1" tabelle.txt' nach Zeilenzahl  
	for /F "delims=:" %%b in ('findstr /N "%1" tabelle.txt') Do set zeile=%%b  
	echo %1 in Spalte %Spalte%; Zeile %zeile% >> farben.txt

Aber mit findstr /N "2" tabelle.txt kommt
1:1;20
2:2;21
2:2;21
raus. Ist etwas unangenehm. Aber bedarf einiger Entwicklungsarbeit.

Vorerst scannen wir die Tabelle Element für Element durch. Ja, das ist nicht schnell.
Mit den Tools cut,head,tail kann man ohne weiteres die Aufgaben erfüllen.
Wir sehen gleich wie man diese Tools benutzt.

Frage: In welcher Spalte/Zeile befindet sich der Wert 20 ??

Hier wird der Inhalt jeder Zelle mit %wert% verglichen, wenn diese gleich sind wird die Spalte und Zeile ausgegeben.
Das Skrip in 0) wurde nur mit einer if %1==%wert% erweitert. Also mit einzelnem Auslesen jedes Elements.

Tabelle benötigt einen künstlichen Header von einer Zeile. Da die erste Zeile ignoriert wird, weil SKIP in der FOR Schleife mit dem Wert Null nichts anfangen kann.
Der Wert wird exakt gesucht. ZB 2020 und "Farbe 20" werden ignoriert.
Wird nichts gefunden, so werden keine Daten ausgegeben in die Farben.txt
Zwischen den Semikolons muss zwingend ein Wert stehen. ;; ist nicht zulässig.
Werte können mehrfach in der Tabelle auftauchen.

set tspalt=2
set tzeile=2
set wert=20
for /L %%c IN (1,1,%tspalt%) DO (for /L %%d IN (1,1,%tzeile%) DO call :sub %%c %%d)
goto :eof
:sub
    :: test.txt zum Testen
    echo %1 %2 >> test.txt
    set aspalte=%1
    set /a "azeile=%2"  
    set /a "count=0"  
    for /f "skip=%azeile% delims=; tokens=%1" %%a in (tabelle.txt) Do call :sub2 %%a  
    goto :eof
    :sub2
	IF %count%==0 if %1==%wert% echo Wert %1 in Zeile %azeile% Spalte %aspalte% >> farben.txt 
	set /a "count+=1"  
goto :eof

Ausgabe:
Wert 20 in Zeile 1 Spalte 2

Mittels. Head,cut.tail ?

Hier eine nette Fassung, die direkt die Elemente anspringt. Diese gibt uns die Anzahl der Treffer und die Positionen der Elemente an.
Diese benötigt in der Tabelle keinen künstlichen Header und die einzelnen Zellen können leer sein.
Geht also auch für eine Tabelle
; ;;;;;20;9;;
;;;3;8899;

Befehle
head -3l tabelle.txt gibt uns die ersten 3 Zeilen von tabelle.txt aus.

tail -1l tabelle.txt gibt uns die letzt Zeile aus (wird von hinten gezählt).

cut -d; -f2 tabelle.txt gibt uns die zweite Spalte (f2) der Tabelle aus. mit d; wird das Trennzeichen übergeben.

head -3l %tabelle%|tail -1l|cut -d; -f2
gibt uns also das 2 Element der 3 Spalte aus.

REM Tabelleninfos
set tabelle=tabelle.txt
set delimiter=;
set tspalt=4

set output=farben.txt
set tempd=temp.txt
set wert=miguel

REM Um die Anzahl der Treffer zu bestimmen.
set /a "count=0"  

REM Suchen nach dem Element mit findstr. Zeilen herausfischen und das an Tab übergeben.

for /L %%c in (1,1,%tspalt%) Do for /f "delims=:" %%a in ('more %tabelle%^|findstr /N "%wert%"') Do call :tab %%a %%c   
if not %count%==0 (echo Anzahl Treffer %count% >> %output%) else echo nichts gefunden >> %output%

goto :eof

REM Element ausgeben
:tab 
   head -%1l %tabelle%|tail -1l|cut -d%delimiter% -f%2 >> %tempd%   
   for /f %%a in (%tempd%) Do IF %%a==%wert% echo Wert ist in Spalte %2 und Zeile %1 >> %output% && set /a "count+=1"  
   del temp.txt
goto :Eof

Hier ist noch, dass Problem, dass mittels findstr auch Teile eines Elementes gefunden werden beseitigt. Zwar findet findstr bei "20" auch 2000 und 200. Aber durch die Prüfung des Wertes in der inneren FOR Schleife, wird dieses Problem beseitigt.

Frage: Welcher Wert enthält Spalte 2, Zeile 1 ?

Erstmal mit dem Skript unter 2/3). Ist zwar etwas umständlich, da die gesamte Tabelle durchgescant wird.

Ist der Spaltenzähler gleich x und der Zeilenzähler gleich y. Wird die Zelle ausgegeben.

set tspalt=2
set tzeile=4

set x=1
set y=4

for /L %%c IN (1,1,%tspalt%) DO (for /L %%d IN (1,1,%tzeile%) DO call :sub %%c %%d)
goto :eof
:sub
    set /a "aspalte=%1"  
    set /a "azeile=%2"  
    set /a "count=0"  
    for /f "skip=%azeile% delims=; tokens=%1" %%a in (tabelle.txt) Do call :sub2 %%a  
    goto :eof
    :sub2
	IF %count%==0 if %aspalte%==%x% if %azeile%==%y% echo %1 >> farben.txt 
	set /a "count+=1"  
goto :eof

Gibt uns wie erwartet 20 aus.

Welcher Wert enthält Spalte 2, Zeile 1 mittels head, cut, tail?

Aber die Befehle verweigern sich in einer FOR Schleife zu arbeiten, deshalb wird eine temp.txt erzeugt, die den aktuellen Wert enthält.

set tabelle=tabelle.txt
set delimiter=;

set y=2
set x=2

call :tab %y% %x%
echo Wert ist %ausgabew% >> farben.txt
goto :eof

REM Element ausgeben
:tab 
   head -%1l %tabelle%|tail -1l|cut -d%delimiter% -f%2 >> temp.txt
   for /f %%a in (temp.txt) Do set ausgabew=%%a
   del temp.txt
goto :Eof

Bestimmen der Spalten und Zeilenzahl einer Datei mit Semikolons als Trennzeichen.

Schön wäre es, wenn wir aus der Tabelle ohne weiteres die Zeilenzahl und Spaltenzahl herausziehen könnten, damit können wir an das Skript einfach eine Tabelle übergegen und der Rest wird vom Skript erledigt.

Idee. Mit Findstr werden die Semikolons gesucht. Die Ausgabe ist ja

ZB:

1:2;20
2:45;56

In der ersten Zeile ist die Zeilennummer. Interessieren tuen wir uns nur für die letzte Zeile der Ausgabe, diese ist ja die Zeilenzahl der Tabelle.

Die Spaltenzahl wird etwas komplizierter gesucht.
Die Zeichen einer Spalte einzeln auf Belegung geprüft. Ist kein Wert vorhanden ist die Zeile zuende.Wobei dabei ausgenutzt wird, dass die for Schleife irgendwann einen Fehler ausgibt uns selbst rausspringt (sonst wäre es eine Endlosschleife.) (Very Dirty)

REM Tabelleninfos
set tabelle=tabelle.txt
set delimiter=;
set header=1

set output=farben.txt

for /f "delims=:" %%b in ('more +%header% %tabelle%^|findstr /N "%delimiter%"') DO set /a "zeilenzahl=%%b"  
set /a "count=0"  

:beginnt	
	set /a "count+=1"  
        for /f "tokens=%count% delims=%delimiter%" %%a in ('more +%zeilenzahl% %tabelle%') DO goto :beginnt  

set /a "spaltenzahl=%count%-1"  
echo Spalten %Spaltenzahl%; Zeilen %Zeilenzahl%; Header %header% >> %output%

Spalten und Zeilenzahl mit Cut;head,Tail.

Man kann die Zeilenzahl auch mit grep -c ; tabelle.txt herausbekommen.

Zwingend bei diesem Code ist also, dass es keine leeren Elemente gibt und wie es mit anderen Trennzeichen ist ???

REM Tabelleninfos
set tabelle=tabelle.txt
set delimiter=;
set header=1

set output=farben.txt
set tempd=temp.txt

for /f "delims=:" %%b in ('more +%header% %tabelle%^|findstr /N ";"') DO set /a "zeilenzahl=%%b"  

set /a "count=0"  

:beginnt
	del %tempd%
	set /a "count+=1"   
	head -2l %tabelle%|tail -1l|cut -d%delimiter% -f%count% >> %tempd%  
	for /f %%a in (%tempd%) Do IF not defined %%a (goto :beginnt)

del %tempd%
set /a "spaltenzahl=%count%-1"  
echo Spalten %Spaltenzahl%; Zeilen %Zeilenzahl%; Header %header% >> %output%

Alles zusammen in einem Skript

@echo off
REM Tabellenbatch mit CUT,TAIL,HEAD,FINDSTR
@echo off
REM ----------------------------------------------------
REM Externe Paramter
set tabelle=tabelle.txt
set delimiter=;
set header=1
REM ----------------------------------------------------

REM ----------------------------------------------------
REm Interne Paramter
set tempd=%temp%	abtemp.txt
set output=farben.txt
set /a "count=0"  
REM ----------------------------------------------------


:main
REM ----------------------------------------------------
REM Externe Paramter
set tabelle=tabelle.txt
set delimiter=;
set header=1
REM ----------------------------------------------------

REM Hier kommen die Befehle rein




REM----

goto :eof

REM -----------------------------------------
REM tabelleninfos

REM Zeilenzahl bestimmen
:spaltcount

set /a "countt=0"  
        if not defined zeilenzahl call :zeilencount
	:beginnt	
	set /a "countt+=1"  
        for /f "tokens=%countt% delims=%delimiter%" %%a in ('more +%zeilenzahl% %tabelle%') DO goto :beginnt  

set /a "spaltenzahl=%countt%-1"  

goto :eof
REM -----------------------------------------

REM -----------------------------------------
REM Spaltenzahl ermitteln
:zeilencount
	for /f "delims=:" %%b in ('more +%header% %tabelle%^|findstr /N "%delimiter%"') DO set /a "zeilenzahl=%%b"  
goto :eof
REM -----------------------------------------

REM -----------------------------------------
REM Element ausgeben
:element   
   REM Header berücksichtigen
   if exist %tempd% del %tempd%
   set /a "yoff=%1+%header%"    
   head -%yoff%l %tabelle%|tail -1l|cut -d%delimiter% -f%2 >> %tempd%
   for /f %%a in (%tempd%) Do set ausgabew=%%a
   del %tempd%
goto :Eof
REM -----------------------------------------

REM -----------------------------------------
:suche
   if exist %tempd% del %tempd%
   set /a "count=0"  
   if not defined spaltenzahl call :spaltcount
   for /L %%c in (1,1,%spaltenzahl%) Do for /f "delims=:" %%a in ('more %tabelle%^|findstr /N "%wert%"') Do call :sub %%a %%c   
   goto :eof
   :sub
   set /a "yoff=%1"  
   set /a "ya=%1-%header%"  
   head -%yoff%l %tabelle%|tail -1l|cut -d%delimiter% -f%2 >> %tempd%   
   for /f %%a in (%tempd%) Do IF %%a==%wert% echo Wert %wert% gefunden in Spalte %2 und Zeile %ya% >> %output% && set /a "count+=1"  
   del %tempd%
   goto :eof
REM -----------------------------------------


REM -----------------------------------------
:ausgabe
echo Wert ist %ausgabew% >> %output%
if defined wert (if not %count%==0 (echo Anzahl Treffer %count% >> farben.txt) else echo nichts gefunden >> %output%)
if defined %spaltenzahl% if defined %zeilenzahl% echo Spalten %Spaltenzahl%; Zeilen %Zeilenzahl%; Header %header% >> %output%
goto :eof
REM -----------------------------------------

-----------------------------------------------------------------------------------------------------------------------------------

Da unser Hauptprogramm definiert ist, wird ab hier nur noch der Hauptteil des Codes gezeigt.

Anwendung und weitere Beispiele.

Frage: Element: 1 Zeile und 2 Spalte plus Element: 2 Zeile und 1 Spalte

:main
REM Ersten Wert auslesen
set y=1
set x=2
call :element %y% %x%
set /a "Summe+=%ausgabew%"  

REM zweiten Wert auslesen
set x=1
set y=2
call :element %y% %x%
set /a "Summe+=%ausgabew%"  

REM Ergebnis
echo summe ist %summe% >> summe.txt
goto :eof

Frage: Summe der Elemente in der ersten Spalte

ohne Kommentar.

:main

call :zeilencount
set x=1

call :addiere
echo summe in der Spalte %x% ist %summe% >> summe.txt

goto :eof

:addiere
for /L %%a in (1,1,%zeilenzahl%) DO call :sum %%a 
goto :eof
:sum
call :element %1 %x%
set /a "Summe+=%ausgabew%"   

goto :eof

Frage: Summe der Elemente in der ersten Zeile

ohne Kommentar.

:main

call :zeilencount
call :spaltcount

set y=1

call :addiere
echo summe in der Zeile %y% ist %summe% >> summe.txt

goto :eof

:addiere
for /L %%a in (1,1,%spaltenzahl%) DO call :sum %%a 
goto :eof
:sum
call :element %y% %1
set /a "Summe+=%ausgabew%"   

goto :eof

Suchen eines Elementes in der ersten Spalte **

Wir schränken die Suche auf eine bestimmte Zeile ein.

:main

call :zeilencount
call :spaltcount

REM Suchen in der ersten Spalte
set wert=2

set x=1
for /l %%a in (1,1,%zeilenzahl%) DO call :typb %%a
goto :eof
:typb
call :element %1 %x%
IF %ausgabew%==%wert% echo %wert% in Zeile %1 >> signal.txt 

goto :eof

Addiere 8 auf den Wert in der zweiten Spalte und zweiten Zeile und schreibe Ihn in die Tabelle

Hierfür wird sed benutzt.
(Quelle und Anleitung: http://www.student.northpark.edu/pemente/sed/sedfaq.html )

Für den Anfang sei folgendes gesagt.

sed "5 s/45/50/1" tabelle.txt > ausgabe.txt

Macht folgendes: In der 5 Zeile wird das erste Vorkommen (1) von 45 durch 50 ersetzt. Die gesamte Tabelle wird in ausgabe.txt ausgegeben.

set "1,5 s/45/50/g" tabelle.txt > ausgabe.txt

Ersetzt uns von der Zeile 1 bis 5 die 45 gegen 50. g steht hier für global.

set "s/45/50/g" tabelle.txt > ausgabe.txt

Ersetzt alle 45 gegen 50.

Für den Anfang begnügen wir uns, damit das in der Tabelle keine doppelten Elemente vorkommen.

Also nicht 50;50 oder 4050;50.

Ziel soll es aber sein ein bestimmtes Element zu ersetzen. (Wird noch gebaut)

Jetzt der Code.

set header=1
:main
call :zeilencount
call :spaltcount

set y=3
set x=2

REM Wert auslesen
call :element %y% %x%

REM Addiere etwas drauf
set /a "ausgabeneu=%ausgabew%+8"  

REM Berücksichtigung des Headers
set /a "yoff=%y%+%header%"  

REM in Zeile springen und erstes Vorkommen dort mit neuem Wert ersetzen
sed "%yoff% s/%ausgabew%/%ausgabeneu%/1" %tabelle% > %output%  

goto :eof

Eine Verfeinerung und Verbesserung der bisherigen Ergebnisse werden bei bedarf und Interesse im zweiten Teil durchgekaut.

Ich hoffe ein bischen von den Möglichkeiten von Batch aufgezeigt zu haben und die Benutzung von Tools nähergebracht zu haben.

In allen Codeschnipseln steckt bestimmt noch eine Menge Entwicklungspotential, mit den Entsprechnende Ideen und Werkzeugen läßt sich bestimmt noch mehr rausholen. (Mal den Batch Biber fragen).

Gruß Miguel