Batch für Übernahme benutzerdef. Einstellungen Win2000Pro (Office,Outlook,Desktop)

Hi, danke erstma für deine Antwort!!!

Ich habe vor dies an jedem Arbeitsplatz selber zu machen und das nur einmal. Kla isses auch ma Hilfreich für die Datensicherung wenn man mal seinen PC platt machen will oder ähnlichem, aber imo hab ich nur das damit vor.

Habe auch schon mal angefangeneine Batch zu schreiben...sie sieht wie folgt aus, kannst ja gerne mal dein Kommentar dazu abgeben und verbesserungsvorschläge machen

rem Programm Backup_Userdata v0.9
rem erstellt von Sebastian Schilling

@echo off
cls
title Sicherung der Benutzer-Daten

:::::::::::::
:: QUELLEN ::
:::::::::::::

set Quelle1="%USERPROFILE%\Eigene Dateien"

set Quelle2="%USERPROFILE%\Lokale Einstellungen\Anwendungsdaten\Microsoft\Outlook\mailbox.pst"
set Quelle3="%USERPROFILE%\Lokale Einstellungen\Anwendungsdaten\Microsoft\Outlook\outlook.pst"
set Quelle4="%USERPROFILE%\Anwendungsdaten\Microsoft\Address Book\*.*"
set Quelle5="%USERPROFILE%\Anwendungsdaten\Microsoft\Outlook\outcmd.dat"

set Quelle6="%USERPROFILE%\Anwendungsdaten\Microsoft\Vorlagen\Normal.dot"
set Quelle7="%USERPROFILE%\Anwendungsdaten\Microsoft\Office\MSO1031.acl"
set Quelle8="%USERPROFILE%\Anwendungsdaten\Microsoft\Proof\Benutzer.dic"

set Quelle9="%USERPROFILE%\Anwendungsdaten\Microsoft\Excel\XLStart\*.*"
set Quelle10="%USERPROFILE%\Anwendungsdaten\Microsoft\Office\*.pip"

:::::::::::
:: ZIELE ::
:::::::::::

set Ziel1=".\Backup_%computername%\%date%\Eigene Dateien\"
set Ziel2=".\Backup_%computername%\%date%\Outlook2000\"
set Ziel3=".\Backup_%computername%\%date%\Outlook Express\"
set Ziel4=".\Backup_%computername%\%date%\Outlook Express\Address Book\"
set Ziel5=".\Backup_%computername%\%date%\Office\Word\"
set Ziel6=".\Backup_%computername%\%date%\Office\Excel\XLStart\"
set Ziel7=".\Backup_%computername%\%date%\Microsoft Office Settings Files\"

md %Ziel1%
md %Ziel2%
md %Ziel3%
md %Ziel4%
md %Ziel5%
md %Ziel6%
md %Ziel7%


rem Mit diesem Befehl {>> ".\Backup_%computername%\%date%\backup.log"} werden alle Aktionen in einer "backup.log"
rem Datei gespeichert. Weiterhin wird durch ">>" die Log-Datei erweitert und nicht immer neu erstellt.

echo Starte Backup der Benutzerdateien >> ".\Backup_%computername%\%date%\backup.log"
echo.

::::::::::::::::::::
:: Eigene Dateien ::
::::::::::::::::::::

echo Starte Backup der Eigenen Dateien auf %computername% am %date% um %time% >> ".\Backup_%computername%\%date%\backup.log"
echo in das Verzeichnis %Ziel1%

xcopy %Quelle1% %Ziel1% /v /c /h /e /k /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.

::::::::::::::::::
:: Outlook 2000 ::
::::::::::::::::::

echo Starte Backup von Outlook 2000 auf %computername% am %date% um %time% >> ".\Backup_%computername%\%date%\backup.log"
echo in das Verzeichnis %Ziel2%
echo.
echo Persoenliche Ordner werden gesichert:>> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle2% %Ziel2% /v /y >> ".\Backup_%computername%\%date%\backup.log"
copy %Quelle3% %Ziel2% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.

echo Persoenliche Symbolleiste wird gesichert:>> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle5% %Ziel2% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.

:::::::::::::::::::::
:: Outlook Express ::
:::::::::::::::::::::

echo Starte Backup von Outlook Express auf %computername% am %date% um %time% >> ".\Backup_%computername%\%date%\backup.log"
echo in das Verzeichnis %Ziel3%
echo.
echo Adressbuch wird gesichert:>> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle4% %Ziel4% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.

echo Persoenliche Ordner werden gesichert:>> ".\Backup_%computername%\%date%\backup.log"
echo.

xcopy "%USERPROFILE%\Lokale Einstellungen\Anwendungsdaten\Identities" %Ziel3% /v /c /h /e /k /y /f >> ".\Backup_%computername%\%date%\backup.log"

rem Dieser Befehl funktioniert nur, wenn im Windows-Explorer unter Extras->Ordneroptionen->Ansicht die Option
rem Alle versteckten Ordner und Dateien anzeigen aktiviert ist.

echo.
echo fertig
echo.

::::::::::::
:: Office ::
::::::::::::

echo Starte Backup von Microsoft Office auf %computername% am %date% um %time% >> ".\Backup_%computername%\%date%\backup.log"
echo in das Verzeichnis %Ziel5%
echo.

echo Word - Dokumentenvorlagen werden gesichert: >> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle6% %Ziel5% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.
:::::::::::::::::::
echo Autokorrekturliste wird gesichert: >> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle7% %Ziel5% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.
::::::::::::::::::
echo Word - Wörterbücher werden gesichert: >> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle8% %Ziel5% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.
::::::::::::::::::
echo Makros (Excel) werden gesichert: >> ".\Backup_%computername%\%date%\backup.log"
echo.

copy %Quelle9% %Ziel6% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.
::::::::::::::::::
echo Voreinstellungen (Pfade,Symbolleisten, etc.) werden gesichert: >> ".\Backup_%computername%\%date%\backup.log"
echo.

reg export HKCU\Software\Microsoft\Office\9.0 ".\Backup_%computername%\%date%\Office\Word\backup.reg" >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.

:::::::::::::::::::::::::::::::::::::
:: Microsoft Office Settings Files ::
:::::::::::::::::::::::::::::::::::::

echo Starte Backup der Microsoft Office Settings Files auf %computername" am %date% um %time">> ".\Backup_%computername%\%date%\backup.log"
echo in das Verzeichnis %Ziel7%
echo.

copy %Quelle10% %Ziel7% /v /y >> ".\Backup_%computername%\%date%\backup.log"

echo.
echo fertig
echo.

start notepad.exe ".\Backup_%computername%\%date%\backup.log"
pause