joe72ka
Goto Top

Excel Zeilen in eine Zeile anzeigen

Hallo,
ich habe eine Excel Tabelle mit dem Aufbau

Nummer Text
0000001 Test2
0000001 Test1
0000002 Titel
0000002 Titel2
0000002 Titel3

Jetzt möchte ich aber die Zeilen zusammenfassen in
0000001 Test2, Test1
0000002 Titel, Titel2, Titel3

Ich habe keine Idee wie ich das in Excel umsetzen kann.

Kann mir jemand weiterhelfen?

Vielen Dank
Ralf

Content-Key: 241036

Url: https://administrator.de/contentid/241036

Ausgedruckt am: 29.03.2024 um 00:03 Uhr

Mitglied: colinardo
colinardo 17.06.2014 aktualisiert um 09:56:59 Uhr
Goto Top
Hallo Ralf,
eine Möglichkeit wäre diese Einträge mit einer Pivottabelle zu gruppieren, eine andere ein kleines Makro das die Einträge wie von dir gewünscht zusammenfasst:

Im Beispiel gehe ich jetzt einfach mal davon aus das die Daten in Zelle A2 auf dem ersten Tabellenblatt liegen
Sub MergeDuplicates()
    Dim ws As Worksheet, rngStart As Range, rngEnd As Range, rngCurrent As Range
    ' Erstes Tabellenblatt referenzieren  
    Set ws = Worksheets(1)
    'Startzelle der Daten festlegen  
    Set rngStart = ws.Range("A2")  
    ' Zellendbereich ermitteln  
    Set rngEnd = rngStart.End(xlDown).Offset(0, 1)

    ' Bereich zuerst nach Nummern sortieren  
    ws.Range(rngStart, rngEnd).Sort ws.Range("A1")  
    
    'So lange zusammenfassen bis eine Zelle keinen Inhalt hat  
    Set rngCurrent = rngStart
    While rngCurrent.Value <> ""  
        If rngCurrent.Value = rngCurrent.Offset(1, 0).Value Then
            rngCurrent.Offset(0, 1).Value = rngCurrent.Offset(0, 1).Value & ", " & rngCurrent.Offset(1, 1).Text  
            rngCurrent.Offset(1, 0).EntireRow.Delete
        Else
            Set rngCurrent = rngCurrent.Offset(1, 0)
        End If
    Wend
End Sub
Hier noch das Demo-Dokument dazu.

Grüße Uwe
Mitglied: Joe72ka
Joe72ka 17.06.2014 um 09:55:16 Uhr
Goto Top
SUPER Vielen Vielen Dank!

Danke
Ralf