an-wei
12.11.2008, aktualisiert am 14.11.2008
view5268
view3
0
Goto Top

fragen zur firefox gpo-einrichtung

FrageInternet
hallo zusammen,
ich habe bei uns den firefox 3.0.3 ueber eine gruppenrichtlinie verteilt (adm+vbs-script). soweit alles gut und es hat auch alles geklappt. dazu habe ich zwei fragen.

nach der verteilung ist es jedoch so, das die option 'passwörter speichern' ausgegraut ist und der user nicht selbst entscheiden kann, ob er seine passwoerter speichern moechte.

25547b0ba555a91513d360f96cff6197-ff-pass

jetzt meine frage; wie kann ich wo einstellen, das das feld nicht mehr ausgegraut ist.
die zweite frage ist, ob ich zertifikate die der firefox nutzen soll, per gruppenrichtlinie verteilen kann.


server: w2k3 / clients: win xp

zum einsatz kommen diese gruppenrichtline gruppenrichtlinien.de und das unten aufgefuehrte vbs-script.

' FirefoxADM  

' create shell instance  
set WshShell = WScript.CreateObject("WScript.Shell")  

' create file object instances  
set fso = CreateObject("Scripting.FileSystemObject")  

' variables I'll be needing later  
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim FirefoxProfilePath, FirefoxPrefsFile, FirefoxProfileFolder, FirefoxProfiles
Dim FirefoxFolder, PrefsFile
Dim ParsePrefsFile, ParseOutPrefsFile
Dim FolderCreate, FirefoxProfileIniFile, FirefoxEmptyPrefsFile
' and this list needed for each feature  
Dim HomePageKey, SearchEngineKey, ImageResizeKey, ProxyKey, ProxyURLKey
Dim HTTPKey, HTTPPortKey, SSLKey, SSLPortKey, FTPKey, FTPPortKey
Dim GopherKey, GopherPortKey, SOCKSKey, SOCKSPortKey, SOCKSVersionKey, ProxyExceptionsKey, ExceptionSplit
Dim FirefoxUseIEKey, IESettingFile, ParseFileLine, ParseSplitLine, ParseSplitSetting, SameProxy
Dim NetscapeJscFile, FirefoxJsFile

on error resume next 

set EnVar = Wshshell.environment("Process")  
FirefoxPrefsFile = EnVar("ProgramFiles") & "\Mozilla Firefox\defaults\autoconfig\prefcalls.js"  
NetscapeJscFile = EnVar("ProgramFiles") & "\Mozilla Firefox\netscape.jsc"  
FirefoxJsFile = EnVar("ProgramFiles") & "\Mozilla Firefox\defaults\pref\firefox.js"  


' check for the Netscape locking file  
if fso.FileExists(NetscapeJscFile) then
	' do nothing  
else
	' create locking file  
	Set NetscapeJscFileSet = fso.OpenTextFile(NetscapeJscFile, ForWriting, True)
  	NetscapeJscFileSet.Write("created by FirefoxADM")  
	NetscapeJscFileSet.Close
end if

RemoveConfigSetting()

' add in netscape.jsc locking variable  
Set FirefoxJsFileSet = fso.OpenTextFile(FirefoxJsFile, ForAppending)
FirefoxJsFileSet.Write(vbCrLf & "pref(" & chr(34) & "general.config.filename" & chr(34) & "," & chr(34) & "netscape.jsc" & chr(34) & ");")  
FirefoxJsFileSet.Close



' homepage setting  
if FirefoxUseIEKey <> "1" then   
	HomePageKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxHomepage")  
end if
if HomePageKey <> "" then  
	RemoveCurrentPrefsFromFile("browser.startup.homepage")  
	set HomePageSet = AppendPrefsToFile("browser.startup.homepage", chr(34) & HomePageKey & chr(34))  
end if

' Automatic Image Resizing  
ImageResizeKey = WshShell.regread("HKLM\Software\Policies\Firefox\ImageResize")  
if ImageResizeKey <> "" then  
	RemoveCurrentPrefsFromFile("browser.enable_automatic_image_resizing")  
	if ImageResizeKey = "0" then  
		set SearchEngineSet = AppendPrefsToFile("browser.enable_automatic_image_resizing", "false")  
	else
		set SearchEngineSet = AppendPrefsToFile("browser.enable_automatic_image_resizing", "true")  
	end if
