Adobe reader 6 per Batch entfernen

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall

@echo off

setlocal

set "regkey=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"  

for /f "skip=5 delims=" %%a in ('reg query "%regkey%"') do (  
  for /f "tokens=3,*" %%b in ('reg query "%%a" /s ^| findstr /i /r /c:"DisplayName.*Adobe Reader" 2^>NUL') do (  
    echo %%b %%c

    for /f "tokens=3,*" %%d in ('reg query "%%a" /s ^| find /i "UninstallString"') do (  
      echo %%d %%e
    )

    echo.
    pause
  )
)

endlocal

@echo off

setlocal enabledelayedexpansion

set "regkey=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"  

for /f "skip=5 delims=" %%a in ('reg query "%regkey%"') do (  
  for /f "tokens=3,*" %%b in ('reg query "%%a" /s ^| findstr /i /r /c:"DisplayName.*Adobe Reader" 2^>NUL') do (  
    for /f "tokens=2 delims={}" %%d in ("%%a") do (  
      tasklist | find /i "acrord32" > NUL  
      
      if !errorlevel! equ 0 (
        echo Adobe Reader wird ausgeführt. Die Deinstallation kann nicht gestartet werden.
        echo.
      ) else (
        echo %%b %%c wird deinstalliert.
        start /wait MsiExec.exe /UNINSTALL {%%d} REBOOT=SUPRESS /QB-
        echo Deinstallation abgeschlossen.
        echo.
      )
    )
  )
)

endlocal