Aufgezeichnetes Makro, formel gibt laufzeitfehler 1004

Hallo liebe Leute,

ich bin sowas von Anfänger mit Makros für Excel, also bitte nachfragen, wenn ich mich nicht klar genug ausdrücke.

Ich möchte von einer (beliebigen) aktiven Zelle(hier a1) ausgehend mittels Button folgendes erreichen

füge unter dieser Zelle drei leere Zeilen ein
Schreibe in Zelle (h3) das Wort Summe
kopiere in die nächstfolgende Spalte(i3) die anfangs aktivierte Zelle(a1)
Schreibe in die nächste Spalte(j3) die Summe von den zwei direkt darüber liegenden Zeilen(j1:j2) bis maximal zum Anfang (j1).........hier will ich später Zeilen einfügen
verschiebe die Zellen L1 und M1 zwei Zeilen nach unten
rechne in n3 = k3*m3
füge Unterstreichungen hinzu.

Aufgezeichnet habe ich erstmal...........
Sub Positionssumme()
'
' Positionssumme Makro
'

'
ActiveCell.Offset(1, 0).Rows("1:3").EntireRow.Select
Selection.Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
ActiveCell.Offset(-1, 11).Range("A1:B1").Select
Selection.Cut Destination:=ActiveCell.Offset(2, 0).Range("A1:B1")
ActiveCell.Offset(2, -4).Range("A1").Select
ActiveCell.FormulaR1C1 = "Summe Pos."
ActiveCell.Offset(-2, -6).Range("A1").Select
Selection.Copy
ActiveCell.Offset(2, 8).Range("A1").Select
ActiveSheet.Paste
Application.CutCopyMode = False
ActiveCell.Offset(0, 1).Range("A1").Select
Range("A1").FormulaR1C1 = "=SUM(R[-1]C:R[-2]C)"
ActiveCell.Offset(0, 3).Range("A1").Select
Range("A1").FormulaR1C1 = "=RC[-3]*RC[-1]"
Range("B50:N50").Select
Selection.Borders(xlDiagonalDown).LineStyle = xlNone
Selection.Borders(xlDiagonalUp).LineStyle = xlNone
Selection.Borders(xlEdgeLeft).LineStyle = xlNone
Selection.Borders(xlEdgeTop).LineStyle = xlNone
With Selection.Borders(xlEdgeBottom)
.LineStyle = xlContinuous
.ColorIndex = 0
.TintAndShade = 0
.Weight = xlThin
End With
Selection.Borders(xlEdgeRight).LineStyle = xlNone
Selection.Borders(xlInsideVertical).LineStyle = xlNone
Selection.Borders(xlInsideHorizontal).LineStyle = xlNone
End Sub

nicht ganz bis zum Ende, weil ich neugierig war, und siehe da........beide Formeln führen zu Laufzeitfehler 1004. Ich suche jetzt seit zwei Tagen den Fehler,
1.1 Baustelle einrichten
Summe Pos1.1 0,000 psch 10.000,00 0,00
so ungefähr solls aussehen.

Helft mir bitte weiter.

Gruß Asta

Sub MachWas()
    If ActiveCell.Column = 1 Then   'Nur Spalte A akzeptieren  
        With ActiveCell
            .Offset(1, 0).Resize(3).EntireRow.Insert Shift:=xlDown  '3 Zeilen einfügen  
            .Offset(2, 7).Value = "Summe:"                          'H3 = Wort Summe  
            .Copy .Offset(2, 8)                                     'A1 -> I3 (Copy)  
            .Offset(2, 9).FormulaR1C1 = "=SUM(R[-2]C:R[-1]C)"       'J3 = Summe J1:J2  
            .Offset(0, 11).Resize(1, 2).Cut .Offset(2, 11)          'L1:M1 -> L3:M3 (Cut)  
            .Offset(2, 13).FormulaR1C1 = "=RC[-3]*RC[-1]"           'N3 = K3*M3  
        End With
        
        With Range("B50:N50").Borders(xlEdgeBottom)  
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
    End If
End Sub

Absolute Zellbezüge:
.Formula = "SUM(J1:J2)"                     'englisch (VBA)  
.FormulaLocal = "SUMME(J1:J2)"              'deutsch (Sprachpaket)  

Relative Zellbezüge:
.FormulaR1C1 = "=SUM(R[-2]C:R[-1]C)"        'englisch (VBA)  
.FormulaR1C1Local = "=SUMME(Z[-2]S:Z[-1]S)" 'deutsch (Sprachpaket)  

'Active Cell in Spalte B (J3 = Summe J1:J2)  
.Offset(2, 8).FormulaR1C1Local = "=SUMME(Z[-2]S:Z[-1]S)"  

'Active Cell in Spalte B  
.Offset(2, 8).Formula = "=SUM(" & .Offset(0, 8).Resize(2, 1).Address & ")"  

.FormulaR1C1Local = "=SUM(R[-2]C:R[-1]C)"   'englisch (Sprachpaket)  

.Offset(2, 8).Formula = "=SUM(" & Replace(.Offset(0, 8).Resize(2, 1).Address,"$","") & ")"