end if
		

' Proxy Settings  
ProxyKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxProxy")  
ProxyURLKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxAutoProxyURL")  
HTTPKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualHTTP")  
HTTPPortKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualHTTPPort")  
SSLKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualSSL")  
SSLPortKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualSSLPort")  
FTPKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualFTP")  
FTPPortKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualFTPPort")  
GopherKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualGopher")  
GopherPortKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualGopherPort")  
SOCKSKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualSOCKS")  
SOCKSPortKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualSOCKSPort")  
ProxyExceptionsKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxProxyExceptions")  
if ProxyKey <> "" then  
	SOCKSVersionKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxManualSOCKSVersion")  
	removeCurrentPrefsFromFile("network.proxy.type")  
	removeCurrentPrefsFromFile("network.proxy.autoconfig_url")  
	removeCurrentPrefsFromFile("network.proxy.http")  
	removeCurrentPrefsFromFile("network.proxy.http_port")  
	removeCurrentPrefsFromFile("network.proxy.ssl")  
	removeCurrentPrefsFromFile("network.proxy.ssl_port")  
	removeCurrentPrefsFromFile("network.proxy.ftp")  
	removeCurrentPrefsFromFile("network.proxy.ftp_port")  
	removeCurrentPrefsFromFile("network.proxy.gopher")  
	removeCurrentPrefsFromFile("network.proxy.gopher_port")  
	removeCurrentPrefsFromFile("network.proxy.socks")  
	removeCurrentPrefsFromFile("network.proxy.socks_port")  
	removeCurrentPrefsFromFile("network.proxy.socks_version")  
	removeCurrentPrefsFromFile("network.proxy.no_proxies_on")  
	if ProxyURLKey <> "" then  
		set ProxyURLSet = AppendPrefsToFile("network.proxy.autoconfig_url", chr(34) & ProxyURLKey & chr(34))  
	end if
	if HTTPKey <> "" then  
		set HTTPSet = AppendPrefsToFile("network.proxy.http", chr(34) & HTTPKey & chr(34))  
		HTTPSet = AppendPrefsToFile("network.proxy.http_port", HTTPPortKey)  
	end if
	if SSLKey <> "" then  
		set SSLSet = AppendPrefsToFile("network.proxy.ssl", chr(34) & SSLKey & chr(34))  
		SSLSet = AppendPrefsToFile("network.proxy.ssl_port", SSLPortKey)  
	end if
	if FTPKey <> "" then  
		set FTPSet = AppendPrefsToFile("network.proxy.ftp", chr(34) & FTPKey & chr(34))  
		FTPSet = AppendPrefsToFile("network.proxy.ftp_port", FTPPortKey)  
	end if
	if GopherKey <> "" then  
		set GopherSet = AppendPrefsToFile("network.proxy.gopher", chr(34) & GopherKey & chr(34))  
		GopherSet = AppendPrefsToFile("network.proxy.gopher_port", GopherPortKey)  
	end if
	if SOCKSKey <> "" then  
		set SOCKSSet = AppendPrefsToFile("network.proxy.socks", chr(34) & SOCKSKey & chr(34))  
		SOCKSSet = AppendPrefsToFile("network.proxy.socks_port", SOCKSPortKey)  
		SOCKSSet = AppendPrefsToFile("network.proxy.socks_version", SOCKSVersionKey)  
	end if
	if ProxyExceptionsKey <> "localhost, 127.0.0.1" or ProxyExceptions <> "" then  
		set ExceptionsSet = AppendPrefsToFile("network.proxy.no_proxies_on", chr(34) & ProxyExceptionsKey & chr(34))  
	Elseif ProxyExceptionsKey = "localhost, 127.0.0.1" then  
		set ExceptionsSet = AppendPrefsToFile("network.proxy.no_proxies_on", chr(34) & ProxyExceptionsKey & chr(34))  
	end if
	set ProxySet = AppendPrefsToFile("network.proxy.type", ProxyKey)  
end if


