Aufteilung einer Logdatei anhand bestimmter Zeichenkette

Sub ProcessLog()
    Dim arrNames() As Variant, cnt As Long, fso As Object, rngOut As Range, regex As Object, blocks As Object, block As Object
    ' Pfad zur Logdatei  
    Const LOGFILE = "D:\Logfiles\MeinMegaLog.log"  
    'Objekte  
    Set fso = CreateObject("Scripting.FileSystemObject")  
    Set regex = CreateObject("vbscript.regexp")  
    ' Regex Optionen festlegen  
    regex.Global = True: regex.IgnoreCase = True: regex.MultiLine = True
    regex.Pattern = "Starte Job[\s\S]*?#{5,}[\r\n]+([\s\S]*?)[^\r\n]+#{5,}"  
    
    ' Inhalt des Logs auslesen  
    strContent = fso.OpenTextFile(LOGFILE, 1).ReadAll()
    
    ' Ausgabe startet in dieser Zeile  
    Set rngOut = Range("A2")  
    ' Überschriften setzen  
    With Range("A1:C1")  
        .Value = Array("Name", "Daten", "Namen")  
        .Font.Bold = True
    End With
    ' Regex ausführen  
    Set blocks = regex.Execute(strContent)
    
    ' neuen Regex Pattern für die Namen festlegen  
    regex.Pattern = " \|\| Name:\s*(.*)"  
    
    ' Für jeden Logabschnitt  
    For Each block In blocks
        ' Name und Daten auslesen  
        arrLines = Split(block.submatches(0), vbNewLine, -1)
        strName = Trim(Split(arrLines(1), "||", 4, vbTextCompare)(3))  
        strDaten = Trim(Split(arrLines(2), "||", 4, vbTextCompare)(3))  
        
        ' betroffene Namen auslesen und in Array schreiben  
        cnt = 1
        Set matchedNames = regex.Execute(block.submatches(0))
        For Each n In matchedNames
            ReDim Preserve arrNames(1 To cnt)
            arrNames(cnt) = Trim(n.submatches(0))
            cnt = cnt + 1
        Next
        ' Name und Daten ausgeben  
        rngOut.Resize(1, 2).Value = Array(strName, strDaten)
        ' betroffene Namen in Spalten ausgeben  
        rngOut.Offset(0, 2).Resize(1, UBound(arrNames)).Value = arrNames
        ' move output range to next line  
        Set rngOut = rngOut.Offset(1, 0)
    Next
End Sub