Email-Adresse im Exchange 2003 finden

Hallo,

bei einem Kunden von uns finde ich eine Email-Adresse nicht.

Laut csvde bekomme ich diese Information bei (objectClass=publicfolder).
Also ein öffentlicher Ordner. Aber wo und welcher?
Ich habe alle durchgeschaut ohne Erfolg.

"CN=Name,CN=Microsoft Exchange System Objects,DC=Name,DC=local",smtp:Name@domain3.de;smtp:Name2@Name.local;X400:c=DE\;a= \;p=Name\;o=Exchange\;s=Name2\;

Name der Domäne
Name.local

Name der Person (Chef)
Name

Ich habe so dass Gefühl, als ob der Name vom System selber verwendet wird.
Allerdings Name@domain1.de und Name@domain2.de funktionieren prima.

Kann mir bitte Jemand einen Tipp geben wo ich da schauen kann?

Danke

Stefan

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 179404

Url: https://administrator.de/forum/email-adresse-im-exchange-2003-finden-179404.html

Ausgedruckt am: 09.04.2025 um 04:04 Uhr

1 Kommentar

Morgen Stefan,

es gibt ein VBs-Script, mit welchem du auf deinem Exchange-Server alle Mailadressen mit zugehörigen Usern/ÖOs ausgeben kannst.

Option Explicit
Dim strMail      '   
Dim arrMember              '   
Dim arrObjectClass         '   
Dim arrProxyAddresses      '   
Dim i                      '   
Dim objConn                '   
Dim objExplorer            '   
Dim objRSAD                '   
Dim objRSlokal             '   
Dim strAusgabe             '   
Dim strConn                '   
Dim strMember              '   
Dim strObjectClass         '   
Dim strSQL                 '   
Dim objRoot
Dim strDomain

Set objConn = CreateObject("ADODB.Connection")  
Set objRSlokal = CreateObject("ADODB.Recordset")  

' Domänenzugriff ...  
set objRoot = GetObject("LDAP://rootDSE")  
strDomain = objRoot.Get("DefaultNamingContext")  

' Datenbankzugriff ...  
strConn = "Provider=ADsDSOObject;"  
objConn.Open strConn

' Zugriff auf die gesamte Tabelle  
strSQL = "SELECT name,mailNickname,mail,proxyAddresses,member,objectClass " _  
	& "FROM 'LDAP://"  & strDomain &  "' WHERE mailNickname='*'"  
Set objRSAD = objConn.Execute(strSQL)

' lokales Recordset zur Anzeige definieren  
objRSlokal.Fields.Append "Mailadresse", 202, 255  
objRSlokal.Fields.Append "Name", 202, 255  
objRSlokal.Fields.Append "Alias", 202, 255  
objRSlokal.Fields.Append "Typ", 202, 255  
objRSlokal.Fields.Append "Mitglieder", 202, 16384  

objRSlokal.Open

Do Until objRSAD.EOF
	arrProxyAddresses = objRSAD("proxyAddresses")  
	strMail = objRSAD("mail")  
	If Not IsNull(objRSAD("member")) Then  
		arrMember = objRSAD("member")  
		strMember = Join(arrMember, "<br>")  
	Else
		strMember = ""  
	End If
	arrObjectClass = objRSAD("objectClass")  
	strObjectClass = arrObjectClass(UBound(arrObjectClass))
		For i=0 To UBound(arrProxyAddresses)
		If LCase(Left(arrProxyAddresses(i),5)) = "smtp:" Then  
			' Neuen Datensatz lokal einfügen  
			objRSlokal.AddNew
			objRSlokal("Name") = objRSAD("name")  
			objRSlokal("Alias") = objRSAD("mailNickname")  
			objRSlokal("Typ") = strObjectClass  
			objRSlokal("Mailadresse") = Mid(arrProxyAddresses(i),6)  
			objRSlokal("Mitglieder") = strMember  
			objRSlokal.Update
		End If
		Next
	objRSAD.MoveNext
Loop
objRSlokal.Sort="Mailadresse"  
objRSlokal.MoveFirst
strAusgabe = objRSlokal.GetString(2, -1, "</TD><TD>", "</TD></TR>" _  
        & vbCrLf & "<TR><TD>", "&nbsp;")  
strAusgabe = "<HTML><BODY style=""font-family:sans-serif;"">" _  
	& "<TABLE border=""1""><TR><TD>" _  
	& strAusgabe & "</TD></TR></TABLE></BODY></HTML>"  

Set objExplorer = CreateObject("InternetExplorer.Application")  
objExplorer.Navigate "about:blank"  
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Width=500
objExplorer.Height = 400
objExplorer.Left = 0
objExplorer.Top = 0
objExplorer.Visible = 1
objExplorer.document.writeln(strAusgabe)