' Cache  
FirefoxCacheKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxCacheSize")  
FirefoxCacheSSLKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxCacheSSL")  
if FirefoxCacheKey <> "" then  
	RemoveCurrentPrefsFromFile("browser.cache.disk.capacity")  
	RemoveCurrentPrefsFromFile("browser.cache.disk_cache_ssl")  
	set CacheSet = AppendPrefsToFile("browser.cache.disk.capacity", FirefoxCacheKey)  
	if FirefoxCacheSSLKey = "1" then  
		set CacheSSLSet = AppendPrefsToFile("browser.cache.disk_cache_ssl", "true")  
	else
		set CacheSSLSet = AppendPrefsToFile("browser.cache.disk_cache_ssl", "false")  
	end if
end if


' Check Default Browser  
FirefoxCheckDefaultKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxCheckDefault")  
if FirefoxCheckDefaultKey = "0" then  
	RemoveCurrentPrefsFromFile("browser.shell.checkDefaultBrowser")  
	set DefaultSet = AppendPrefsToFile("browser.shell.checkDefaultBrowser", "false")  
Elseif FirefoxCheckDefaultKey = "1" then  
	RemoveCurrentPrefsFromFile("browser.shell.checkDefaultBrowser")  
	set DefaultSet = AppendPrefsToFile("browser.shell.checkDefaultBrowser", "true")  
end if


' Disable XPI Installations?  
FirefoxXPIStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxXPIState")  
if FirefoxXPIStateKey = "0" then  
	RemoveCurrentPrefsFromFile("xpinstall.enabled")  
	set XPISet = AppendPrefsToFile("xpinstall.enabled", "false")  
Elseif FirefoxXPIStateKey = "1" then  
	RemoveCurrentPrefsFromFile("xpinstall.enabled")  
	set XPISet = AppendPrefsToFile("xpinstall.enabled", "true")  
end if


' update Firefox  
FirefoxUpdateStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxUpdateState")  
If FirefoxUpdateStateKey = "1" then  
	RemoveCurrentPrefsFromFile("app.update.autoUpdateEnabled")  
	RemoveCurrentPrefsFromFile("app.update.enabled")  
	set UpdateSet1 = AppendPrefsToFile("app.update.autoUpdateEnabled", "true")  
	set UpdateSet2 = AppendPrefsToFile("app.update.enabled", "true")  
ElseIf FirefoxUpdateStateKey = "0" then  
	RemoveCurrentPrefsFromFile("app.update.autoUpdateEnabled")  
	RemoveCurrentPrefsFromFile("app.update.enabled")  
	set UpdateSet1 = AppendPrefsToFile("app.update.autoUpdateEnabled", "false")  
	set UpdateSet2 = AppendPrefsToFile("app.update.enabled", "false")  
end if


' update Firefox's extensions  
FirefoxExtUpdateStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxExtUpdateState")  
If FirefoxExtUpdateStateKey = "1" then  
	RemoveCurrentPrefsFromFile("extensions.update.autoUpdateEnabled")  
	RemoveCurrentPrefsFromFile("extensions.update.enabled")  
	set UpdateXtSet1 = AppendPrefsToFile("extensions.update.autoUpdateEnabled", "true")  
	set UpdateXtSet2 = AppendPrefsToFile("extensions.update.enabled", "true")  
ElseIf FirefoxExtUpdateStateKey = "0" then  
	RemoveCurrentPrefsFromFile("extensions.update.autoUpdate")  
	RemoveCurrentPrefsFromFile("extensions.update.enabled")  
	set UpdateXtSet1 = AppendPrefsToFile("extensions.update.autoUpdateEnabled", "false")  
	set UpdateXtSet2 = AppendPrefsToFile("extensions.update.enabled", "false")  
end if


' Disable Java?  
FirefoxJavaStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxJavaState")  
If FirefoxJavaStateKey = "1" then  
	RemoveCurrentPrefsFromFile("security.enable_java")  
	set JavaStateSet = AppendPrefsToFile("security.enable_java", "true")  
ElseIf FirefoxJavaStateKey = "0" then  
	RemoveCurrentPrefsFromFile("security.enable_java")  
	set JavaStateSet = AppendPrefsToFile("security.enable_java", "false")  
end if


