Excel-VBA: Alle Werte einer Spalte in einer anderen Suchen

Hallo,

ich hänge jetzt schon seit Tagen dran und komm nicht zu Rande.

Ich versuche jeden Wert eines Tabellenblattes (Spalte B bis Zeile 32) in einer anderen Splate (D) des gleichen Tabellenblattes zu finden. In der Nachbarzelle (Spalte E) steht dann der Wert, den ich in die Ursprungszelle (Spalte B Zeile ?) übergeben möchte. Es kann auch sein, dass eine Zeile (in Spalte B) leer ist, die nächste jedoch wieder Daten zum Suchen enthällt.

Beispiel:

Spalte B Spalte D Spalte E
C A Erster Wert
C B Zweiter Wert
A C Dritter Wert
... ... ...

Gewünschtes Ergebnis:
Spalte B Spalte D Spalte E
Dritter Wert A Erster Wert
Dritter Wert B Zweiter Wert
Erster Wert C Dritter Wert
... ... ...


Hat Jemand eine Idee?

Sub Werte_Zuordnen()
    Dim dic As Object, cell As Range, rngData as Range
    'Dictionary Object das die Daten aus Spalten D und E enthält  
    Set dic = CreateObject("Scripting.Dictionary")  
    With ActiveSheet
        'Bereich in dem die Suchdaten stehen die ersetzt werden sollen  
        Set rngData = .Range("D2:D" & .Cells(Rows.Count, "D").End(xlUp).Row)  
        'Dictionary mit den Werten füllen  
        For Each cell In rngData
            dic.Add cell.Value, cell.Offset(0, 1).Value
        Next
        'Werte in Spalte B zuordnen  
        For Each cell In .Range("B2:B" & .Cells(Rows.Count, "B").End(xlUp).Row)  
            If cell.Value <> "" And dic.Exists(cell.Value) Then  
                cell.Value = dic.Item(cell.Value)
            End If
        Next
    End With
End Sub