Script zum auslesen von variabeln in einer logdatei mit weitergabe an netsh advfirewall

for /f "tokens=4 delims=: " %%r in ("%%c") do (

:readinput.cmd
@echo off


if "%~1" equ "/?" echo Stellt eine Pufferdatei zum Permaneten auslesen zur verfuegung.^  
 &echo Dies ermoeglicht Tee waerend der Ausfuehrung eines Befehls.^
 &echo(&<nul set /p "=%~n0 " &echo [Logfile] [/.]&echo(^  
 &echo      Logfile    Angabe eines zu Puffernden Logfiles.^
 &echo      /.         Auch Leerzeilen Puffern.&echo(^
 &echo   "%~pd0%~n0-write.cmd"  wird zum^  
 &echo    abarbeiten des Puffers Bereitgestellt.&echo(^
 &echo   Befehle mit Pipe einleiten:^
 &echo    Befehl1 ^| "%~n0" [Logfile] [/.] &exit /b   
if not exist "%~pd0%~n0-write.cmd" for /f "delims=:" %%i in ('findstr /nb :INSTALLPuffer "%~f0"') do more +%%i "%~f0" > "%~pd0%~n0-write.cmd"   
setlocal disabledelayedexpansion
set "Puffertmp=%temp%\Tee%random%.txt"  
set "Puffer=%Puffertmp%"  
set "LN=."  
set "del=/D"  
if "%~1" equ "" goto :noParam  
:Parameter
if /i "%~1" equ "/N" (set "N=1" &set LN="^" ) else set "del=" &set "Puffer=%~1"  
if "%~2" neq "" shift &goto :Parameter  
:noParam

(findstr /n %LN% && ECHO E_O_F_END_OF_FILE:) >"%Puffer%" | <"%Puffer%" "%~pd0%~n0-write.cmd" "%Puffer%" %del%  

exit /b



:INSTALLPuffer
@echo off
setlocal
set /a Limit=60
if "%~1" equ "/?" echo Liest aus einer nummerierten Pufferdatei, bis zur Abschlusszeile "E_O_F_END_OF_FILE:".^  
 &echo oder bis diese Datei kleiner als Vorher wird: ^( type nul ^<PufferDatei ^).&echo(^
 &<nul set /p "=%~n0 Pufferdatei [/d] ^<PufferDatei" &echo(^  
 &echo    /D     Die ^(temporaere^) Datei wird nachher geloescht.^
 &echo   Werden %Limit% Sekunden keine Ausgaben Produziert wird dieses Programm beendet.&exit /b
if not exist "%~1" echo Pufferdatei nicht gefunden! >&2 &exit /b 1  
if /i "%~2" neq /D (set "Del=") else set del=^&del %1 ^>nul  
for %%i in (%1) do set "Z=%%~zi"  

set /a R=limit
:IN
 set /a r-=1
 set "out=1"  
 set "inline="  
 set /p "inline="  
 setlocal enabledelayedexpansion
  rem Abbruch mit AbschlussZeile
 for /f "delims=:" %%i in ("!inline!") do set "out=" &if %%i equ E_O_F_END_OF_FILE (title Verabeitung Fertig.%del%&exit /b) else title Verarbeite Zeile %%i  
  rem Abbruch wenn nach Zeitlimit keine Ausgabe
 if %r% leq 0 title Verabeitung Fertig.%del%&exit /b
  rem Abbruch wenn Datei kleiner
 for %%i in (%1) do if %Z% gtr %%~zi (title Verabeitung Fertig.%del%&exit /b) else set "Z=%%~zi"  
 if defined Out endlocal &waitfor EineSekundePause /t 1 >nul 2>&1 &title Timer %r%&goto :in
  rem  Hier muss die Verarbeitung Hinein zB.
 echo(!inline:*:=!
 for /f "tokens=1,2,3*" %%i in ("!inline:*:=!") do endlocal &echo %%j-%time%-%%l  
 if "%os%" equ "!OS!" endlocal  
 set /a R=limit
goto :in

(for /l %i in (1 1 10) do @Dir & ping localhost -n 5 1>nul ) |readinput.cmd Testlog.txt

@echo off & setlocal enabledelayedexpansion
set "Log=D:\log\alert.id  
set /a Zeilen=10

:loop
for /f "delims=:" %%i in ('findstr /n "^" "%Log%"') do set /a Setoff=%%i-%Zeilen%  
if %Setoff% lss 0 set /a Setoff=0
for /f "tokens=1*" %%i in ('more +%Setoff% "%Log%"^|findstr /c:"Priority"') do (  
    for /f "tokens=1-3 delims={}" %%a in ("%%j") do (  
        for /f "tokens=4 delims=: " %%r in ("%%c") do (  
            set "Name=%%i %%r %%a"  
            echo netsh advfirewall firewall add rule name="!Name:~,-1!" dir=in action=block protocol=%%b remoteip=%%r  
        )
    )
)
sleep 30
goto :loop

@echo off
setlocal disabledelayedexpansion
if not exist "%~pd0%~n0-write.cmd" for /f "delims=:" %%i in ('findstr /nb :INSTALLPuffer "%~f0"') do more +%%i "%~f0" > "%~pd0%~n0-write.cmd"   

set "Datei=D:\log\alert.id"  

 rem wenig CPUlast
 rem Verarbeitet alle Zeilen und wenn eine neue angefügt wird immer die Letzte Zeile

<"%Datei%" "%~pd0%~n0-write.cmd"  
exit /b



:INSTALLPuffer
@echo off
setlocal
set /a Limit=60
set /a R=limit
:IN
 set /a r-=1
 set "out=1"  
 set "inline="  
 set /p "inline="  
 setlocal enabledelayedexpansion

  rem Abbruch wenn nach Zeitlimit keine Ausgabe
 if %r% leq 0 exit /b
 if not defined inline endlocal &waitfor EineSekundePause /t 1 >nul 2>&1&title Timer %r% &goto :in

  rem Verarbeite Zeile mit Programm
for /f "tokens=1*" %%t in ("!inline!") do ^  
for /f "tokens=1-5* delims=]" %%a in ("%%u") do ^  
for /f "tokens=1,3,4 delims=[{}: " %%p in ("%%e %%f") do if %%p equ Priority ^  
echo netsh advfirewall firewall add rule name="%%t %%r %%a]%%b]%%c]%%d]%%e]" dir=in action=block protocol=%%q remoteip=%%r  

 if "!os!" equ "%OS%" endlocal  
 set /a R=limit
 title verarbeite Zeile
goto :in

@echo off
setlocal disabledelayedexpansion
if "%~1" neq "" (set "Datei=%~1") else set "Datei=D:\log\alert.id"  
find "" "%Datei%"|find "-" >nul ||exit /b 1 &for /f %%i in ('more +5 "%datei%" ^|find /c /v "" ') do Call <"%Datei%" :Read_Lines %%i &exit /b  
:Read_Lines
for /l %%i in (1 1 %1 ) do set /p "inline="  
:IN
 set "inline="  
 set /p "inline="  
 if not defined inline waitfor EineSekundePause /t 1 >nul 2>&1 &goto :in
 setlocal enabledelayedexpansion
for /f "tokens=1*" %%t in ("!inline!") do ^  
for /f "tokens=1-5* delims=]" %%a in ("%%u") do ^  
for /f "tokens=1,3,4 delims=[{}: " %%p in ("%%e %%f") do if %%p equ Priority ^  
netsh advfirewall firewall show rule name="%%t %%r %%a]%%b]%%c]%%d]%%e]" >nul|| netsh advfirewall firewall add rule name="%%t %%r %%a]%%b]%%c]%%d]%%e]" dir=in action=block protocol=%%q remoteip=%%r  

 if "!os!" equ "%OS%" endlocal  
goto :in

findstr /e "%%r" "Regeln.txt">nul || (  
    netsh advfirewall firewall add rule name="!Name:~,-1!" dir=in action=block protocol=%%b remoteip=%%r  
)

@echo off & setlocal enabledelayedexpansion
set "Log=D:\log\alert.id  
set /a Zeilen=10

:loop
for /f "delims=:" %%i in ('findstr /n "^" "%Log%"') do set /a Setoff=%%i-%Zeilen%  
if %Setoff% lss 0 set /a Setoff=0
for /f "tokens=1*" %%i in ('more +%Setoff% "%Log%"^|findstr /c:"Priority"') do (  
    for /f "tokens=1-3 delims={}" %%a in ("%%j") do (  
        for /f "tokens=4 delims=: " %%r in ("%%c") do (  
            set "Name=%%i %%r %%a"  
            netsh advfirewall firewall show rule name="!Name:~,-1!">nul || (  
                netsh advfirewall firewall add rule name="!Name:~,-1!" dir=in action=block protocol=%%b remoteip=%%r  
            )
        )
    )
)
sleep 30
goto :loop

@echo off & setlocal
set "Log=D:\log\alert.id  
set /a Zeilen=10

:loop
for /f "delims=:" %%i in ('findstr /n "^" "%Log%"') do set /a Setoff=%%i-%Zeilen%  
if %Setoff% lss 0 set /a Setoff=0
for /f "tokens=1*" %%i in ('more +%Setoff% "%Log%"^|findstr /c:"Priority"') do (  
    for /f "tokens=1-3 delims={}" %%a in ("%%j") do (  
        for /f "tokens=4 delims=: " %%r in ("%%c") do (  
            netsh advfirewall firewall show rule name="%%i %%a %%r">nul || (  
                netsh advfirewall firewall add rule name="%%i %%a %%r" dir=in action=block protocol=%%b remoteip=%%r  
            )
        )
    )
)
sleep 30
goto :loop