' Disable Javascript?  
FirefoxJavascriptStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxJavascriptState")  
If FirefoxJavascriptStateKey = "1" then  
	RemoveCurrentPrefsFromFile("javascript.enabled")  
	set JavascriptStateSet = AppendPrefsToFile("javascript.enabled", "true")  
ElseIf FirefoxJavascriptStateKey = "0" then  
	RemoveCurrentPrefsFromFile("javascript.enabled")  
	set JavascriptStateSet = AppendPrefsToFile("javascript.enabled", "false")  
end if


' Disable SSL 2/3 & TLS?  
FirefoxSSLStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxSSLState")  
If FirefoxSSLStateKey = "1" then  
	RemoveCurrentPrefsFromFile("security.enable_ssl2")  
	RemoveCurrentPrefsFromFile("security.enable_ssl3")  
	RemoveCurrentPrefsFromFile("security.enable_tls")  
	set SSLStateSet = AppendPrefsToFile("security.enable_ssl2", "true")  
	set SSLStateSet = AppendPrefsToFile("security.enable_ssl3", "true")  
	set SSLStateSet = AppendPrefsToFile("security.enable_tls", "true")  
Elseif FirefoxSSLStateKey = "0" then  
	RemoveCurrentPrefsFromFile("security.enable_ssl2")  
	RemoveCurrentPrefsFromFile("security.enable_ssl3")  
	RemoveCurrentPrefsFromFile("security.enable_tls")  
	set SSLStateSet = AppendPrefsToFile("security.enable_ssl2", "false")  
	set SSLStateSet = AppendPrefsToFile("security.enable_ssl3", "false")  
	set SSLStateSet = AppendPrefsToFile("security.enable_tls", "false")	  
end if


' Disable IDNs?  
FirefoxIDNStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxIDNState")  
If FirefoxIDNStateKey = "1" then  
	RemoveCurrentPrefsFromFile("network.enableIDN")  
	set IDNStateSet = AppendPrefsToFile("network.enableIDN", "true")  
ElseIf FirefoxIDNStateKey = "0" then  
	RemoveCurrentPrefsFromFile("network.enableIDN")  
	set IDNStateSet = AppendPrefsToFile("network.enableIDN", "false")  
end if


' Disable Password Remembering?  
FirefoxPasswordRememberKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxPasswordRememberState")  
If FirefoxPasswordRememberKey = "1" then  
	RemoveCurrentPrefsFromFile("signon.rememberSignons")  
	set PasswordRememberStateSet = AppendPrefsToFile("signon.rememberSignons", "true")  
ElseIf FirefoxPasswordRememberKey = "0" then  
	RemoveCurrentPrefsFromFile("signon.rememberSignons")  
	set PasswordRememberStateSet = AppendPrefsToFile("signon.rememberSignons", "false")  
end if


' Enable Type Ahead Find  
FirefoxTypeAheadFindKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxTypeAheadFindState")  
If FirefoxTypeAheadFindKey = "1" then  
	RemoveCurrentPrefsFromFile("accessibility.typeaheadfind")  
	set FirefoxTypeAheadFindSet = AppendPrefsToFile("accessibility.typeaheadfind", "true")  
ElseIf FirefoxTypeAheadFindKey = "0" then  
	RemoveCurrentPrefsFromFile("accessibility.typeaheadfind")  
	set FirefoxTypeAheadFindSet = AppendPrefsToFile("accessibility.typeaheadfind", "false")  
end if


' Disable Prefetching  
FirefoxPrefetchStateKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxPrefetchState")  
If FirefoxPrefetchStateKey = "1" then  
	RemoveCurrentPrefsFromFile("network.prefetch-next")  
	set FirefoxPrefetchState = AppendPrefsToFile("network.prefetch-next", "true")  
ElseIf FirefoxPrefetchStateKey = "0" then  
	RemoveCurrentPrefsFromFile("network.prefetch-next")  
	set FirefoxPrefetchState = AppendPrefsToFile("network.prefetch-next", "false")  
end if


' Enable/Disable URL security check  
FirefoxSecurityCheckLoadUriKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxSecurityCheckLoadUri")  
If FirefoxSecurityCheckLoadUriKey = "1" then  
	RemoveCurrentPrefsFromFile("security.checkloaduri")  
	set FirefoxSecurityCheckLoadUriSet = AppendPrefsToFile("security.checkloaduri", "false")  
