VBS - zuletzt erstellte Verzeichnis per vbs auswählen

Hänge fest und bitte um Hilfe des Forums - Ziel ist es, innerhalb eines übergebenen Verzeichnisses die Unterverzeichnisse (über 600) durchzusehen, das jüngst angelegte zu identifizieren und seinen Namen in einer Variablen zurückzugeben. Es handelt sich um eine Funktion, die innerhalb eines längeren VBS-Scriptes aufgerufen werden soll (der Verzeichnisname und nur dieser wird weiter verarbeitet)

Function listfolder(folder, AZ)

    Set fso = CreateObject("Scripting.FileSystemObject")  
    Set objFolder = fso.getfolder(folder)
	Set liste = fso.CreateTextFile("d:\ORDNERLISTE.txt",2)  
	
    for each objSubFolder in objFolder.SubFolders
	    D ="" 'Folder Name des jüngst angelegten Folders  
		M = 0 ' Datum  
		i = objSubFolder.Name
		n = objSubFolder.DateCreated
		j = j &i &" - Erstellungsdatum: " &n &vbCrLf  
		If objSubFolder.DateCreated > M Then
			D = i
			M = objSubFolder.DateCreated
		End If
	next

	liste.WriteLine ("Start: " &now &vbCrLf)  
	liste.WriteLine j
	liste.WriteLine ("---------------------------------" &vbCrLf)  
	liste.WriteLine (" D = " &D &" und M = " &M &vbCrLf)  
	liste.WriteLine ("Ende: " &now)  
	liste.close
	MsgBox("zuletzt angelegter Ordner lautet: "&D &" - angelegt am: " &M)  

End Function

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 110541

Url: https://administrator.de/forum/vbs-zuletzt-erstellte-verzeichnis-per-vbs-auswaehlen-110541.html

Ausgedruckt am: 11.01.2025 um 04:01 Uhr

2 Kommentare

Neuester Kommentar

Hallo lerner001und willkommen im Forum!

Soferne es nur um eine Ordnerebene geht (und auf das Wesentliche gekürzt):

Function listfolder(folder, AZ)

Set fso = CreateObject("Scripting.FileSystemObject")  
Set objFolder = fso.GetFolder(folder)
	
D = "" 'Name des zuletzt angelegten Folders  
M = 0 'jüngstes Erstellungsdatum  
For Each objSubFolder In objFolder.SubFolders
    If objSubFolder.DateCreated > M Then
        D = objSubFolder.Name
        M = objSubFolder.DateCreated
    End If
Next
WScript.Echo "Zuletzt angelegter Ordner: " & D & " - angelegt: " & M  

listfolder = D
End Function

Der Parameter AZ ist (mangels Verwendung) relativ sinnfrei ...

Grüße
bastla

Hallo bastla,

vielen Dank für Begrüßung und Behebung meines Fehlers - die Umstellung der Reihenfolge hat mein Problem behoben - Glückwunsch und vielen Dank für die rasche Hilfe.

Gruß
lerner001

gelöst Frage VB for Applications Entwicklung

Mehr von lerner001

VBA - von Word per VBA AUCH PDF druckenlerner001

Heiß diskutiert