Fehlende numerierte Unterverzeichnisse mit batch ausfindig machen

Hallo zusammen,

ich habe ein Verzeichnis, in der sich eine bestimmte Anzahl Unterverzeichnisse sich befinden. Diese Unterverzeichnisse sind Zahlen:

/Test/0001
/Test/0002
...
/Test/000n

Ich weiß nun dass in dem Verzeichnis Test sich z.B. sechs Unterverzeichnisse (n=6) befinden müssten. Also

/Test/0001
/Test/0002
/Test/0003
/Test/0004
/Test/0005
/Test/0006

Nun fehlen aber (keine,) eine oder mehrere Unterverzeichnisse

/Test/0001
/Test/0002
/Test/0004
/Test/0006


Wie kann ich mit einer Batch-Datei herausfinden, welches Verzeichnis, bzw. welche Nummern fehlen?

Ideal wäre es die kleinste Fehlende Nummer als Variable zur Verfügung zu haben

Danke und Grüße

@echo off & setlocal
set "Verz=D:\Test"  
set /a Anz=6

set /a Nr=10001
set /a MaxNr=10000+Anz

pushd "%Verz%"  
set "Fehlend="  
:Loop
if not exist %Nr:~-4% if not defined Fehlend set "Fehlend=%Nr:~-4%"  
set /a Nr+=1
if %Nr% leq %MaxNr% goto :Loop
popd
if defined Fehlend (
    echo Erstes fehlendes Verzeichnis: %Verz%\%Fehlend%
) else (
    echo Alle Verzeichnisse vorhanden
)