ElseIf FirefoxSecurityCheckLoadUriKey = "0" then  
	RemoveCurrentPrefsFromFile("security.checkloaduri")  
	set FirefoxSecurityCheckLoadUriSet = AppendPrefsToFile("security.checkloaduri", "true")  
end if


' Trusted & Delegated Authentication white list  
FirefoxTrustedAuthKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxTrustedAuth")  
FirefoxDelegatedAuthKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxDelegatedAuth")  
If FirefoxTrustedAuthKey <> "" or FirefoxDelegatedAuthKey <> "" then  
	RemoveCurrentPrefsFromFile("network.negotiate-auth.trusted-uris")  
	RemoveCurrentPrefsFromFile("network.negotiate-auth.delegation-uris")  
	set FirefoxTrustedAuthSet = AppendPrefsToFile("network.negotiate-auth.trusted-uris", chr(34) & FirefoxTrustedAuthKey & chr(34))  
	set FirefoxDelegatedAuthSet = AppendPrefsToFile("network.negotiate-auth.delegation-uris", chr(34) & FirefoxDelegatedAuthKey & chr(34))  
end if


' Browse with Caret  
FirefoxCaretKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxCaret")  
If FirefoxCaretKey = "1" then  
	RemoveCurrentPrefsFromFile("accessibility.browsewithcaret")  
	set FirefoxCaretSet = AppendPrefsToFile("accessibility.browsewithcaret", "true")  
ElseIf FirefoxCaretKey = "0" then  
	RemoveCurrentPrefsFromFile("accessibility.browsewithcaret")  
	set FirefoxCaretSet = AppendPrefsToFile("accessibility.browsewithcaret", "false")  
end if


' Cookie Handling  
FirefoxCookieKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxCookieBehaviour")  
If FirefoxCookieKey <> "" then  
	RemoveCurrentPrefsFromFile("network.cookie.cookieBehavior")  
	set FirefoxCookieBehaviourKey = AppendPrefsToFile("network.cookie.cookieBehavior", FirefoxCookieKey)  
end if


' Set Bookmarks Location  
FirefoxBookmarksLocationKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxBookmarks")  
If FirefoxBookmarksLocationKey <> "" then  
	RemoveCurrentPrefsFromFile("browser.bookmarks.file")  
	set FirefoxBookmarksKey = AppendPrefsToFile("browser.bookmarks.file", chr(34) & FirefoxBookmarksLocationKey & "\\bookmarks.html" & chr(34))  
end if


' TODO:  More settings!  


Function RemoveCurrentPrefsFromFile(removeSetting)
	Set ParsePrefsFile = fso.OpenTextFile(FirefoxPrefsFile, ForReading)

	' Get file content into an array:  
	Dim aContents
	aContents = Split(ParsePrefsFile.ReadAll, vbCrLf)

	ParsePrefsFile.Close
	set ParsePrefsFile = Nothing

	' Parse Back In to Prefs.js file  

	Dim aContentsNew
	aContentsNew = Filter(aContents, removeSetting, False, vbTextCompare)

	' Overwrite the old file with the new file,  
  	Set ParseOutPrefsFile = fso.OpenTextFile(FirefoxPrefsFile, ForWriting)
  	ParseOutPrefsFile.Write Join(aContentsNew, vbCrLf)
    	ParseOutPrefsFile.Close
End Function

Function AppendPrefsToFile(writeKey, writeData)
	set PrefsFile = fso.OpenTextFile(FirefoxPrefsFile,ForAppending)
	PrefsFile.Write (vbCrLf & "lockPref(" & chr(34) & writeKey & chr(34) & ", " & writeData & ");")  
	PrefsFile.Close
End Function

Function RemoveConfigSetting()
	Set ParsePrefsFile = fso.OpenTextFile(FirefoxJsFile, ForReading)

	' Get file content into an array:  
	Dim aContents
	aContents = Split(ParsePrefsFile.ReadAll, vbCrLf)

	ParsePrefsFile.Close
	set ParsePrefsFile = Nothing

	' Parse Back In to Firefox.js file  

	Dim aContentsNew
	aContentsNew = Filter(aContents, chr(34) & "general.config.filename" & chr(34), False, vbTextCompare)  

	' Overwrite the old file with the new file,  
  	Set ParseOutPrefsFile = fso.OpenTextFile(FirefoxJsFile, ForWriting)
  	ParseOutPrefsFile.Write Join(aContentsNew, vbCrLf)
    	ParseOutPrefsFile.Close
