Excel Makro: Zusammenfassen von zwei Tabellen

Sub MergeTables()
    'Variablen  
    Dim wsOld As Worksheet, wsNew As Worksheet, wsMerged As Worksheet, cell As Range
    ' Tabellenzuweisung  
    ' Alte Tabelle  
    Set wsOld = Sheets("Tabelle_Alt")  
    ' Neue Tabelle  
    Set wsNew = Sheets("Tabelle_Neu")  
    ' Zusammenfassung-Sheet erstellen/zuweisen  
    On Error Resume Next
    Set wsMerged = Sheets("Zusammenfassung")  
    On Error GoTo 0
    ' Wenn das Zusammenfassungs Sheet noch nicht existiert erstelle es anhand einer Kopie mittels "wsOld"  
    If wsMerged Is Nothing Then
        wsOld.Copy After:=Sheets(Sheets.Count)
        Set wsMerged = Sheets(Sheets.Count)
        wsMerged.Name = "Zusammenfassung"  
    End If
    
    With wsNew
        ' Für jede Zelle im Bereich A2:A(n) des Sheets "wsNew"  
        For Each cell In .Range("A2:A" & .Cells(Rows.Count, "A").End(xlUp).Row)  
            ' Wenn Zellwert nicht leer ist  
            If cell.Value <> "" Then  
                ' finde im Zusamenfassungs-Sheet eine existierende Nummer  
                Set f = wsMerged.Range("A:A").Find(cell.Value, LookIn:=xlValues)  
                ' Wenn dort keine gefunden wurde setze als Ziel die nächste freie Zeile  
                If f Is Nothing Then
                    Set f = wsMerged.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0)  
                End If
                ' kopiere Daten aus wsNew ans Ziel  
                cell.Resize(1, 8).Copy f
            End If
        Next
    End With
End Sub