End Function


vielen dank im voraus fuer eure hinweise
andré
ShareTeilen
Auf Facebook teilen Auf Twitter teilen Auf Reddit teilen Auf Linkedin teilen

Content-ID: 101635

Url: https://administrator.de/forum/fragen-zur-firefox-gpo-einrichtung-101635.html

Ausgedruckt am: 26.12.2024 um 03:12 Uhr

3 Kommentare
Neuester Kommentar
Goto Top
godlie
godlie 12.11.2008 um 15:32:30 Uhr
Goto Top
Also zuständig für die Passwort merken geschichte sind im Script folgende Zeilen:
252-260
' Disable Password Remembering?   
FirefoxPasswordRememberKey = WshShell.regread("HKLM\Software\Policies\Firefox\FirefoxPasswordRememberState")   
If FirefoxPasswordRememberKey = "1" then  
	RemoveCurrentPrefsFromFile("signon.rememberSignons")   
	set PasswordRememberStateSet = AppendPrefsToFile("signon.rememberSignons", "true")   
ElseIf FirefoxPasswordRememberKey = "0" then   
	RemoveCurrentPrefsFromFile("signon.rememberSignons")  
	set PasswordRememberStateSet = AppendPrefsToFile("signon.rememberSignons", "false")   
end if
ich würd das hier einfach durch folgendes ersetzen.
RemoveCurrentPrefsFromFile("signon.rememberSignons")  
set PasswordRememberStateSet = AppendPrefsToFile("signon.rememberSignons", "true")

grüße
an-wei
an-wei 14.11.2008 um 11:11:26 Uhr
Goto Top
das klappt leider auch nicht.
ich habe aus dem vbs- und adm script die betreffenden eintraege entfernt und per cmd den registry-ordner [HKLM\Software\Policies\Firefox] geloescht.

dann erst war die bewusste option nicht mehr ausgegraut.

godlie, danke fuer deine hilfe.
retz12
retz12 30.06.2009 um 10:24:30 Uhr
Goto Top
Hallo,
ich hätte noch eine Frage,
wann wird das vbs Script ausgeführt. Jedes mal beim anmelden? oder nur einmal bei der installation?
FrageInternet
Mehr von an-weian-weiÜber Powershell AD Gruppen erstellen und anpassenan-wei - 2 Kommentarean-weiAufgaben zusammenfassen und mittels Schleife verarbeitenan-wei - 3 Kommentarean-weiHostnamen von ThinClients abfragen - Wie optimaler gestalten?an-wei - 1 Kommentaran-weiSAP Symbole werden nicht angezeigtan-wei - 2 Kommentare
Heiß diskutiert
NullcheckPortweiterleitung ist böse. tatsächlich? (Externzugriff auf Fritzbox)Nullcheck - 36 KommentareStef223Draytek VLAN allgemeinStef223 - 26 KommentareSarekHLProblem mit SMB-Versionen?SarekHL - 24 KommentareStefanKittelWireguard pfSense zu Securepoint - Kein trafficStefanKittel - 16 KommentareGhent74Feste IP via DHCP im DHCP Bereich oder im statischen Bereich?Ghent74 - 14 KommentareKostasAD 2019 reinstalliert, Probleme bei den MapingsKostas - 13 KommentareHaralabosHilfe bei E-Mail-Analyse: Absender einer anonymen Nachricht herausfindenHaralabos - 13 KommentareGhent74Zwei Router, ein SubnetzGhent74 - 13 KommentareKamelleLöschen von Verknüpfungen in beliebigen OrdnerstrukturenKamelle - 12 KommentareKnettenbrechExchange Online: MFA deaktivierenKnettenbrech - 12 KommentareNetzworker9Passwort-Management in Schulen (Online-Datenbank oder so)Netzworker9 - 11 KommentarelarsvomdachOPNSense Mikrotik WG Internet, Lokal kein Zugrifflarsvomdach - 11 Kommentare